IEコンポーネントでの話ですよね。
でしたらこちらが参考になると思います。
\sample\comobj\comtest7.hsp
ブラウジング中に検出したいということでしたらイベント割り込みを設定してあげると良いです。
// 割り込み設定
comevent ie_event, ie, DIID_DWebBrowserEvents2,*event
comtest7.hspをちょっと改造して最初にGoogleが表示、「HSP」が検出されるとHSP3掲示板に飛ぶようにしてみました。
いろんな割り込みイベントがあるので検索して調べてみると良いと思います。
; IEコンポーネントを使う
;
#define DIID_DWebBrowserEvents2 "{34A715A0-6587-11D0-924A-0020AFC7AC4D}"
#define DISPID_COMMANDSTATECHANGE 105
#define DISPID_BEFORENAVIGATE2 250
#define DISPID_NAVIGATECOMPLETE2 252
#define DISPID_ONQUIT 253
#define DISPID_ONMENUBAR 256
#define DISPID_ONSTATUSBAR 257
#define DISPID_ONFULLSCREEN 258
#define DISPID_WINDOWSETLEFT 264
#define DISPID_WINDOWSETTOP 265
#define DISPID_WINDOWSETWIDTH 266
#define DISPID_WINDOWSETHEIGHT 267
#define DISPID_ONTHEATERMODE 260
// Webページの表示が完了
#define DISPID_DocumentComplete 259
cls 1
sdim url,512
url="http://www.google.co.jp/"
objsize 600,24
pos 0,2:mes "URL:"
pos 0,26:mes "WEB Browser Sample"
pos 40,0:input url
objsize 120,24
pos 520,24:button "移動",*wow
pos 400,24:button "進む",*go_f
pos 280,24:button "戻る",*go_b
pos 0,48
axobj ie, "Shell.Explorer.2",640,480-48
num=stat
// 割り込み設定
comevent ie_event, ie, DIID_DWebBrowserEvents2,*event
ie->"Navigate" url
*main
stop
*event
; COMイベント処理
dispid = comevdisp(ie_event)
if dispid = DISPID_BEFORENAVIGATE2 : gosub *OnBeforeNavigate
if dispid = DISPID_NAVIGATECOMPLETE2 : gosub *OnNavigateComplete2
// Webページの表示が完了
if dispid = DISPID_DocumentComplete : gosub *OnDocumentComplete
return
// Webページの表示が完了
*OnDocumentComplete
pDoc = ie("Document")
pBody = pDoc("body")
name = pDoc("Title")
// HTMLソースを取得
HtmlSource = pBody("innerHTML")
// 「HSP」があればどこでもいつまでも反応してしまうため何かして弾く
if instr(name,0,"HSP3掲示板")=-1 {
// 検出・判定
if instr(HtmlSource,0,"HSP")!-1 {
dialog "「HSP」を検出。HSP3掲示板に移動します。"
// HSP3掲示板へ移動
ie->"Navigate" "http://hsptv.sakura.ne.jp/play/pforum.php"
}
}
return
*OnBeforeNavigate
comevarg name,ie_event,1
objprm 0,name
return
*OnNavigateComplete2
pDoc = ie("Document")
name = pDoc("Title")
title name
delcom pDoc
return
*wow
ie->"Navigate" url
goto *main
*go_f
ie->"GoForward"
goto *main
*go_b
ie->"GoBack"
goto *main