HSPTV!掲示板

マトリックスの数字が流れるやつを作りたいと思うんですが、なかなかうまくいきません
それっぽいものは作れたんですが、流れないし出現タイミングも同じで全然だめでした
どうすればいいでしょうか？

//終了する場合は「Alt+F4」でお願いします
buffer 1,10000,10000
color :boxf
bgscr 0,ginfo_dispx,ginfo_dispy,0,0,0
color :boxf
repeat
randomize
redraw 0
pos 0,0
gmode 4,,,8
gcopy 1,0,0,ginfo_winx,ginfo_winy
c=0
repeat 100
c+
no(c)=rnd(2)
x(c)=rnd(ginfo_winx)+1
y(c)+30
color ,255,
if y(c)>ginfo_winy :y(c)=0
pos x(c),y(c)
mes no(c)
loop
redraw 1
wait 1
loop

buffer 1,ginfo_dispx,ginfo_dispy
bgscr 0,ginfo_dispx,ginfo_dispy,0,0,0
ux=ginfo_dispx:uy=ginfo_dispy

gsel 1:color :boxf

gsel 0

oo=300
dim x,oo:dim y,oo
dim m,oo

repeat oo
x.cnt=h			
tx.cnt=h		;開始位置を記憶する
h=10*w	
w+
y.cnt=0
m.cnt=rnd(2)	;文字 1 or 0
loop
color ,,:boxf

*main
	redraw 0
	
	pos 0,0:gmode 3,ux,uy,10:gcopy 1
	color ,255,
	repeat oo
	m.cnt=rnd(2)
	pos x.cnt,y.cnt:mes m.cnt
	y.cnt+=20:if y.cnt>uy:y.cnt=0:x.cnt=tx.cnt
	loop
	redraw 1
	await 1
	goto *main

こんなんでよろしいでしょうか。

なんとなく凝ってみたらこんなのに。

;ウィンドウ設定
	wx=ginfo_dispx : wy=ginfo_dispx
	buffer 1,wx,wy : cls 4
	fsize=20
	buffer 2,fsize+2,fsize : color 0,0,0 : boxf : color 0,255,0 : font msgothic,fsize,1 : pos 0,0 : mes "0" : pos fsize/2+1,0 : mes "1"
	bgscr 0,ginfo_dispx,ginfo_dispy,0,0,0 : cls 4

;種まき
	randomize

;配列設定
	sn=150
	repeat sn : sx(cnt)=rnd(wx-fsize/2) : sy(cnt)=rnd(wy) : sp(cnt)=rnd(16)+5 : loop

*main

	redraw 0

;描画処理
	repeat sn

;加算コピーで０か１を表示
	pos sx(cnt),sy(cnt) : gmode 5,fsize/2+1,fsize,255*sp(cnt)/20 : gcopy 2,(fsize/2+1)*rnd(2),0

;Ｙ座標の処理と、下まで行った時の処理
	sy(cnt)+=sp(cnt)
	if sy(cnt)>wy : sx(cnt)=rnd(wx-fsize/2) : sy(cnt)=-20 : sp(cnt)=rnd(16)+5
	loop

	pos 0,0 : gmode 3,wx,wy,5 : gcopy 1

	redraw 1
	await 10
	goto *main

>>Quietさん
出現タイミングもバラバラにしたいようです。

buffer 1,ginfo_dispx,ginfo_dispy
bgscr 0,ginfo_dispx,ginfo_dispy,0,0,0
ux=ginfo_dispx:uy=ginfo_dispy

gsel 1:color :boxf

gsel 0

oo=500
dim x,oo:dim y,oo
dim m,oo
color ,,:boxf

*main
	redraw 0
	
	pos 0,0:gmode 3,ux,uy,10:gcopy 1
	
	
	repeat oo
	m.cnt=rnd(10)
	x.cnt=10*rnd(ux/10)
	y.cnt=20*rnd(uy/20)
	color ,255,:pos x.cnt,y.cnt:mes m.cnt
	
	loop
	
	redraw 1
	await 1
	goto *main

では、こんな感じですか？

解決しました
うまく組み込んでみます

>>17286　カッコイイ！

> マトリックスの数字が流れるやつを作りたいと思うんですが、なかなかうまくいきません

あれは確かカタカナ（半角？）の左右反転文字でしたね。