HSPTV!掲示板

おにぎりです。

数字あてゲームのようなものを作っています。
１ターン終わるごとに出てくる数字を記憶していって、過去の記録として画面上に書く。
ということをしたいのです。

ただ、変わっていく数字を、違う関数にどんどん保存していくという方法がわかりません。
構想だけでもいいので教えてくださるとありがたいです。

スタック構造とかどうですか？
https://ja.wikipedia.org/wiki/スタック
以前はアルティメットさんのとこで　講座書いてたんですけどLINK切れでして
手前味噌ですが　それっぽいの以前書きました
http://zuzazann.main.jp/wiki4/index.php?ws_010_stack

溜めっぱなしもよくなさそうですが
大量に溜めるケースでもなさそうですね

追記
こっちの方がいいかな？
https://wiki.hsp.moe/ラボ／スタック.html

HSPではモジュールとか使わない限り変数はグローバルなので
配列変数で充分なのでは？

１ターンで出て来る数字が複数あるのなら
２次元配列にするという手もあります。

スペースを押すたびにサイコロを振り、履歴を配列変数に最大30件登録し、
オーバーした分は過去の分から消えていくというサンプルを作ってみました。

#const max 30	//履歴の最大数

dim past,max	//履歴
p_num=0	//履歴の件数
dice=-1	//サイコロの目。-1の場合はまだ振っていない状態

randomize

onkey gosub *roll
stop

*roll
	if iparam!=32 : return	//スペースキーを押した時のみ反応
	if dice!=-1 {
		repeat max-1 : past(max-1-cnt)=past(max-2-cnt) : loop	//履歴を後ろに1つシフト
		//memcpy past,past,max*4-4,4,0	//たぶん↑よりもこちらの方が早い
		past(0)=dice : p_num=limit(p_num+1,0,max)	//件数はmaxは超えない
	}
	dice=(rnd(6)+1)+(rnd(6)+1)	//6面サイコロを2つ振る
	color 255,255,255 : boxf
	color 0,0,0
	pos 0,0 : mes "サイコロの目："+strf("%2d",dice)
	pos 0,40 : mes "履歴"
	//履歴を表示
	repeat p_num
		pos 30*(cnt\10),20*(cnt/10)+60
		mes strf("%2d",past(cnt))
	loop
	return

ありがとうございます〜。
参考になります！