HSPTV!掲示板

hsp3でiniファイルを読み込む方法を教えてください
リンク切れな古いページしか見つかりませんでした

やりたいこと

variable1="a"

が書かれたファイルを読み込み
dialog variable1
などで使用

(ホントは30個ほど項目があります,クオーテーションとかはなくてもいいです,空白改行は考えなくていいです)

リンクが切れていないことまでは確認済み
https://hsp.tv/play/pforum.php?mode=pastwch&num=39294#39318

自分のアプリからコードを引っ張ってきました。
私はこんなふうにしてます。

#uselib "kernel32.dll"
// 設定ファイル読み書き
#func WritePrivateProfileString "WritePrivateProfileStringA" sptr,sptr,sptr,sptr
#func GetPrivateProfileString "GetPrivateProfileStringA" sptr,sptr,sptr,sptr,sptr,sptr

#define INI_FILE "test.ini"	// 設定ファイル名
#define INI_SEC  "general"	// 設定ファイルのセクション名

filename=dir_cur+"\\"+INI_FILE
sdim s

// ini書き込み
setini filename,"valtest",""+255
setini filename,"strtest","これはテストテキストです。"
// ini読み込み
v=getini(filename,"valtest",0,0)
s=getini(filename,"strtest",0,1)
// 結果を表示
mes "v="+v
mes "s="+s
stop

// 設定ファイルから読み出し
// getini ファイル名, キー(文字列), デフォルト値, フラグ(0:数値 1:文字列)
#defcfunc getini str _s1, str _key, int _p1, int _p2
	sdim buf,1024	// 必要な文字列サイズ分確保のこと
	GetPrivateProfileString INI_SEC, _key, str(_p1), varptr(buf), 1024, _s1
	if _p2 { return buf }	// 文字列として返す
	return int(buf)			// 整数値として返す

// 設定ファイルに書き込み
// setini ファイル名, キー(文字列), 値(文字列)
#deffunc setini str _s1, str _key, str _s2
	WritePrivateProfileString INI_SEC, _key, _s2, _s1
	return

読み出しのところの1024とは1024バイト分まで対応するって意味です。
APIの後ろから2番目のパラメータと合わせてください。
ここまでのサイズが必要なければ、必要サイズに縮小して構いません。

補足。
読み出しのデフォルト値はキーが存在しなかった場合の戻り値に使われます。

Tomatoさん、ウィンドウの位置を取得する方のサンプルが動きません...

>Tomatoさん、ウィンドウの位置を取得する方のサンプルが動きません...

確かに提供モジュールだとサンプルコードが動きませんね。
サンプルコードを直してみましたが、これでどうでしょう？

;#include (上記のモジュール)
    gsel 0, -1
    gosub *LoadConfig    // 設定を読み込む
    
    // ウィンドウ表示
    screen 1, ginfo_dispx, ginfo_dispy, screen_hide
    title "INIサンプル"
    width windowSize(0), windowSize(1), windowPos(0), windowPos(1)
    gsel 1, 1
    
    mes "load: " + dir_cur + "/sample.ini"
    
    onexit goto *Exit
    stop
    
*Exit
    gosub *SaveConfig    // 終了時に保存する
    end
    
// 読み込み
*LoadConfig
    ini_setpath "./sample.ini"
    
    windowPos(0)  = ini_geti( "Window", "PosX" )    // 位置 (x, y)
    windowPos(1)  = ini_geti( "Window", "PosY" )
    windowSize(0) = ini_geti( "Window", "ClientX", 640 )    // 大きさ (x, y)
    windowSize(1) = ini_geti( "Window", "ClientY", 480 )
    return
    
// 保存
*SaveConfig
    ini_puti "Window", "ClientX", ginfo_winx
    ini_puti "Window", "ClientY", ginfo_winy
    ini_puti "Window", "PosX", ginfo_wx1
    ini_puti "Window", "PosY", ginfo_wy1
    return

今この話題を扱うなら、この作品について触れないわけにはいかないでしょう。
ini編集モジュール
https://dev.onionsoft.net/seed/info.ax?id=2367


しかし、個人的にお勧めしたいのはこちら。あまり宣伝してませんが、iniの読み書きモジュールが付属しています。
PAD設定さん IniEdit.as
https://mclab.uunyan.com/dl/dl11.htm

これとかどうですか
https://wiki.hsp.moe/INI%E3%83%95%E3%82%A1%E3%82%A4%E3%83%AB%E6%93%8D%E4%BD%9C%E3%83%A2%E3%82%B8%E3%83%A5%E3%83%BC%E3%83%AB.html