hspでのかっこいいスコアカウンター的な物

私も少し興味があったので、書いてみました。
Dripさんのプログラムも、少し使わさせて頂きます。


/*━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━・
		数字パネルモジュール
──────────────────────────────
	製作者　　　　end
	バージョン　　Ver 1.00
	確認済みOS　　windows 7
	製作日　　　　2015/05/27
──────────────────────────────
	●本モジュールの利用点について
		本モジュールは、[Dripさん](NO.69297)のプログラムを参考にして、作りました。
		簡単に複数の数字パネルを設置できることが特徴です。
		また、文字の前や後に任意の文字を指定することも可能です。(英半角のみ対応)
	
──────────────────────────────
	//---- 命令一覧 ----//
	
	●初期化
		・命令  NumberPanel_Init
		・解説
			数字パネルモジュールを利用する前に初期化します。
			初めに必ず初期化してください。
	
	●新しい数字パネルを作成
		・NumberPanel_New P1 , P2 , P3 , P4 , P5 , P6
		・解説
		　　新しい数字パネルを作成します。　　※注意：この命令を使用しても、実際には描画されません。
		　　P1=表示する文字(半角英数字のみ、"*"を除く)　"*"の箇所に数字パネルが表示されます。　　例："Score:*"とすることで"*"の部分が数字パネルになります。　　※省略した場合は"*"が自動で入力されます。
		　　P2=パネルサイズ　　一つのパネルのサイズです。（パネルは正方形です。）
		　　P3=桁数　　数字パネルの桁数を指定します。　※P1で指定する文字の長さではありません。
		　　P4=速度　　何フレームで一つパネルが動くかを指定します。　　※FPS60の処理である時、60を指定すると一秒に一つパネルが動きます。
		　　P5=デフォルトの値　　数字パネルに表示する値を指定します。
		　　P6=最大値　　省略時は、(10^桁数)となります。
		　　Stat=数字パネルコントロールID　　※本モジュールで、数字パネルを操作するためのIDとなります。
	
	●数字パネルの表示
		・NumberPanel_Copy P1
		・解説
		　　数字パネルを描画します。
		　　P1=数字パネルコントロールID　　※「NumberPanel_New」の戻り値で取得したID
		　　Stat=失敗すれば-1が入り、成功すれば0が入ります。
	
	●数字パネルの更新
		・NumberPanel_Updt P1
		・解説
		　　数字パネルを実際に動かします。（回します。）
		　　P1=数字パネルコントロールID　　※「NumberPanel_New」の戻り値で取得したID
		　　Stat=失敗すれば-1が入り、成功すればそれ以外の値が入ります。　動かした場合、1が入り、動かしていない場合は0が入ります。
	
	●数字パネルの値を変更
		・NumberPanel_Set P1 , P2 , P3
		・解説
		　　数字パネルの値を変更します。
		　　P1=数字パネルコントロールID　　※「NumberPanel_New」の戻り値で取得したID
		　　P2=値　　変更する値を入れてください。
		　　P3=モード　　0で値をそのまま代入します。1で現在の数字パネルの値に追加します。2で現在の数字パネルの値から減少します。

	●数字パネルの値を取得
		・Ver = NumberPanel_Get ( P1 )
		・解説
		　　数字パネルの値を取得します。
		　　P1=数字パネルコントロールID　　※「NumberPanel_New」の戻り値で取得したID
		　　戻り値=失敗すれば-1、正常であれば0以上の値(数字パネルの値)

──────────────────────────────・*/

#module 
/*━━━━━━━━━━
	マクロ
──────────*/
#const MAX_Panel 100	;最大設置可能パネル数
#const MAX_Digt 30	;最大桁数

/*━━━━━━━━━━
	初期化
──────────*/
#deffunc NumberPanel_Init
	dim Frag,MAX_Panel	;使用されているかのフラグ(0=未使用 1=使用している)
	dim Pcid,MAX_Panel	;数字画像ID
	dim Psid,MAX_Panel	;文字画像ID
	dim Psln,MAX_Panel	;文字画像の長さ
	dim Psiz,MAX_Panel	;パネルサイズ
	dim Digt,MAX_Panel	;桁数
	dim Ftim,MAX_Panel	;速度
	dim Fsit,MAX_Panel,MAX_Digt	;数字パネルの描画位置
	dim Valu,MAX_Panel	;値
	dim Mval,MAX_Panel	;最大値
	sdim Strs,100,MAX_Panel	;デフォルト表示文字
