HSPTV!掲示板

ウィンドウハンドルからウィンドウIDに変換するモジュールを作ってみました。
間違いがあれば教えてください。

#module "WindowIDconvert"
#uselib "user32.dll"
#func GetWindowLong "GetWindowLongA" int,int
#define GWL_USERDATA -21
#defcfunc WindowID int p1
gselID=ginfo(3)
gsel 0
if p1=hwnd:gsel gselID:return 0//ウィンドウIDが0の場合
gsel gselID
GetWindowLong p1,GWL_USERDATA//ウィンドウハンドルからウィンドウIDに変換
if stat<=p1:return -1
return stat
#global

すごいですね

少し微妙だったので修正しました。

#module "WindowIDconvert"
#uselib "user32.dll"
#func GetWindowLong "GetWindowLongA" int,int
#define GWL_USERDATA -21
#defcfunc WindowID int p1
gselID=ginfo(3)
gsel 0
if p1=hwnd:gsel gselID:return 0//ウィンドウIDが0の場合
gsel gselID
GetWindowLong p1,GWL_USERDATA//ウィンドウハンドルからウィンドウIDに変換
if stat<=0|stat>=ginfo(25):return -1//HSPウィンドウ以外のウィンドウの場合
return stat
#global

関数名が「WindowID」だと分かりにくいので、「GetWindowIdFromHwnd(ウィンドウハンドルからIDを取得)」
など、具体的にすれば分かりやすいと思います。

モジュール名は「WindowIDconvert」ではなく「ConvertToWindowID」がいいと思います。

修正しました。

#module "ConvertToWindowID"
#uselib "user32.dll"
#func GetWindowLong "GetWindowLongA" int,int
#define GWL_USERDATA -21
#defcfunc GetWindowIDFromHwnd int p1
gselID=ginfo(3)
gsel 0
if p1=hwnd:gsel gselID:return 0//ウィンドウIDが0の場合
gsel gselID
GetWindowLong p1,GWL_USERDATA//ウィンドウハンドルからウィンドウIDに変換
if stat<=0|stat>=ginfo(25):return -1//HSPウィンドウ以外のウィンドウの場合
return stat
#global

repeat 50
screen cnt
mes "ウィンドウID="+GetWindowIDFromHwnd(hwnd)
loop

ふむ…

//
// モジュール部分 省略
//
repeat 4
screen cnt*cnt
mes "ウィンドウID="+GetWindowIDFromHwnd(hwnd)
loop
button "A",*o
button "B",*o
mes "B:"+GetWindowIDFromHwnd(objinfo_hwnd(stat))
*o

HSPウィンドウ以外のウィンドウを除外するコードに問題があるよ。

ところでこのコードは、
別に実行しているHSP製のプログラムのウィンドウハンドルを放り込んだ時に、ウィンドウIDを取得するっていうことが
可能な見込みで作っているのか、不可能な見込みで作っているのか、未定義で作っているのか…。

掘木さん。ありがとうございます。

if stat<=0|stat>=ginfo(25):return -1

を

if stat<=0|stat>=1000:return -1

にすれば、
うまくいくと思います。

ボタンにUserDataを持たせてGetWindowIDFromHwndでIDを取得したら-1が返ってこない。
逆にウィンドウIDが1001以上のウィンドウをGetWindowIDFromHwndでIDを取得したら-1が返ってくる。
GetClassName関数でクラス名が「hspwnd0」かどうかでHSP製ウィンドウか判断するのがいいと思います。

#uselib "user32.dll"
#func SetWindowLong "SetWindowLongA" int,int,int
button "Button",*dummy:hButton=objinfo(stat,2)
SetWindowLong hButton,-21/*GWL_USERDATA*/,10
mes "ウィンドウID="+GetWindowIDFromHwnd(hButton)

screen 10000
mes "ウィンドウID="+GetWindowIDFromHwnd(hwnd)
*dummy

ありがとうございます。
これでどうでしょうか...

#module "ConvertToWindowID"
#uselib "user32.dll"
#func GetClassName "GetClassNameA" int,var,int
#cfunc GetWindowLong "GetWindowLongA" int,int
#define GWL_USERDATA -21
#defcfunc GetWindowIDFromHwnd int p1
sdim class,256
GetClassName p1,class,256
if class!"hspwnd0":return -1////HSPウィンドウ以外のウィンドウの場合
return GetWindowLong(p1,GWL_USERDATA)//ウィンドウハンドルからウィンドウIDに変換
#global
repeat 50
screen cnt
wait 2
mes cnt
mes GetWindowIDFromHwnd(hwnd)
loop