HSPTV!掲示板

ソフト全般に備わっている「名前をつけて保存」と「開く」機能をつけたいのですが
うまくいきません

title "カウント"
screen 0,400,300

a=0
b=0
c=0
d=0

*main 
pos 20,20
color 0,0,0
mes a
pos 20,40
color 0,0,0
mes b
pos 20,60
color 0,0,0
mes c
pos 20,80
color 0,0,0
mes d

//ボタンの位置とサイズ
pos 50,20
objsize 80,20
button "a",*hidari

pos 50,40
objsize 80,20
button "b",*nakahidari

pos 50,60
objsize 80,20
button "C",*nakamigi

pos 50,80
objsize 80,20
button "d",*migi
stop
//メイン表示ここまで
*hidari
	a=a+1
	cls
	goto *main
	
*nakahidari
	b=b+1
	cls
	goto *main

*nakamigi
	c=c+1
	cls
	goto *main

*migi
	d=d+1
	cls
	goto *main

これにセーブとロードをできればボタンでつけたいと思っているのですがどうすれば
いいのでしょうか？　いろいろ検索してためしてみたのですが出来ませんでした……
セーブ、ロードするのはa,b,c,dの数値です

また初心者なのでスクリプト自体におかしいところがあればご指摘していただけると嬉しいです。

いくつか方法がありますが、簡単な方法を１つ。
数値を , 区切りの文字列にしてファイルに保存する方法。

	screen 0,400,300
	title "カウント"

	//ボタンの位置とサイズ
	pos 50,20
	objsize 80,20
	button gosub "a",*hidari
	button gosub "b",*nakahidari
	button gosub "c",*nakamigi
	button gosub "d",*migi
	mes
	button gosub "SAVE",*save
	button gosub "LOAD",*load
	button gosub "RESET",*reset

	gosub *reset

*main
	redraw 0
	color 255,255,255: boxf	// クリア
	color 0,0,0
	pos 20,20
	mes a
	mes b
	mes c
	mes d
	redraw 1
	await 16
	goto *main	// ループ

//メイン表示ここまで

*hidari
	a++
	return
	
*nakahidari
	b++
	return

*nakamigi
	c++
	return

*migi
	d++
	return

*save
	datastr=""+a+","+b+","+c+","+d
	bsave "data.txt",datastr
	return

*load
	bload "data.txt",datastr
	split datastr,",",a,b,c,d
	a=int(a): b=int(b): c=int(c): d=int(d)
	return

*reset
	a=0: b=0: c=0: d=0
	sdim datastr
	return

>「名前をつけて保存」
と書いているので

dialog "message",17,"option"
使った方が良さそうですね

*save
	dialog "FILEを選んでください",17,"txt"
	datastr=""+a+","+b+","+c+","+d
	bsave refstr,datastr
	return

みたいかんじで

お二方のを参考に求めているものが出来ました。
助言有難うございました