return

/*━━━━━━━━━━
	新しい数字パネル
	p1=表示する文字
	p2=パネルサイズ
	p3=桁数
	p4=フレーム時間(例：60を指定した場合、60フレームで一つ数字が動きます。)
	p5=デフォルトの値
	p6=最大値(これ以降は0に戻る)
	stat=数字パネルコントロールID(数字パネルを操作するときのコントロールID) -1=エラー
──────────*/
#deffunc NumberPanel_New str p1 , int p2 , int p3 , int p4 , int p5 , int p6 , local SetId , local GmSel , local _Scnt , local Index , local _Psid
	GmSel=ginfo_sel	;元の画面IDを維持
	
	//----IDの取得
	SetId=-1
	repeat MAX_Panel
	if Frag(cnt)=0	:SetId=cnt	:break	;空きのパネルコントロールであれば抜ける
	loop
	if SetId=-1	:return -1	;使用可能なIDが無ければエラー
	
	//----情報を入力
	Strs(SetId)=p1	;表示する文字
	if Strs(SetId)=""	:Strs(SetId)="*"	;省略した場合は[*]を指定
	Psiz(SetId)=p2	;パネルサイズ
	Digt(SetId)=p3	;桁数
	Ftim(SetId)=p4	;フレーム時間
	Valu(SetId)=p5	;デフォルトの値
	Mval(SetId)=p6	;最大値
	if Mval(SetId)<1	:Mval(SetId)=int(powf(10,Digt(SetId)))	;最大が設定されていない場合は設定する
	
	//----画像
	Pcid(SetId)=ginfo_newid	;空きの画像バファを取得
	buffer Pcid(SetId),Psiz(SetId)*4,Psiz(SetId)*11	//スコアパネル画像バッファ
	cls 4:color 255,255,255:font "Arial Black",Psiz(SetId)-2	//フォント定義
	repeat 37			//パネルデザイン開始
		gradf 0,cnt*Psiz(SetId),Psiz(SetId),Psiz(SetId)/2,1,$080808,$606060
		gradf 0,cnt*Psiz(SetId)+Psiz(SetId)/2,Psiz(SetId),Psiz(SetId)/2,1,$606060,$080808
		gradf Psiz(SetId),cnt*Psiz(SetId),Psiz(SetId),Psiz(SetId)/2,1,$FF0000,$FFFF00
		gradf Psiz(SetId),cnt*Psiz(SetId)+Psiz(SetId)/2,Psiz(SetId),Psiz(SetId)/2,1,$FFFF00,$FF0000
		pos Psiz(SetId)*4,0:mes ""+(cnt\10)
		pos Psiz(SetId)*2+(Psiz(SetId)-ginfo_mesx)/2,cnt*Psiz(SetId)+(Psiz(SetId)-ginfo_mesy)/2:mes ""+(cnt\10)
	loop
	color 8,8,8:line 0,0,0,Psiz(SetId)*11:line Psiz(SetId)-1,0,Psiz(SetId)-1,Psiz(SetId)*11
	gmode 7,Psiz(SetId),Psiz(SetId)*11:pos 0,0:gcopy Pcid(SetId),Psiz(SetId),0
	
	//----文字画像
	;[*]がいくつあるか計測
	repeat strlen(Strs(SetId))
	if peek(Strs(SetId),cnt)='*'	:_Scnt++	;カウント増加
	loop
	Psln(SetId)=strlen(Strs(SetId))-_Scnt + _Scnt*Digt(SetId)	;文字画像の長さ
	;初期化
	_Psid=ginfo_newid	;空きの画像バファを取得
	buffer _Psid , Psiz(SetId)*3 , Psiz(SetId)* Psln(SetId)	//スコアパネル画像バッファ
	cls 4:color 255,255,255:font "Arial Black",Psiz(SetId)-2	//フォント定義
	Index=0
	repeat strlen(Strs(SetId))
		if peek(Strs(SetId),cnt)='*'{
		Index+=Digt(SetId)	;桁数だけ増加
		}else{
		gradf 0,Index*Psiz(SetId),Psiz(SetId),Psiz(SetId)/2,1,$080808,$606060
		gradf 0,Index*Psiz(SetId)+Psiz(SetId)/2,Psiz(SetId),Psiz(SetId)/2,1,$606060,$080808
		gradf Psiz(SetId),Index*Psiz(SetId),Psiz(SetId),Psiz(SetId)/2,1,$FF0000,$FFFF00
		gradf Psiz(SetId),Index*Psiz(SetId)+Psiz(SetId)/2,Psiz(SetId),Psiz(SetId)/2,1,$FFFF00,$FF0000
		
		pos Psiz(SetId)*4,0:mes ""+strmid(Strs(SetId),cnt,1)
		pos Psiz(SetId)*2+(Psiz(SetId)-ginfo_mesx)/2,Index*Psiz(SetId)+(Psiz(SetId)-ginfo_mesy)/2:mes ""+strmid(Strs(SetId),cnt,1)
		Index++
	}
	loop
	color 8,8,8:line 0,0,0,Psiz(SetId)*Psln(SetId):line Psiz(SetId)-1,0,Psiz(SetId)-1,Psiz(SetId)*Psln(SetId)
	gmode 7,Psiz(SetId),Psiz(SetId)*Psln(SetId):pos 0,0:gcopy _Psid,Psiz(SetId),0
	
	Psid(SetId)=ginfo_newid	;空きの画像バファを取得
	buffer Psid(SetId) , Psiz(SetId)* Psln(SetId) , Psiz(SetId)	//スコアパネル画像バッファ
	
	repeat Psln(SetId)
	pos cnt*Psiz(SetId),0
	gcopy _Psid,0,cnt*Psiz(SetId),Psiz(SetId),Psiz(SetId)
	
	loop
	
	gsel GmSel	;元の画面IDに変更
	Frag(SetId)=1	;使用中フラグ

