HSPTV!掲示板

例えば
こんにちはhello

という文を、中央や右寄せに表示したいのですが
フォントのサイズが全角・半角と違うので、文の長さがわかりません

全角のフォントの幅のサイズ
半角のフォントの幅のサイズ
全角が何文字
半角が何文字
と調べるにはどうしたらいいでしょうか？

半角は1文字で全角は半角2文字分だよ。

GetTextExtentPoint32で文字列の幅と高さを取得できます

	#include "gdi32.as"

	screen 0, 640, 480
	moji = "こんにちはhello"

	GetTextExtentPoint32 hdc, varptr(moji), strlen(moji), varptr(size)

	pos 0, 0
	mes "左寄せ
	mes moji
	pos (ginfo_winx - size(0)) / 2, 0
	mes "中央"
	mes moji
	pos ginfo_winx - size(0), 0
	mes "右寄せ"
	mes moji

APIを使わなくてもginfo14と15でメッセージの幅と高さは取得できますよ。

color 255 :line 320,0,320,480 :color 0 :pos 0,0 ;センターライン
a="ABCDEFG"
mes a
mlen=ginfo(14)
mes "文字の描画幅 "+mlen
pos 640-mlen,0 :mes a  ;右寄せ
pos 320-mlen/2,0 :mes a  ;センタリング

a="ＡＢＣＤＥＦＧ"
pos 0,36 :mes a
mlen=ginfo(14)
mes "文字の描画幅 "+mlen
pos 640-mlen,36 :mes a  ;右寄せ
pos 320-mlen/2,36 :mes a  ;センタリング

font msmincho,20,1
a="新春シャンソンショー"
pos 0,72 :mes a
mlen=ginfo(14)
mes "文字の描画幅 "+mlen
pos 640-mlen,72 :mes a  ;右寄せ
pos 320-mlen/2,72 :mes a  ;センタリング

bufferに出力→ginfo_mesx ginfo_mesy

文字１つずつを計算するのではなく、文字列の長さをginfoで求めることが
できたんですね。
勉強になりました、皆さんありがとうございます。

右寄せとかをやりたいなら、WinAPIのDrawTextEx関数を使う手もあるよ

参考までに、DrawText関数にブン投げる方法〜。

#include "user32.as"

	string = "こんにちはhello"

	color $FF
	font "MS UI Gothic", 40, 1 | 16

	RECT = 0, 0, 640, 480

	DrawText hdc, string, -1, varptr(RECT), $1

	DrawText hdc, "\n" + string, -1, varptr(RECT), $2

	DrawText hdc, "\n\n" + string, -1, varptr(RECT), $0

	redraw

みなさん回答速いな…。
私からはいつものようにこの資料：
http://hspdev-wiki.net/?cmd=read&page=String%2F%B6%EB%B7%C1#g095da3b

こういうサイトもありますんで活用してくださいね。