HSPTV!掲示板

	mouse -1
	repeat : await : loop

↑しっかり消えたまま

	mouse -1 : mouse 100,100
	repeat : await : loop

↑oh...

どうしたらいいのでしょうか？
というか、パラメーターを省略した場合のみ非表示から表示に切り替わると書いてあるのに、パラメーター指定（しかも正数）した場合でも表示になってしまうのはバグですか？
それとも自分のミスでしょうか？（九割九分九厘こちらだと思いますが・・・）

というか別に下のループ文いりませんでしたね

調整してから消すのではダメなのか？

ループ内で何度も調整するので、調整後に消すって手段は使えないですね・・・。
また、調整してから消してをループでやると、カーソルがチカチカと見え隠れするのでよろしくないです。

あぁ、説明書には書かれていないけど、マウス非表示になるのは、自身が管理しているウィンドウ上のみだからね。
他のウィンドウ上及びデスクトップ上では、表示のままになるので注意。

ウィンドウ上のみというのは承知しています。

こんばんは。(お久しぶり。)

↓こういうのはどうでしょう？

#uselib "user32.dll"
#func SetCursorPos "SetCursorPos" int,int
#func ShowCursor "ShowCursor" int

width  , ,0,0

mes "1秒後にカーソルを消します。"
mouse 100,100
wait 100

mouse -1
SetCursorPos 300,400
mes "出現まで2秒..."
wait 200

mouse
mes "出現しました。"

失礼。先ほどのコードの3行目は不要です。

>FunnyMakerさん

うーん、すみません、ちょっと違います。
やりたいのはこういうことです。

	#define scrx ginfo(4)
	#define scry ginfo(5)
	#define cntx ginfo_winx/2
	#define cnty ginfo_winy/2

	//　ここでマウス非表示
	mouse -1
	
	repeat
	
		//　スペースキーを押したとき、マウスをウィンドウ中央へ
		//　（※実際の中央とは若干ズレますが・・・）
		stick key
		if(key&16) : mouse scrx+cntx,scry+cnty
		//↑実行したときにマウスが表示されてしまう
		
		await
	loop

>kanahironさん

＞それだとスクリーン座標指定なのでウィンドウをずらすとカーソルがおかしくなりません？

確かにそうですね。座標変換手段まで示した方が良かったですね。
方法はkanahironさんのモジュールまさにその通りです。

<文章もおかしかったので投稿しなおしました>

それだとスクリーン座標指定なのでウィンドウをずらすとカーソルがおかしくなりません？

#module

#uselib "user32.dll"
#func SetCursorPos "SetCursorPos" int, int
#func ClientToScreen "ClientToScreen" int,int

#deffunc setmouse int p1,int p2
	Point = p1,p2
	ClientToScreen hwnd,varptr(point)
	SetCursorPos point.0,point.1
return

#global

//以下サンプル


	mousef = 1
	
	repeat
	
		x = rnd(640)
		y = rnd(480)
		setmouse x,y
		
		title strf("%03d,%03d",x,y)
	
		repeat 60
			stick cli
			if cli{
				if mousef = 0{
					mouse
					mousef = 1
				} else {
					mouse -1
					mousef = 0
				}
			}
			await 33
		loop
		
	loop

mouseで座標を指定しているところをsetmouseに置き換えてください
サンプルは2秒ごとにカーソルがランダムで移動し、クリックすると
カーソル表示と非表示が入れ替わります

プログラムに組み込むときは、#moduleから#globalまでをスクリプトの頭に貼って下さい

>kanahironさん

おお、素晴らしいです！
しかし、やはり外部dllを呼ばないと出来ないことなのでしょうか？
出来ればリファレンス通り、mouse -1とmouseでのみ切り替えが出来るようにしてもらいたいものです。
何はともあれ、皆さんありがとうございました。

システムカウンタで管理されているのを利用してみるとか。

#define scrx ginfo(4)
#define scry ginfo(5)
#define cntx ginfo_winx/2
#define cnty ginfo_winy/2

	//　ここでマウス非表示
	mouse -1
	
	repeat
	
		//　スペースキーを押したとき、マウスをウィンドウ中央へ
		//　（※実際の中央とは若干ズレますが・・・）
		stick key
		if(key&16) : mouse -1 : mouse scrx+cntx,scry+cnty
		//↑実行したときにマウスが表示されてしまう
		
		await
	loop

その発想はなかったです…
さすがinoviaさん…

>やはり外部dllを呼ばないと出来ないことなのでしょうか？
使用しているDLLはWindowsなら必ずインストールされているから
特に気にする必用はないが、HSPのmouse命令だけでは氏のやりたいことは不可能だな。

mouse -1 は回数をカウントしていて
0にならないと表示されません
マウスカーソル座標設定で表示させたくないなら
移動させる前に更にmouse -1しておけば良い

randomize

mouse -1 //とりあえずHSPウィンドウ上で非表示に（ここでカウント1）
repeat 100
	title ""+cnt
	stick k
	if k{end}
	color rnd(255),rnd(255),rnd(255)
	x=ginfo_wx1+rnd(560)+40
	y=ginfo_wy1+rnd(400)+40
	repeat 20
		mouse -1 //移動前にもう一度非表示（ここでカウント2）
		mouse x+40-rnd(80),y+40-rnd(80)//（ここでカウント1なのでまだ非表示のまま）
		pos ginfo_mx-ginfo_wx1,ginfo_my-ginfo_wy1
		mes "*"
	loop
	await 16
loop
mouse //カウント0になり表示される

>inovia

あ・・・。
それ順番入れ替えると点滅もしませんね・・・。
位置調整の後に消すというのをループで回すのは試したのですが、その逆をやっておらず気づきませんでした。

点滅する

#define scrx ginfo(4)
#define scry ginfo(5)
#define cntx ginfo_winx/2
#define cnty ginfo_winy/2
	mouse -1
	repeat
		stick key
		if(key&128) : end
		mouse scrx+cntx,scry+cnty
		mouse -1
		await
	loop

しない。

#define scrx ginfo(4)
#define scry ginfo(5)
#define cntx ginfo_winx/2
#define cnty ginfo_winy/2
	mouse -1
	repeat
		stick key
		if(key&128) : end
		mouse -1
		mouse scrx+cntx,scry+cnty
		await
	loop

盲点でした・・・。

>inoviaさん
すみません敬称をつけ忘れていました。失礼しました。

動作テストしながら書き込んでる間に・・・

>暇人さん

なるほどそういうことでしたか。
納得いきました。