HSPTV!掲示板

bgscr で作った枠なしウインドウの影を表示したいのですが
何か方法は有りますでしょうか？

Windows2000/XPより前のOSでは多分不可.
左ドラッグで移動、
右クリックで終了。

#include "user32.as"

w_width = 320
w_height = 240

bgscr 0,w_width,w_height,0
color 255,255,255 : boxf

bgscr 1,w_width,w_height,0
color 0,0,0 : boxf
GetWindowLong hwnd,-20
SetWindowLong hwnd,-20,stat|$80000
SetLayeredWindowAttributes hwnd,0xffffff,128,3

z=8
gsel 0
gosub *ON_WINDOW_MOVE

*MAIN_ROUTINE
	ps=s
	stick s,256 : ts=ps^s : rs=ts&ps : ts&=s
	if(s&512):end

	gsel 0
	if(ts&256):mx=ginfo_mx:my=ginfo_my:wx=ginfo_wx1-8:wy=ginfo_wy1-8:z=24
	if(s&256):width ,,wx-mx+ginfo_mx,wy-my+ginfo_my:gosub *ON_WINDOW_MOVE
	if(rs&256):z=8:width ,,ginfo_wx1+8,ginfo_wy1+8 : gosub *ON_WINDOW_MOVE
	await 1
	goto *MAIN_ROUTINE

*ON_WINDOW_MOVE
	w_x=ginfo_wx1:w_y=ginfo_wy1
	gsel 1
	width ,,w_x+z,w_y+z
	gsel 0,1
	return

ヴァー。
影ウインドウが他のウインドウの裏に回る・・・。
かといって安易に手前に持ってくるとチラつく・・・。

ゴメンちょっと時間ないのでリタイアorz

スクリプト有難うございます。

　出来れば、通常表示されているDEFAULTの影を表示したいのです。
　何か方法は有りますでしょうか？

こんにちはー、A.Cです。
WinXP以降なら CS_DROPSHADOW というウインドウクラスが追加されたみたいです。
これを現在のクラススタイルに追加してやると影がつきます。

#include "user32.as"
#define GCL_STYLE		-26
#define CS_DROPSHADOW	0x00020000
	bgscr 0,100,100,2 : onclick *e	;ウインドウを非表示で初期化
	GetClassLong hwnd,GCL_STYLE		;クラススタイルの取得
	SetClassLong hwnd,GCL_STYLE,stat|CS_DROPSHADOW	;CS_DROPSHADOWを追加
	gsel 0,1	;表示！
	stop
*e
	end

SYAM　さん
A.C さん

　有難うございます。おかげで解決しました。