HSPTV!掲示板

スレッド一覧 | 新規書き込み | 新着一覧 | 使い方 | 過去ログ

未解決

解決

停止

削除要請


	2018 0925	初心者	Windows のスタートメニューのようなもの	4

初心者

2018/9/25(Tue) 16:02:40|NO.85441

Windows のスタートボタンのようなものが作りたいです。
一回ボタンを押すと、boxf命令で四角形を描画。
もう一度ボタンを押すと、描画した四角形を消す、といったものです。
分かりにくいかもしれませんが、回答よろしくお願いします。

この記事に返信する

沢渡

2018/9/25(Tue) 18:34:20|NO.85442

こんな感じでしょうか？
メイン画面の内容をあらかじめ裏画面にコピーしておき、四角形を消すときは裏画面からコピーするようにしています。



#define global boxf2(%1,%2,%3,%4) boxf %1,%2,(%1)+(%3)-1,(%2)+(%4)-1	//座標(%1,%2)に、幅%3、高さ%4の四角形を描く

//裏画面バッファを作成
buffer 1,640,480,0 : gsel 0
#define mirror gsel 1 : pos 0,0 : gcopy 0,0,0,640,480 : gsel 0	//メイン画面の内容を裏画面にコピー
#define back(%1,%2,%3,%4) pos %1,%2 : gcopy 1,%1,%2,%3,%4

//背景を描画
repeat 15
	if cnt\2 : color 128,128,0 : else : color 0,0,128
	boxf2 0,32*cnt,640,32
loop
mirror

flag=0	//ボックスを表示しているフラグ
objsize 100,30
pos 0,450 : button gosub "スタート",*toggle
stop

*toggle
if flag {
	flag=0
	back 10,200,150,230
} else {
	flag=1
	color 0,240,240
	boxf2 10,200,150,230
}
return

たかし

2018/9/25(Tue) 19:54:22|NO.85443

私が途中まで作ったOSもどきです。参考にしてみてください。
※これを改造する行為はおやめください

http://fast-uploader.com/file/7093428369726/

名無し

2018/9/29(Sat) 17:33:28|NO.85472

①メニューを「描画がするかしないか」の変数を用意する

②カーソル座標がある範囲内に存在するかを取得する

以下は取得するモジュール。




#module __HSP3MEX__

	#deffunc minit
		W = (ginfo(10) - ginfo(12)) / 2
		T = ginfo(11) - ginfo(13) - W
		return 0

	#undef mousex
	#defcfunc mousex
		return ginfo(0) - ginfo(4) - W

	#undef mousey
	#defcfunc mousey
		return ginfo(1) - ginfo(5) - T

	#defcfunc GetMouseRectPointer int prm1, int prm2, int prm3, int prm4
		minit
		x1 = prm1
		y1 = prm2
		x2 = prm3
		y2 = prm4
		if mousex() >= x1 & mousey() >= y1 & mousex() <= x2 & mousey() <= y2 {
			return 1
		}
		return 0

#global

	// 変数宣言
	MenuButtonSize = 32 ; メニューボタンのサイズ(正方形とする)

	// メイン処理
	repeat
		redraw 0
		color 255, 255, 255
		boxf
		color 40, 40, 40
		boxf 0, ( 480 - MenuButtonSize ), MenuButtonSize, 480
		if GetMouseRectPointer( 0, ( 480 - MenuButtonSize ), MenuButtonSize, 480 ) {
			title "メニューボタンの所にカーソルを発見！"
		} else {
			title "座標XY " + mousex() + " , " + mousey()
		}
		redraw 1
		await 16
	loop

※通常のHSP関数 mousex mousey が mousex() mousey() になっているのは、
　オブジェクト上にマウスが合っても取得するためです。
　元関数が存在した場合は置換か何かで修正してください。

③②のモジュールの GetMouseRectPointer関数が範囲内になるとTRUE(1)になり、
　それ以外だとFALSE(0)になることを抑える。

④上記の新関数で戻り値が TRUE の時に stick 命令で左クリックをした時に
　①の変数を変数 = 変数 ^ 1 にする。
　↑にすることで変数がFALSEの時にTRUEになり、TRUEの時にFALSEになる。

⑤①の変数がTRUEの時にメニューとなる描画命令を記入すれば完成となる。

結局は以下のスクリプトになる。




#module __HSP3MEX__

	#deffunc minit
		W = (ginfo(10) - ginfo(12)) / 2
		T = ginfo(11) - ginfo(13) - W
		return 0

	#undef mousex
	#defcfunc mousex
		return ginfo(0) - ginfo(4) - W

	#undef mousey
	#defcfunc mousey
		return ginfo(1) - ginfo(5) - T

	#defcfunc GetMouseRectPointer int prm1, int prm2, int prm3, int prm4
		minit
		x1 = prm1
		y1 = prm2
		x2 = prm3
		y2 = prm4
		if mousex() >= x1 & mousey() >= y1 & mousex() <= x2 & mousey() <= y2 {
			return 1
		}
		return 0

#global

	// 変数宣言
	MenuFlag = 0 ; メニューを「描画がするかしないか」
	MenuButtonSize = 32 ; メニューボタンのサイズ(正方形とする)

	// メイン処理
	repeat
		stick key ; キー管理
		redraw 0
		color 255, 255, 255
		boxf
		color 40, 40, 40
		boxf 0, ( 480 - MenuButtonSize ), MenuButtonSize, 480
		if GetMouseRectPointer( 0, ( 480 - MenuButtonSize ), MenuButtonSize, 480 ) {
			title "メニューの所にカーソルを発見！"
			if key = 256 {
				dialog "クリック!!"
				MenuFlag ^= 1
			}
		} else {
			title "座標XY " + mousex() + " , " + mousey()
		}
		if MenuFlag = 1 {
			color 0, 128, 255
			boxf 0, 0, 160, ( 480 - MenuButtonSize )
		}
		redraw 1
		await 16
	loop

これは自己中心的に作った手抜きスクリプトのオブジェクトを使わない派のやり方なので、
オブジェクトを使う派なら．．．頑張ってくれ。

初心者

2018/10/20(Sat) 21:11:36|NO.85625

皆様ありがとうございました。
OSもどきで使おうと思います。
ご覧になりたい方はマスコットの下のHPで飛べるはずです。
(まあ誰も使わんだろうね)