ネット上に参考になりそうな文献があったのであげ
http://hikari-hinomoto.hp.infoseek.co.jp/PDF/DX7A02.pdf
正方形同士の当たり判定なら、NO.18049の�，諒�法で
tekix : 敵の座標X
tekiy : 敵の座標Y
s : 敵のサイズ＋見方のサイズ
if ((tekix-mousex)/s | (tekiy-mousey)/s) == 0
とすると、HSPでは速く判定でる．
tekix = ginfo_winx >> 1 ; 敵の座標
tekiy = ginfo_winy >> 1 ;
tekis = 20 ; 敵のサイズ
mikatas = 30 ; 見方のサイズ
s = tekis + mikatas
*main
if( ((tekix-mousex)/s | (tekiy-mousey)/s) == 0 ) {
dialog "hit"
}
redraw 0
color 255, 255, 255 : boxf : color
boxf tekix-tekis, tekiy-tekis, tekix+tekis, tekiy+tekis
boxf mousex-mikatas, mousey-mikatas, mousex+mikatas, mousey+mikatas
redraw
await 10
goto *main
それから、何かの役に立つと思い、矩形と点の当たり判断をする関数を作ってみた．
/*
|【ある点が矩形上にあるか調べる】
| onsquare array rect_x, array rect_y, int mx, int my
| rect_x : 矩形の頂点が代入された配列変数 (X 座標)
| rect_y : 矩形の頂点が代入された配列変数 (Y 座標)
| 配列は、左上(0),右上(1),右下(2),左下(3)の順番
| mx : 調べる点 (X 座標)
| my : 調べる点 (Y 座標)
|【戻り値】
| 0 : (mx, my)が矩形上にない
| 1 : (mx, my)が矩形上にある
*/
#module
#defcfunc onsquare array rect_x, array rect_y, int mx, int my
x1 = mx - rect_x(0)
y2 = my - rect_y(3)
x2 = rect_x(3) - mx
y1 = rect_y(0) - my
flg = 1
repeat 2, 1
a = rect_x(cnt) - rect_x(0)
b = rect_y(cnt) - rect_y(0)
// 線分と線分の重なりを調べる
if( (a*y1+b*x1 ^ a*y2+b*x2) >> 31 ) {
flg--
break
}
loop
return flg
#global
サンプル：
CX = ginfo_winx >> 1 ; 中心
CY = ginfo_winy >> 1 ;
PI = 3.1415926535897932384627
bsx = 300 ; 矩形の幅
bsy = 150 ; 矩形の高さ
ang = 0.0
x = -bsx/2, bsx/2, -bsx/2, bsx/2
y = -bsy/2, -bsy/2, bsy/2, bsy/2
*main
ang += 0.005
// 矩形：4つの頂点の座標を代入する
repeat 4
rect_x(cnt) = CX + cos(ang)*x(cnt) - sin(ang)*y(cnt)
rect_y(cnt) = CY + cos(ang)*y(cnt) + sin(ang)*x(cnt)
loop
// ヒットチェック
if( onsquare(rect_x, rect_y, mousex, mousey) ) {
title "hit"
} else : title ""
redraw 0
color 255, 255, 255 : boxf
color
grect CX, CY, ang, bsx, bsy
redraw
await 10
goto *main
矩形と点の当たり判断をするアルゴリズムは次のよう．
矩形を構成する線分の対象性を利用し
(mx, my) : マウスの座標
(gx, gy) : 矩形の重心
(sx, sy) : (gx, gy) を中点とした (mx, my) の対称点
として、矩形上の線分が(sx, sy)、(mx, my)内にあるか調べる．
これは2本の線分について調べるだけでよい．
これを解いて、式変形をしていくとかなり簡略化できる．
あたり判定