return SetId

/*━━━━━━━━━━
	数字パネルの表示
	※表示する位置はposで指定してください。
	p1=操作する数字パネルコントロールID
	stat= (-1=エラー 0=正常)
──────────*/
#deffunc NumberPanel_Copy int SetId , local Px , local Pt , local Gp , local Index , local SetIndex
	if Frag(SetId)=0	:return -1
	
	//----表示
	Px=ginfo_cx	;カレントポジションX(パネルの左上X)
	Py=ginfo_cy	;カレントポジションY(パネルの左上Y)
	
	Index=0
	pos Px , Py
	gcopy Psid(SetId),0,0,Psiz(SetId)*Psln(SetId),Psiz(SetId)*3
	
	repeat strlen(Strs(SetId))
		if peek(Strs(SetId),cnt)='*'{
			repeat Digt(SetId)
				pos Px+(cnt+Index)*Psiz(SetId) , Py
				Gp=1.0*Psiz(SetId)/Ftim(SetId)*Fsit(SetId,cnt)
				gcopy Pcid(SetId),0,Gp,Psiz(SetId),Psiz(SetId)
			loop
			Index+=Digt(SetId)	;桁数だけ増加
		}else{
			Index++
		}
	loop

return 0

/*━━━━━━━━━━
	数字パネルの更新　　フレームごとに呼び出す必要があります。
	p1=操作する数字パネルコントロールID
	stat= (-1=エラー 0=待機中 1=作動中[数字が動いている])
──────────*/
#deffunc NumberPanel_Updt int SetId , local dt , local md
	if Frag(SetId)=0	:return -1
	md=0
	//----表示
	repeat Digt(SetId)
		Gp=1.0*Psiz(SetId)/Ftim(SetId)*Fsit(SetId,cnt)
		dt=Valu(SetId) \ powf(10,Digt(SetId)-cnt)/powf(10,Digt(SetId)-cnt-1) * Ftim(SetId)	;桁の値を求める×時間
		if Fsit(SetId,cnt)!=dt	:Fsit(SetId,cnt)++	:md=1
		if Fsit(SetId,cnt)>Ftim(SetId)*10	:Fsit(SetId,cnt)=0	;オーバーフローした場合は0に戻す
	loop

return md

/*━━━━━━━━━━
	値を変更
	p1=操作する数字パネルコントロールID
	p2=値
	p3=変更モード(0=代入 1=増加 2=減少)
	stat= (-1=エラー 0=正常)
──────────*/
#deffunc NumberPanel_Set int SetId , int p2 , int p3
	if Frag(SetId)=0	:return -1	;チェック
	
	switch p3
		case 0	:Valu(SetId)=p2	:swbreak
		case 1	:Valu(SetId)+=p2	:swbreak
		case 2	:Valu(SetId)-=p2	:swbreak
	swend
	
	Valu(SetId)\=Mval(SetId)
	return 0

/*━━━━━━━━━━
	値を取得
	p1=操作する数字パネルコントロールID
	戻り= (-1=エラー その他=値)
──────────*/
#defcfunc NumberPanel_Get int SetId , int p2 , int p3
	if Frag(SetId)=0	:return -1	;チェック
	return Valu(SetId)
