HSPTV!掲示板

初歩的な質問をして申し訳ありません。
http://www.geocities.jp/yosshiory/hsp/prg_04.jpg
このような色のプログレスバーを作りたいのですが

以下ソース

#define PBM_SETPOS   0x0402 ;位置設定
#define PBM_GETPOS   0x0408 ;位置取得
#define PBM_SETSTATE 0x0410 ;状態設定
#define PBM_GETSTATE 0x0411 ;状態取得

#define PBFS_PARTIAL 0x0004

#define PBS_MARQUEE  0x08
#define PBM_SETMARQUEE 0x040A 

    winobj "msctls_progress32", "", 0, $50000000, 200, 20
    h=objinfo(stat,2) 
    sendmsg h, PBM_SETPOS,75 
    sendmsg h,PBM_SETSTATE,PBFS_PARTIAL ;状態設定 
    sendmsg h, PBM_GETPOS, 0
    stop

http://www.geocities.jp/yosshiory/hsp_prg.html
こちらのサイトを参考にして作成しているのですが
なぜか青色のプログレスバーになりません。

青色のプログレスバーを作成するにはどうすればいいのでしょうか？
アドバイス等を頂けると嬉しいです。

Windowsテーマの問題なら下記でいいのかも知れません。

SetWindowTheme h,"", ""
stop
sendmsg h,$409 ,0,$ff
sendmsg h,$2001,0,$ff0000

WHOSさんの開発環境がVistaか7でないといくらやっても意味がないみたいなので
開発環境がVistaか7であることを祈ろう。
(自分はXPで第3引数を変えてやってみたけど意味がなかったことをここに記す。)

こんにちはー、A.Cです。
この記事の青色バーは、プログレスバーを配置しているのではなく
テーマの画像を直接描画しているだけです。
本物のプログレスバーでどうやって使うのかはわかりません。

以下、UxTheme.DLLのDrawThemeBackgroundを呼び出して描画する方法
（Windows7でのみ動作確認）

#uselib "UxTheme"
#func OpenThemeData "OpenThemeData" int, wstr
#func DrawThemeBackground "DrawThemeBackground" int, int, int, int, int, int
#func CloseThemeData "CloseThemeData" int
#define PP_BAR 1
#define PP_FILL 5
#define PBBS_NORMAL 1
#define PBFS_PARTIAL 0x0004
	if varptr(OpenThemeData) = 0 : mes "非対応環境" : stop
	OpenThemeData hwnd, "progress"	;プログレスバーを描画できるようにする
	hTheme = stat
	if hTheme = 0 : mes "非対応環境" : stop

	;描画（変数rは描画する範囲）
	pos 50, 50
	r = ginfo_cx, ginfo_cy, ginfo_cx+200, ginfo_cy+20
	DrawThemeBackground hTheme, hdc, PP_BAR, PBBS_NORMAL, varptr(r)		;下地
	r = ginfo_cx, ginfo_cy, ginfo_cx+150, ginfo_cy+20
	DrawThemeBackground hTheme, hdc, PP_FILL, PBFS_PARTIAL, varptr(r)	;青色バー

	redraw
	CloseThemeData hTheme	;使ったら閉じる
	stop

>>fortunehill様
なるほど。
参考になりました！！
ありがとうございます。

>>skyblue様
報告ありがとうございます。
参考になりました。

>>AC様
DrawThemeBackgroundを使うってちゃんと記事に書いてあったのにちゃんと読んでいませんでした。
すいません＞＜
それとソースまで提示して頂きありがとうございます＞＜

◇解決