HSPTV!掲示板

hspで、ある特定のサイトにアクセスできなくなるようにしたいのですが、それはどうすればいいでしょうか。

#include "user32.as"
// ie event
#define DIID_DWebBrowserEvents2     "{34A715A0-6587-11D0-924A-0020AFC7AC4D}"
// exdispid.h
#define DISPID_BEFORENAVIGATE2      250   // hyperlink clicked on

#packopt hide 1
    // ウィンドウ最大化を可能にする
    // 参考 -> http://lhsp.s206.xrea.com/hsp_window.html

    sdim BlockURL
    BlockURL="https://www.youtube.com/"
    
    screen 0, ginfo_dispx, ginfo_dispy, screen_hide
    GetWindowLong hwnd, -16
    SetWindowLong hwnd, -16, stat | $10000 | $40000

    // ActiveXコントロール（IEコンポーネント）の配置
    axobj ieBrowser, "Shell.Explorer.2"
    idIE = stat
    if idIE == -1 {
        dialog "ActiveXコントロールの配置に失敗しました。", 1
        end
    }

    ieBrowser->"Navigate" "http://www.yahoo.co.jp/"

    // 割り込み設定
    comevent ieEvent, ieBrowser, DIID_DWebBrowserEvents2, *event_ie
    oncmd gosub *event_resize, 0x0005
    onexit goto *exit

    width 640, 480
    gsel 0, 1
    stop

// COMイベント発生時のジャンプ先
*event_ie
    if comevdisp(ieEvent) == DISPID_BEFORENAVIGATE2 {
        // URLを取得
        comevarg newurl, ieEvent, 1, 1
        if instr(newurl,0,BlockURL)!-1 {
	       dialog"このサイトにはアクセスできません。",1
            comevarg Cancel, ieEvent, 6, 2
            Cancel("val") = 1
            delcom Cancel
            ieBrowser->"GoBack"
        }
    }
    return

// ウィンドウのリサイズ
*event_resize
    MoveWindow objinfo(idIE, 2), 0, 0, ginfo_winx, ginfo_winy, 1
    return

// プログラムの終了処理
*exit
    oncmd 0 : onexit 0
    delcom ieEvent
    delcom ieBrowser
    end

以下のサイトのソースを改造して作りました

http://rpen.blogspot.com/2008/01/ie.html

BlockURL変数の値を変更することでブロックするサイトを変更できます。