HSPTV!掲示板

IEコンポーネントでpdfを表示しようと思うのですが、ウィンドウをリサイズ可にしたいと思います。
しかし初心者の私にはウィンドウのリサイズに合わせてIEコンポーネントの大きさも変えることができません。
どなたかどうすればいいか教えていただけると幸いです。

こんな感じでどうでしょうか。pdfへのナビゲートは対応させていません。
各Win32API関数が何をしているかは関数名をググればすぐ出てきます。

#include "user32.as"

#define  global  GWL_STYLE  0xFFFFFFF0
#define  global  WS_SIZEBOX  0x00040000
#define  global  WS_MAXIMIZEBOX  0x00010000
#define  global  WM_SIZE  0x00000005

Screen 0, ginfo_dispx, ginfo_dispy, 0, , , 800, 600

// WM_SIZEメッセージはウィンドウリサイズに送られる
oncmd gosub *WhenWindowResized, WM_SIZE

// サイズ変更可能＆最大化可能にする
GetWindowLong hwnd, GWL_STYLE
SetWindowLong hwnd, GWL_STYLE, stat | WS_SIZEBOX | WS_MAXIMIZEBOX

axobj ie, "Shell.Explorer.2", ginfo_winx, ginfo_winy
hIE = objinfo_hwnd(stat)

ie->"Navigate" "www.onionsoft.net"

stop

*WhenWindowResized

  // IEコンポーネントをリサイズ
  MoveWindow hIE, 0, 0, ginfo_winx, ginfo_winy, 1

return

ありがとうございます。解決いたしました。

すみません。IEを使ったことで不都合な点(警告など)がいくつか見つかってしまったのでIEを使わずにPDFを表示したいのですが、
それは可能ですか？

「HSP PDF表示」で検索したらAcrobat Readerを使う方法が出てきましたよ。
http://lhsp.s206.xrea.com/hsp_com.html#pdf

一応上のリサイズサンプルと結合したサンプルも作っておきました。
当方の環境では問題なく表示できましたが、Adobe Readerがすべての環境で使えるのかが分からないのでそこは了承願います。

//  Adobe Reader - PDFファイルの表示 (by Kpan); modified
#include "user32.as"

#define CLSID_AcroPDF "{CA8A9780-280D-11CF-A24D-444553540000}"

#define  global  GWL_STYLE  0xFFFFFFF0
#define  global  WS_SIZEBOX  0x00040000
#define  global  WS_MAXIMIZEBOX  0x00010000
#define  global  WM_SIZE  0x00000005

Screen 0, ginfo_dispx, ginfo_dispy, 0, , , 800, 600

// WM_SIZEメッセージはウィンドウリサイズに送られる
oncmd gosub *WhenWindowResized, WM_SIZE
onexit goto *exit


// サイズ変更可能＆最大化可能にする
GetWindowLong hwnd, GWL_STYLE
SetWindowLong hwnd, GWL_STYLE, stat | WS_SIZEBOX | WS_MAXIMIZEBOX

// 読み込みボタン
objsize 80, 20
pos 0, 0
button gosub "読み込み", *LoadPDF
hButton = objinfo_hwnd(stat)

// Adobe Acrobat Reader
pos 0, 20
axobj AcroPDF, CLSID_AcroPDF, ginfo_winx, ginfo_winy - 20
if (stat == -1) : dialog "error", 1 : end
hAPDF = objinfo_hwnd(stat)

stop


*WhenWindowResized

  // リサイズ
  MoveWindow hAPDF, 0, 20, ginfo_winx, ginfo_winy - 20, 1

return


*LoadPDF
	dialog "pdf", 16, "PDFファイル"
	if (stat == 0) : return

	AcroPDF->"LoadFile" refstr

return

*exit
	delcom AcroPDF

end

ありがとうございます。