HSPTV!掲示板

タイトル通りです。
画像の色調を変更する命令はありますか？

私がイメージしているのは、背景画面の画像の色調を変更して、
夜に見せる・・・というものです。
それではなくても、画面全体の色調を変更する命令はありますか？

上から目線のような説明でしたら、すいません・・・。

黒なり青なりの半透明の四角形を画面全体に描写、とか。
（画面全体の色調を変えるだなんてシェーダくらいしか思い付かない）

ipmpackを使ってみてはどうでしょうか？
http://www.vector.co.jp/soft/win95/prog/se440193.html

また『HSP　画像処理』等で検索すれば他の方法も見つかりますよ。

　hspcvとかどうでしょう？

おお！解決しました！
なるほど半透明の四角形をつかうとはいいですね＾＾
ありさん、ｆ３ｄさんもありがとうございました！

すでに解決済みになってしまっていますが
HSP3に同梱されているArtlet2Dモジュールを使っても
画像の色調加工が出来る事を忘れていました（汗）
特にカラーマトリックス変換はかなり自由度が高いので
使いこなすと色々な効果が出せますね。
以下簡単なサンプルです。

#include "a2d.hsp"

	title "元画像"
	alCreateImageByFile  0, dirinfo(1) + "\\sample\\demo\\sky_bg.jpg"
	alSelectImage 0
	alCopyImageToScreen 0, 0, 0, 0, 640, 480, 0, 0
	redraw
	
	screen 1 : cls 0
	title "半透明（左上）カラーキーの透過（右上）ガンマ値変更（左下）カラーマトリクス変換（右下）"
	color 255 : repeat 240 : line 0, cnt*2, 640, cnt*2 : loop	;	赤白ラインで背景を塗りつぶす
	
;	半透明コピー
	alCopyModeAlpha 0.5
	alStretchImageToScreen 0, 1, 0, 0, 640, 480, 0, 0, 320, 240
	
;	指定範囲内の色の透過
	alCopyModeColorKey $555555, $ffffff	;	$555555から$ffffffまでの色が透過される
	alStretchImageToScreen 0, 1, 0, 0, 640, 480, 320, 0, 320, 240
	
;	ガンマ値変更
	alCopyModeGamma 3.0		;	数値が大きくなるほど暗くなる
	alStretchImageToScreen 0, 1, 0, 0, 640, 480, 0, 240, 320, 240
	
;	カラーマトリックス変換コピー
	ddim colmatrix, 20
	colmatrix(MAT_R) = 0.30, 0.0, 0.4, 0.0, 0.0	;	赤成分
	colmatrix(MAT_G) = 0.4, 0.30, 0.0, 0.0, 0.0	;	緑成分
	colmatrix(MAT_B) = 0.0, 0.9, 0.30, 0.0, 0.0	;	青成分
	colmatrix(MAT_A) = 0.0, 0.0, 0.0, 1.0, 0.0	;	透明度
	alCopyModeColorMatrix colmatrix		;	カラーマトリックス設定
	alStretchImageToScreen 0, 1, 0, 0, 640, 480, 320, 240, 320, 240
	redraw

をを・・・こんな機能知らなかったです(笑)
ちょっと勉強してきます！