#global


//--------------------------------------------------------------//
//------------------------ 以下サンプル ------------------------//
//--------------------------------------------------------------//
#if 1
//----初期化
screen 0,380,80
randomize 
NumberPanel_Init 	;初期化

//----初期の登録
NumberPanel_New "Current time",30	:ID_Main=stat	;文字バー
NumberPanel_New "*:",30,2,8,gettime(4),24	:ID_Hour=stat	;時
NumberPanel_New "*:",30,2,8,gettime(5),60	:ID_Minute=stat	;分
NumberPanel_New "*",30,2,8,gettime(6),60	:ID_Second=stat	;秒
NumberPanel_New "(*)",30,2,3,gettime(7),60	:ID_Milliseconds=stat	;ミリ秒(雰囲気的に付けてみた)

//----ループ開始
repeat

	//----時刻設定
	NumberPanel_Set ID_Hour,gettime(4)
	NumberPanel_Set ID_Minute,gettime(5)
	NumberPanel_Set ID_Second,gettime(6)
	NumberPanel_Set ID_Milliseconds,gettime(7)

	//----値の更新
	NumberPanel_Updt ID_Hour
	NumberPanel_Updt ID_Minute
	NumberPanel_Updt ID_Second
	NumberPanel_Updt ID_Milliseconds
	
	//----描画
	redraw 0
		color 60,60,60	:boxf
		pos 10,10	:NumberPanel_Copy ID_Main
		pos 10,40	:NumberPanel_Copy ID_Hour
		pos 100,40	:NumberPanel_Copy ID_Minute
		pos 190,40	:NumberPanel_Copy ID_Second
		pos 250,40	:NumberPanel_Copy ID_Milliseconds
	redraw 1
	await 16	;FPS60に近い状態
loop


//--------------------------------------------------------------//
//------- 分かりにくい場合は以下のサンプルも試してみてね -------//
//--------------------------------------------------------------//
//260行辺りにある「#if 1」を「#if 0」に変えると下のサンプルを実行できます。
#else

//----基本初期化
screen 0,460,110	;スクリーン初期化
randomize	;乱数発生用の初期化
NumberPanel_Init 	;数字パネルモジュールを利用するための初期化

//----数字パネルの初期化
NumberPanel_New "",24,4,8,1234	:ID_Number=stat	;値を表示
//P1には表示する文字　今回は数字パネルのみ表示するので、空白。　実際は"*"が自動で入力される。
//P2にはパネルサイズ
//P3にはパネルの桁数　
//P4にはデフォルトの値　
//stat(戻り値)は数字パネルを操作するためのIDが入ります。

NumberPanel_New "Number panel",24	:ID_Character=stat	;文字だけ表示
//文字だけ表示する場合は、P1に表示する文字(半角英数字のみ)を入力します。
//今回は文字だけなので、P2にパネルサイズだけ指定して、他は省略OKです。

NumberPanel_New "Score:*",24,6,8,1530	:ID_Score=stat	;文字と値を表示
//文字を数字パネルを表示するには、"*"を文字列内に入力します。
//上の例では、"Score:"の後に数字パネルが表示されます。

//----ゲームの開始
repeat

	//----数字パネルの変更
	NumberPanel_Set ID_Number , cnt/30
	if cnt\120=0	:NumberPanel_Set ID_Score , rnd(6000)+100 , 1	;ランダムに値を追加
	
	//----数字パネルの更新　　※数字パネルを実際に動かします。
	NumberPanel_Updt ID_Number
	NumberPanel_Updt ID_Score


	//----描画
	redraw 0	;描画を一時停止
		color 20,20,20	:boxf	;画面を初期化
		
		pos 10,10	:color 255,255,200	:mes "数字パネル表示"
		pos 160,10	:NumberPanel_Copy ID_Number
	
		pos 10,40	:color 255,255,200	:mes "文字の表示"
		pos 160,40	:NumberPanel_Copy ID_Character
	
		pos 10,70	:color 255,255,200	:mes "数字と文字パネル"
		pos 160,70	:NumberPanel_Copy ID_Score
		
	redraw 1	;描画を再開

	//----後処理
	await 16	;FPS60に近い状態
loop

#endif
長文失礼しました。

急いで書いたので、間違いがあると思います。その場合ご指摘いただけると幸いです。
HSPTV!掲示板
