HSPTV!掲示板

高解像度のディスプレイだとwebページの文字が細かすぎて読みづらいことありますよね。
私はよくブラウザの拡大・縮小で全体を拡大して表示させています。

この機能を、可能なら自作のHSP製ブラウザにも付けたいのですが
javascriptなら document.body.style.zoom='150%' とかいうのが使えることが分かったのですが、
HSPではどのようにしたら良いのか分からず困っています。

どなたか知恵を貸していただけないでしょうか。

出来ました。HDLのソースにヒントがありました。

	;

	;	IEコンポーネントを使ったブラウザ
	;
#define DIID_DWebBrowserEvents2     "{34A715A0-6587-11D0-924A-0020AFC7AC4D}"
#define DISPID_NAVIGATECOMPLETE2    252

#define OLECMDID_OPTICAL_ZOOM		63

	cls 1
	sdim url,512
	url="http://hsp.tv/"
	objsize 600,24
	pos 0,2:mes "URL:"
	pos 0,26:mes "WEB Browser Sample"
	pos 40,0:input url
	objsize 80,24
	pos 560,24:button "移動",*wow
	pos 480,24:button "進む",*go_f
	pos 400,24:button "戻る",*go_b
////////////////ボタン追加////////////////
	pos 160,24:button "縮小(50%)",*zoomdown
	pos 240,24:button "通常(100%)",*normal
	pos 320,24:button "拡大(200%)",*zoomup
////////////////以上////////////////
	pos 0,48
	axobj ie, "Shell.Explorer.2",640,480-48
	num=stat
	comevent ie_event, ie, "{34A715A0-6587-11D0-924A-0020AFC7AC4D}",*event	; DIID_DWebBrowserEvents2     
	ie->"Navigate" url
*main
	stop
*event
	;	COMイベント処理
	dispid = comevdisp(ie_event)
	if dispid = DISPID_NAVIGATECOMPLETE2 : gosub *OnNavigateComplete2
	return

*OnNavigateComplete2
	name = ie("LocationURL")
	objprm 0,name
	pDoc = ie("Document")
	name = pDoc("Title")
	title name
	delcom pDoc
	return
*wow
	ie->"Navigate" url
	goto *main
*go_f
	ie->"GoForward"
	goto *main
*go_b
	ie->"GoBack"
	goto *main

*normal
	zoom = 100	; 100%
	ie-> "ExecWB" OLECMDID_OPTICAL_ZOOM,0,zoom,0
	goto *main

*zoomup
	zoom = 200	; 200%に拡大
	ie-> "ExecWB" OLECMDID_OPTICAL_ZOOM,0,zoom,0
	goto *main

*zoomdown
	zoom = 50	; 50%に縮小
	ie-> "ExecWB" OLECMDID_OPTICAL_ZOOM,0,zoom,0
	goto *main

解決です。