HSPTV!掲示板

noteadd命令を使って１００００行分の書き込みを行ったのですが、かなり処理に時間がかかってしまいます。
この命令は処理が重いんでしょうか？
また、早く書き込める方法があれば教えていただきたいです。

noteaddは自動的なメモリ拡張が含まれれます
この処理は重く、またメモリに負荷がかかります
最初にあとで使うであろう文字数をsdimで確保することをおすすめします

例）一行10文字の場合
sdim buf,1100000;10*100000に少し見積もって足しておく

素早い回答ありがとうございます。
sdimで確保してみました。
ですが、これでもまだ遅いです。
noteadd命令の限界なのでしょうか？
自分のプログラムが間違っているのでしょうか？

sdim date,1100000
notesel date
repeat 10000
    noteadd "テスト",cnt,1
loop
mes "完了"

↑で完了と表示されるまでに５秒くらいでした。

この処理なら、
noteadd "テスト",cnt,1
を
date+="テスト\n"
にすれば少し早くなります

あとこれで限界です

時間がかかりすぎるとつらいと思うのですが、仕様ということにします。
ご回答ありがとうございました。

この場合だったらmemcpyが速そうな感じ

#include "winmm.as"
#define timeStart timeGetTime : st = stat
#define timeEnd timeGetTime : et = stat
#define ctype time ((1.0 * et - st) / 1000)

// -----
sdim date, 1100000
notesel date
timeStart
repeat 10000
	noteadd "テスト",cnt,1
loop
timeEnd
mes "noteadd : \t"+strf("%.3f",time())+"s"

// -----
sdim date, 1100000
timeStart
repeat 10000
    date+="テスト3\n"
loop
timeEnd
mes "文字列連結 : \t"+strf("%.3f",time())+"s"

// -----
sdim date, 1100000
src = "テスト3\n"
offset = 0
size = strlen(src)
timeStart
repeat 10000
    memcpy date, src, size, offset, 0
    offset+=size
loop
timeEnd
mes "memcpy : \t"+strf("%.3f",time())+"s"

memcpyだとすごく早いんですね。
ちょっと分かりづらい命令ですが、試してみたいと思います。
ありがとうございます。

できました。

#module
#deffunc save
    sdim date,1100000
    notesel date
    offset = 0
    repeat 10000
        src = "行数"+cnt+"\n"
        size = strlen(str)
        memcpy date, src, size, offset, 0
        offset+=size
    loop
    notesave "save.txt"
    return
#global

    save

こんな感じにしました。
すぐにセーブできているみたいですがどうでしょうか