HSPTV!掲示板

初心者です。初歩的な質問ですみません。
「メッセージを表示させて、”次へボタン”で次のメッセージに移る」という
プログラムを組んでいるのですが、

cls
mes "こんにちは"
button "次へ",*hata1
stop

*hata1
mes "私は名無しです。"
button "次へ",*hata2

*hata2

という感じになってしまっています。
これだとラベルが多くなり、長くなってしまうので、もっと短くしたいんです。
どうすればいいでしょうか。
質問が分かりにくかったらすみません。

ラベルの後に、clsを入れてみてはどうですか？

clsを入れてメッセージを消すのを忘れていました。
私が言いたいのは、ノベルゲームのようにセリフをたくさん表示させるときに、
スクリプトが長くなってしまうということです。

マクロで短くするとかでしょうか

#define hoge(%1,%2) cls 0:mes %1:button %2,*@f:stop
cls
hoge "１","NEXT"
*@
hoge "２","NEXT"
*@
hoge "３","NEXT"
*@
hoge "４","NEXT"
*@
stop

dialogで代用とか?
--------------------

cls
dialog "こんにちは",1,"???"
dialog "私は名無しです",1,"名無し"

短くなります

変数で条件分岐すれば分かりやすそうな、
例えばこんな感じで。

*hata1
if num=0: mes "こんにちは"
if num=1: mes "私は名無しです。"
if num=2: mes "3個目" 
button "次へ",*hata2
stop

*hata2
cls
num+1
goto*hata1

おせっかいかもしれませんが、今後それなりの規模のゲームを作られるのでしたら、
配列を覚えて下記のような書き方にされると後々楽になります。

「message(数字) = 〜」　の行を追加するだけでメッセージを追加できます。

// 必要な変数を準備
sdim message,100,100	// メッセージを格納する配列変数
text_cnt = 0		// 何個目のメッセージかをカウント数える変数

// 配列変数にメッセージを格納
// ここを増やしていけばメッセージが増えます
message(0) = "こんにちは"
message(1) = "私は名無しです。"
message(2) = "3番目のメッセージ"


// メインループ
*hata
	cls
	pos 0,0: mes message(text_cnt)
	pos 0,30: button "次へ",*hata
	text_cnt++
stop

「ノベルゲームのように」という記述から察するに、メッセージデータはスクリプト
ではなく外部のテキストファイルに置いておき、note系命令を使って
読み込んで表示するようにした方が、幸せになれるかもしれません。

色々な方法を教えていただき、ありがとうございました。
配列を使う方法と、テキストファイルを読み込む方法を使ってみようと思います。

文を書いている間に解決になってしまいましたが（汗）
メモリーノートパッド系命令を使うとこんな感じです。

	data = "こんにちは\n私は名無しです。\nあとは適当\n終わります。"
	notesel data	//	文字列dataをメモリーノートパッドのバッファに指定

*main
	cls
	noteget txt, txtindex	//	dataから一行ずつ取り出す
	mes txt
	txtindex ++				//	読み込む行を移動
	if txtindex < notemax :	button "次へ", *main

この方法だとdataの行数が増えてもスクリプトの変更はいりません。

テキスト量が多いならdataの内容をテキストファイル（data.txt等）に保存してnoteselの次に

noteload "data.txt"

とすればスクリプトの見通しをよく出来ます。