HSPTV!掲示板

exec"C:\\Users\\"+sysinfo(1)+"\\",,"properties"

パスはあっているはずなのにエラーが出ます
どうすればいいでしょうか

確認できましたが、これはなんでしょうね……。

管理者権限的な問題とかかと思いましたが、
システムフォルダなんかは普通にプロパティ表示できるのに
ユーザー名フォルダだけできないのがわかりませんね。

おそらくHSP内部でやっているであろうプロパティ表示を
APIでやってみましたが失敗でした。

#include "shell32.as"

#include "kernel32.as"

	lpFile = "C:\\Users\\"+sysinfo(1)+"\\";
	lpVerb = "properties";

	dim exinfo, 15;
	exinfo(0) = 60;					// cbSize	構造体サイズ
	exinfo(1) = 0x0000000c;			// fMask	SEE_MASK_INVOKEIDLIST
	exinfo(2) = hwnd;				// hwnd		ウィンドウハンドル
	exinfo(3) = varptr(lpVerb);		// lpVerb	コマンド
	exinfo(4) = varptr(lpFile);		// lpFile	ファイル・フォルダのパス
	exinfo(7) = 1;					// nShow	SW_SHOWNORMAL

	ShellExecuteEx varptr(exinfo);
	rc1 = stat;
	if( rc1 != 0 ) {
		mes "プロパティ表示成功";
	}
	else {
		GetLastError;
		rc2 = stat;
		mes "プロパティ表示失敗";
		// エラーコードを文字列で取得。
		sdim errstr, 1024;
		FormatMessage 0x00001000, 0, rc2, 0, varptr(errstr), 1024, 0;
		mes "エラーコード: "+rc2+"";
		mes errstr;
	}

	stop;

「エラーを特定できません」というダイアログと
「この操作はユーザーによって取り消されました。」というエラーメッセージ。

取り消した覚えなんて無いんですけどね。。。

ShellExecuteEx varptr(exinfo);
rc1 = stat;
if( rc1 != 0 ) {
を
ShellExecuteEx varptr(exinfo);
rc1 = stat;
wait 500
if( rc1 != 0 ) {
にすると、
「この操作はユーザーによって取り消されました」
が
「この操作を正しく終了しました。」
になりますた
waitを入れたらいいのかも？(-_-)

ShellExecuteEx varptr(exinfo);
rc1 = stat;
if( rc1 != 0 ) {
を
ShellExecuteEx varptr(exinfo);
rc1 = stat;
wait 500
if( rc1 != 0 ) {
にすると、
「この操作はユーザーによって取り消されました」
が
「この操作を正しく終了しました。」
になりますた
waitを入れたらいいのかも？(-_-)

ShellExecuteEx varptr(exinfo);
rc1 = stat;
if( rc1 != 0 ) {
を
ShellExecuteEx varptr(exinfo);
rc1 = stat;
wait 500
if( rc1 != 0 ) {
にすると、
「この操作はユーザーによって取り消されました」
が
「この操作を正しく終了しました。」
になりますた
waitを入れたらいいのかも？(-_-)

なぜか３かいも送信してしまった
すまない

GetLastErrorは直前の処理で発生したエラーの状況を調べるためのAPIなので

ShellExecuteEx
wait
GetLastError
とすると、ShellExecuteExのエラーではなくて
wait処理のエラーを調べてしまうのではないかと。。。

waitは正常に動作しているでしょうから
それは「この操作を正しく終了しました。」になるでしょう。。。

Shell32のSHObjectProperties関数を使えばうまく表示させることができました。

#uselib "shell32.dll"

#func SHObjectProperties "SHObjectProperties" int, int, wptr, wptr
#define SHOP_FILEPATH 0x00000002

szObjectName = "C:\\Users\\"+sysinfo(1)+"\\"
SHObjectProperties hwnd, SHOP_FILEPATH, szObjectName, 0
if stat{
	mes "成功"
}else{
	mes "失敗"
}

おお!感激!
やっと解決しました
ありがとうございました!