HSPTV!掲示板

皆さんコンニチワ

　HSPのswitch文だと、case条件に詳細なルールを設けられない（と思っている）ため、
　repeat文を代用しているのですが、おかしいでしょうか？
　今のところ特に問題はなく、gotoで抜けないように注意する程度です。
　
　あるいは、switch文で同じようなことができるのでしょうか？

　

  a=0
　b=0

　repeat 1　//1回だけ実行
    
     if (a=1)&(b=1):mes "1":break
     if (a=2)&(b=1):mes "2":break
     if (a=3)&(b=1):mes "3":break
     
     mes "条件を満たしませんでした"
  loop

　stop

　

これは良いアイディア…！
サブルーチンやユーザ定義命令・関数ですと、
if文で条件を満たした時にreturnして「以降のことはもう関係ないよ」
とするのをよくやりますが、サブルーチンでない場合でも
repeatとbreakを使って同じようなことができたとは…。

ちなみに、switch文でも似たようなことはできなくもありません。
switch文やcase文はhspdef.as内で定義されたマクロで、
hspdef.asの中身を見ますと、
・switch文の引数を"_switch_val"という変数に入れる。
・case文の引数と"_switch_val"を比較し、同じであればcase以降を実行する。
という流れになっていますので、たとえば以下のような書き方も
できなくはありません。
（実用性があるかどうかはともかく）

a=0
b=0
switch 1
	case a=1 & b=1
		mes "1"
		swbreak
	case a=2 & b=1
		mes "2"
		swbreak
	case a=3 & b=1
		mes "3"
		swbreak
	default
		mes "条件を満たしませんでした"
		swbreak
swend

こんにちわ。
repeat 1で見ただけで1回だけ実行と分かるので、読みやすさ的にもおかくないのではないでしょうか。
別案だと、ループ中だとcntの退避、おっしゃられるgoto使えない所もあるので、
数多ければローカルラベルを使うか、少なければelse:ifを使うやりかたはよく書いてます。

ですが。。。
↓の様に見比べてみると見た目的に分かりにくいので提示されてるスクリプトは
条件次第ではすっきりして良いのではないでしょうか。

a=0:b=0
if (a=1)&(b=1):mes "1":goto *@f
if (a=2)&(b=1):mes "2":goto *@f
if (a=3)&(b=1):mes "3":goto *@f
mes "条件を満たしませんでした"
*@

a=0:b=0
if (a=1)&(b=1) {
	mes "1"
} else:if (a=2)&(b=1) {
	mes "2"
} else:if (a=3)&(b=1) {
	mes "3"
} else {
 mes "条件を満たしませんでした"
}

一見変な書き方だけど、見やすくていいですね。
本来の命令の用途と異なるので、何となくこう書きたくなります。

a=1
b=1

gosub *sw
stop

*sw
	if (a=1)&(b=1):mes "1":return
	if (a=2)&(b=1):mes "2":return
	if (a=3)&(b=1):mes "3":return
	mes "条件を満たしませんでした"
	return

しかしこれだと離れた場所に書く必要があるので、読みにくくなってしまいますね。


普段の私なら…switchで無理やり書いてしまいそうです。

a=3
b=0

switch ((a=1)<<3) | ((a=2)<<2) | ((a=3)<<1) | (b=1)
	case 1<<3 | 1
		mes "1"
		swbreak
	case 1<<2 | 1
		mes "2"
		swbreak
	case 1<<1 | 1
		mes "3"
		swbreak
	default
		mes "条件を満たしませんでした"
swend

repeat使った方がすっきりする。

repeat のその使い方もアリです。
repeat 1 とはしませんが、私も似たような使い方をすることがあります。

switch〜case は hspdef.as で定義されているマクロです。
以下がそれですが、これを見れば展開後どうなるかわかると思われます。

#define global switch(%1) %tswitch %i0 %s1 _switch_val=%p : if 0 {
#define global case(%1) %tswitch _switch_sw++} if _switch_val == (%1) | _switch_sw { _switch_sw = 0

#define global default %tswitch } if 1 {
#define global swbreak %tswitch goto *%p1
#define global swend %tswitch %o0 } *%o

皆さん色々とswitchの書き方例を提示いただきありがとうございます。

　どうもswitch文というかマクロは苦手なので、TPOに応じてrepeatで代用していこうと思います。
　ローカルラベルについては、まだよく理解していないので、調べてみようと思います。
　

わぁ、いろいろあって面白いですね。
たしかにreturn使いたかったらGENKIさんの様に書いていたかも。。。
という事で、インラインで書きたい気持ちでマクロ化してみました。
(switchは予約されてるので仮にbranchとしました)

#define global branch gosub %tbrs *%i : goto %tbre *%i : %tbrs *%o
#define global brend %tbranch %tbre *%o
; ↑これをhspdef.asなどに書いておく

a=0:b=0
branch
	if (a=1)&(b=1):mes "1":return
	if (a=2)&(b=1):mes "2":return
	if (a=3)&(b=1):mes "3":return
	mes "条件を満たしませんでした"
brend

>buhioさん
ローカルラベルはラベル名考えるの面倒な時と簡単な分岐の時に使ってるのですが、
保守管理敵に混乱あるかもなので、今回のマクロの方がシンプルかもです。すみません。
あと今回のはスタック使っているので、ネストできます。