HSPTV!掲示板

64bit版windows7にて、
#include "hsptv.as"
を実行するとawaitが不安定になるようです。
windowsXPでは問題ありませんでした。

他の方のPCでの動作状況を知りたいです。

自分のwindows 7の64bitでは、
hsptv.asに限らず
HSP全般でawait 1でFPSが160とか出てみたりします。
（他PCで同じ物を実行してもFPSの数値はこんなになりません。
他には特に異常等はないです）
どう不安定なんでしょうか？
動作が止まったり…ということなら
自分はなりませんね。

例えば、await 20としてもFPSが50にならず、32になりました。前バージョンのawaitの動作に似ています。
hsptv.asをインクルードしなければFPSが50になります。

OSとは別の問題でしょうか・・・？

どうなんでしょうかね…
自分が実行しても、
使ったのはこのサイトのfps測るソースのawaitを20にしたものです↓
http://very.skr.jp/page_tips/game06_o1.html
自分も、hsptv.asをインクルードした場合、
50から32になりました。
OSの問題ですかね…
32bitで正常に動けば
64bitだからと考えられますが…
32bitのwin7が無いのでどうとも言えないです。
7の問題か、win7 64bitのみの現象なのかもわかんないですね

2012/06/14 3.31β1
await命令の時間待ちを高精度タイマーによる処理に変更

多分これで通常のHSPは改善されたけど
hsptvは以前のままでawit 20がawait 15*2と同等の時間待ちしてる

;#include "hsptv.as"

repeat 20
	w++
	wait 1
	tim=gettime(7)
	repeat 20
		await w
	loop
	timcnt(cnt)=(gettime(7)-tim+1000)\1000
	mes strf("await %2d //%5.2f ms",w,double(timcnt(cnt))/20)
loop

XPと64bit版win7で待ち時間が違いました
XPではawait 10*nになって、win7ではawait 15*nでした

正確に待つには何かFPSを保つ処理を作るか、await 30あたりで妥協するしかなさそうですね

タイマー精度を上げたSleepとawaitを置き換えてみる

#include "hsptv.as"

#module "mod_await"
#uselib "KERNEL32.DLL"
#func _Sleep "Sleep" sptr

#uselib "winmm.dll"
#func _timeBeginPeriod "timeBeginPeriod" sptr
#func _timeEndPeriod "timeEndPeriod" sptr
#cfunc _timeGetTime "timeGetTime"

#undef await
#deffunc  await int w
	if tBP {
		_Sleep limit(w-(_timeGetTime()-tim),0,w)
		await@hsp 0
		tim=_timeGetTime()
	}else{
		tBP=1
		_timeBeginPeriod 1
		tim=_timeGetTime()
	}
return 

#deffunc timeEndPeriod onexit
	if tBP {
		_timeEndPeriod 1
	}
return
#global

repeat 20
	w++
	wait 1
	tim=gettime(7)
	repeat 20
		await w
	loop
	timcnt(cnt)=(gettime(7)-tim+1000)\1000
	mes strf("await %2d //%5.2f ms",w,double(timcnt(cnt))/20)
loop

一回目のawaitがSleepしてなかったのを修正

#include "hsptv.as"

#module "mod_await"
#uselib "KERNEL32.DLL"
#func _Sleep "Sleep" sptr

#uselib "winmm.dll"
#func _timeBeginPeriod "timeBeginPeriod" sptr
#func _timeEndPeriod "timeEndPeriod" sptr
#cfunc global GTime "timeGetTime"

#undef await
#deffunc  await int w
	if tBP=0 {
		tBP=1
		_timeBeginPeriod 1
		tim=GTime()	
	}	
	_Sleep limit(w-(GTime()-tim),0,w)
	await@hsp 0
	tim=GTime()
return 

#deffunc timeEndPeriod onexit
	if tBP {
		_timeEndPeriod 1
	}
return
#global
c=1
repeat 20
	w++
	await 10	//awaitからawaitの時間を使うので
	ttim=GTime()
	tim=gettime(7)
	repeat c
		await w
	loop
	ttimcnt(cnt)=GTime()-ttim
	timcnt(cnt)=(gettime(7)-tim+1000)\1000
	
	mes strf("await %2d //timeGetTime() %5.2fms  //gettime(7) %5.2fms",w,double(ttimcnt(cnt))/c,double(timcnt(cnt))/c)
loop

後gettime(7)は本来の精度の1/10ぐらいしかないのでtimeGetTimeも使用

>>MNIGHTさん
>>正確に待つには何かFPSを保つ処理を作るか、await 30あたりで妥協するしかなさそうですね
FPSを保つ処理なら過去の質問にありましたから
await 30で妥協するよりはそちらのほうが良いかと…
win7でちゃんと使えるかわかりませんが…