HSPTV!掲示板

起動したプログラムを最前面（gsel 0,2）にしたり無効（gsel 0,1）にするには
以下のようなボタンを２つ使った方法でしか無理なのでしょうか？
１つのchkboxでチェックを付けたら最前面（gsel 0,2）、外したら無効（gsel 0,1）
と切り替えたいのですが思うようにできません。

button "ON1",*sc1
button "ON2",*sc2
stop
*sc1
gsel 0,1
stop
*sc2
gsel 0,2
stop

chkbox の変数内容をループの中で監視しても良いのですが、button の見た目をチェックボックスにしてしまう裏技を使うと簡単に監視ができます。

//	チェックボックス監視サンプル

;	普通にボタンを作成
	button gosub "最前面", *check
	hButton = objinfo(stat, 2)

;	ボタンのウィンドウスタイルを変更してチェックボックス化
	sendmsg hButton, $F4, $3

;	チェックボックスにチェックを入れる (BM_SETCHECK)
;	第3パラに 1=チェックあり、0=チェックなし
;	(標準のobjprm命令では制御できないため)
	sendmsg hButton, $F1, 0  // ← 最初からチェックボックスにチェックを入れたい場合に使う

	stop

*check
;	チェックボックスの状態を取得 (BM_GETCHECK)
;	statに 0=チェックなし、1=チェックありが返る
	sendmsg hButton, $F0
	value = stat

	gsel 0, 1 + value  // 最前面指定 [チェックあり: 2(=1+1), チェックなし: 1(=1+0)]
	return

以下リンクでKpanさんが分かりやすくまとめて下さっているので参考にしてみてください。
上記のサンプルスクリプトはほぼここからの抜粋です。

Let's HSP! - HSP3 あれこれ <オブジェクト 1>
http://lhsp.s206.xrea.com/hsp_object1.html

ループでチェック内容を取得したいならこのような方法があります。
MIZUSHIKIさんと被りますが、こちらのサイトが参考になります。
http://lhsp.s206.xrea.com/command/chkbox.html

scchk=0
tscchk=scchk
chkbox "ON",scchk
repeat
	gosub *sc
	await
loop
stop
*sc
	if tscchk=scchk:return
	if scchk=0{
		gsel 0,1
	}else{
		gsel 0,2
	}
	tscchk=scchk
	return

MIZUSHIKI様、
ボタンをチェックボックス化するなんて思いも付きませんでした。
試しましたところ思った通りの動作となり大変助かりました。

雪月夜様
こちらの方法も今後なにか作る時に参考にさせていただきます。

MIZUSHIKI様、雪月夜様　有難う御座いました。