HSPTV!掲示板

下記のURLで昨日質問した者です。
http://hsp.tv/play/pforum.php?mode=all&num=75204

IEのコンポーネントを利用してInstGramに自動ログインするために以下のコードを書きました。

newcom IE, "InternetExplorer.Application"
IE->"Navigate" "https://www.instagram.com/accounts/login/"
IE("Visible")=1
repeat : wait 10 : if IE("ReadyState")=4 { break } : loop
repeat : wait 10 : pDoc = ie("Document") : if pDoc("ReadyState") = "complete" { break }: loop

repeat
	DocumentElement=IE("Document")

	comres UserNameElement
	DocumentElement->"getElementsByName" "username"
	comres PassWordElement
	DocumentElement->"getElementsByName" "password"
	comres TagElement
	DocumentElement->"getElementsByTagName" "button"

	if (UserNameElement("length") != 0){
		UserNameRoot=UserNameElement("item",0)
		UserNameRoot("value")="UserName"
	}
	
	if (PassWordElement("length") != 0){
		PassWordRoot=PassWordElement("item",0)
		PassWordRoot("value")="PassWord"
	}

	if (TagElement("length") != 0){
		TagRoot=TagElement("item",0)
		TagRoot->"click"
		break
	}
	wait 10
loop

正常にIDとPWが入力されログイン出来ると思いきや、「入力された情報は存在しない。」と表示されます。
調べた所見た目は入力されているが実際には入力されていないようになっているみたいです。
※これはプログラムがサイトにIDPWを打ち込む前に手動で撃ち込んだ後にそのまま自動ログインさせるとわかります。

ですので、どのようにコードを書けばよろしいでしょうか?
よろしくお願い致します。

こんな感じでしょうか。

	newcom IE, "InternetExplorer.Application"
	IE->"Navigate" "https://www.instagram.com/accounts/login/"
	IE("Visible")=1
	repeat : wait 10 : if IE("ReadyState")=4 { break } : loop
	repeat : wait 10 : pDoc = ie("Document") : if pDoc("ReadyState") = "complete" { break }: loop

	// inputイベントを発火させるために必要
	// （IE11でしか動かないかも？）
	comres InputEvent
	pDoc->"createEvent" "HTMLEvents"
	InputEvent->"initEvent" "input", 1, 0
		
	repeat
		DocumentElement=IE("Document")
	
		comres UserNameElement
		DocumentElement->"getElementsByName" "username"
		comres PassWordElement
		DocumentElement->"getElementsByName" "password"
		comres TagElement
		DocumentElement->"getElementsByTagName" "button"
	
		if (UserNameElement("length") != 0){
			UserNameRoot=UserNameElement("item",0)
			UserNameRoot("value")="ユーザー名"
			comres dummyRet	// ないと TagElement が上書きされる
			// 値を変更したらinputイベントを発火する
			UserNameRoot->"dispatchEvent" InputEvent
		}
		
		if (PassWordElement("length") != 0){
			PassWordRoot=PassWordElement("item",0)
			PassWordRoot("value")="パスワード"
			comres dummyRet	// ないと TagElement が上書きされる
			// 値を変更したらinputイベントを発火する
			PassWordRoot->"dispatchEvent" InputEvent
		}
	
		if (TagElement("length") != 0){
			TagRoot=TagElement("item",0)
			TagRoot->"click"
			break
		}
		wait 10
	loop

>>inoviaさん
掲載して頂いたコードで完璧に動作しました。
1日調べても分からなかったので本当に助かりました!!
ご丁寧な回答ありがとうございました＞＜!!