HSPTV!掲示板

どうも、こんにちわ
ちょっとしたものを作ろうとして、いきなりつまずきました。

オブジェクトの最大数を4096に設定しているのですが、1024個既定値でエラーになります。
何か間違ってますかね？？？バグ？
皆さんの環境ではいかがでしょうか

#include "hgimg4.as"
gpreset
setcls CLSMODE_SOLID,0
setreq SYSREQ_MAXOBJ,4096	; オブジェクト最大数を4096に拡張する

getreq var,SYSREQ_MAXOBJ
dialog var;←ちゃんと設定されているが、実際は既定値1024のままか？

gpbox id_box,1,$ff0000

repeat 4
	i=cnt
	repeat 16
		j=cnt
		repeat 16
			k=cnt
			gpclone id,id_box
			setpos id,j,i,k
			 num++
			 logmes num ;←1021個でエラー発生
		loop
	loop
loop

dialog num

*main
	redraw 0
	gpdraw
	redraw 1
	await 1000/60
goto *main

Dripです。buhioさんこんにちは。
setreq SYSREQ_MAXOBJをgpresetよりも前に設定し、カメラなどのシステムで利用するオブジェクト数を考慮した値を最大値に設定してテストしてみてください！
私も前々から不便だなと感じていたのですが、setreqの説明にはgpresetの前に使わなければならないのか、後に使ってもいいのか、または毎フレーム使うような激しい利用は可能なのか等が書かれていないので、この命令は実際に試してみないとわかりません。
私の作品でもゆとりを持ってオブジェクト数を設定したつもりが実は効いてなくてユーザー様からのバグ報告で気づいたこともありました＾＾；

#include "hgimg4.as"
chdir dir_exe+"\\sample\\hgimg4"
#define lines 32	//１ラインの個数
#define max 4096	//オブジェクト数
setcls 1,$888888	//背景色
setreq SYSREQ_MAXOBJ,max+8		//オブジェクト最大数（+8は多めのゆとり）
gpreset	//↑を定義したあとに初期化！
repeat max	//箱を生成（１段32*32=1024で4096なら4段の立方体群が出現）
	gpbox b,0.9
	setpos b,cnt\lines-lines/2,cnt\(lines*lines)/lines-lines/2,cnt/(lines*lines)
loop

repeat	//表示
	setpos GPOBJ_CAMERA,1.5*sin(0.01*cnt)*lines,,1.5*cos(0.01*cnt)*lines
	gplookat GPOBJ_CAMERA,0,0,0	//中心を見つめる
	redraw 0
	gpdraw
	redraw 1
	await 30
loop

>>Dripさん

　いけました！！

　ぬぅぅぅ、そういえば何回かこういうことがあった気がするが、忘れていました。。
　ありがとうございました！！！！

解決！！！