HSPTV!掲示板

マウスをドラッグしたら軸を中心に点（座標）の
位置関係を維持したまま回転させたいのですが
なかなかできません。

↓のソースだと点が軸とマウス座標の線上に
全部集まってしまいます＞＜
わかる方がいましたらご教授ください。
よろしくお願いします。

dim ten,5:ddim x,5:ddim y,5
ten.0=1:x.0=0.0+rnd(320):y.0=0.0+rnd(240)
ten.1=1:x.1=0.0+rnd(320):y.1=0.0+rnd(240)
ten.2=1:x.2=0.0+rnd(320):y.2=0.0+rnd(240)

jikux=320
jikuy=240

repeat
	color 255,255,255:boxf

	getkey k1,1
	repeat 5
		if k1{
			vx=x.cnt-jikux
			vy=y.cnt-jikuy
			kyori=sqrt((vx*vx)+(vy*vy))
			r=atan(mousex-jikux,mousey-jikuy)
			x.cnt=sin(r)*kyori+jikux
			y.cnt=cos(r)*kyori+jikuy
		}

		if ten.cnt{
			color 0,0,0:pos x.cnt,y.cnt:mes "点"+cnt
			color 0,0,255:circle x.cnt-3,y.cnt-3,x.cnt+3,y.cnt+3
		}
	loop
	color 0,0,0:pos jikux,jikuy:mes "軸"
	color 255,0,0:circle jikux-3,jikuy-3,jikux+3,jikuy+3

	redraw:redraw 0
	await 30
loop

……マウス座標の角度しか算出してませんよ？
結果、みなマウス角度に。

各点の角度も求めて、それにマウス座標の角度を加えてください。（´ω｀）

追記。

初回クリック直後の角度をセンターとして記憶する必要もありますね。
そして以降のマウスダウン中の角度を、最初のと相対比較して移動値を計算。

がんばってください。（´ω｀）

返信ありがとうございます。
（´ω｀）さんの言われたことを頭にいれて
試行錯誤してたら無事できました。
ありがとうございました。

これで今年のHSPコンテストに向けた
プログラムが一歩前進しました！

念のためソースを載せときます。
では本当にありがとうございました。
失礼します。

dim ten,5:ddim x,5:ddim y,5:ddim r,5
ten.0=1:x.0=0.0+rnd(320):y.0=0.0+rnd(240)
ten.1=1:x.1=0.0+rnd(320):y.1=0.0+rnd(240)
ten.2=1:x.2=0.0+rnd(320):y.2=0.0+rnd(240)

jikux=320
jikuy=240

repeat
	color 255,255,255:boxf

	getkey k1,1
	rA=atan(mousex-jikux,mousey-jikuy)
	repeat 5
		if k1{
			vx=x.cnt-jikux
			vy=y.cnt-jikuy
			kyori=sqrt((vx*vx)+(vy*vy))
			r.cnt=atan(x.cnt-jikux,y.cnt-jikuy)+(rA-rB)
			x.cnt=sin(r.cnt)*kyori+jikux
			y.cnt=cos(r.cnt)*kyori+jikuy
		}
		if ten.cnt{
			color 0,0,0:pos x.cnt,y.cnt:mes "点"+cnt
			color 0,0,255:circle x.cnt-3,y.cnt-3,x.cnt+3,y.cnt+3
		}
	loop
	rB=atan(mousex-jikux,mousey-jikuy)

	color 0,0,0:pos jikux,jikuy:mes "軸"
	color 255,0,0:circle jikux-3,jikuy-3,jikux+3,jikuy+3

	redraw:redraw 0
	await 30
loop

うお、グルグル回るｗｗｗたのしーｗｗｗｗｗ

アドバイスだけして逆に楽しませていただいたという。
コンテスト、がんばってください。（*´ω｀*）

僕は絵が下手なので
関節（ボーン？）が付いたドット絵エディタ
みたいなのを作っていますｗ
ありがとうございました。がんばります！