HSPTV!掲示板

HSP初心者です。HSPでブラウザを作ってみたいと思い、ボタン等は表示したのですが、
IEコンポーネントについてがよくわかりません。

    #include "user32.as"
	screen 0, ginfo(20), ginfo(21)
	GetWindowLong hwnd, -16
	SetWindowLong hwnd, -16, stat | $10000 | $40000
	width 1100, 750
	title "ブラウザ　β1.0"
	cls 1.9
	objmode 2
	font "ＭＳ ゴシック",12,0
	objsize 60,30 
	pos 10,10 
	button "＜＜",*Button1
	objsize 45,30
	pos 75,10
	button "＞＞",*Button2
	pos 150,10
	button "ホーム",*Button3
	pos 200,10
	button "更新",*Button4
	pos 250,10
	button "中止",*Button5
	pos 340,18
	mes "URL:"	
	pos 370,15
	input1="http://ここに入力/"
	input input1,630,20,
	pos 1008,10
	button "移動",*Button6
	stop
*Button1
	stop
*Button2
	stop
*Button3
	stop
*Button4
	stop
*Button5
	stop
*Button6
	stop

という感じなのですが、続き・修正をしてもらえないでしょうか？

とりあえず、スクリプトエディタでF1キーを押して「ＨＳＰキーワード検索」を起動し、「IE」で検索してみてください。
お探しのサンプルが見つかりますよ。

見ては見たのですがよくわかりませんでした。できればスクリプトを書いてくれるとうれしい
のですが…

どこがどう分からないのかを自分で理解していないと、
サンプルを書いても分からないでしょう。

私も詳しくはないのですが、サンプルのcomtest7.hspを参考にするとこうなりました。
IEコンポーネントを使ったブラウザの作り方についての質問はよくあるので、ここの掲示板の過去ログを
検索してみるといろいろ参考になると思いますよ。

	;	IEコンポーネントを使う

	;
#define DIID_DWebBrowserEvents2     "{34A715A0-6587-11D0-924A-0020AFC7AC4D}"

#define DISPID_COMMANDSTATECHANGE   105
#define DISPID_BEFORENAVIGATE2      250
#define DISPID_NAVIGATECOMPLETE2    252
#define DISPID_ONQUIT               253
#define DISPID_ONMENUBAR            256
#define DISPID_ONSTATUSBAR          257
#define DISPID_ONFULLSCREEN         258
#define DISPID_WINDOWSETLEFT        264
#define DISPID_WINDOWSETTOP         265
#define DISPID_WINDOWSETWIDTH       266
#define DISPID_WINDOWSETHEIGHT      267
#define DISPID_ONTHEATERMODE        260

	sdim url,512
		url="http://www.onionsoft.net"
	sdim homeurl,512
		homeurl="http://www.hsp.tv"

	screen 0,1100,750,0
	title "ブラウザ　β1.0"

	cls 1
	objmode 2
	font "ＭＳ ゴシック",12,0

	objsize 60,30 
	pos 10,10 
	button "＜＜",*Button1

	objsize 45,30
	pos 75,10
	button "＞＞",*Button2
	pos 150,10
	button "ホーム",*Button3
	pos 200,10
	button "更新",*Button4
	pos 250,10
	button "中止",*Button5
	pos 340,18
	mes "URL:"	
	pos 370,15
	input1="http://ここに入力/"
	input input1,630,20
	inputid = stat
	pos 1008,10
	button "移動",*Button6

	pos 0,50
	axobj ie, "Shell.Explorer.2",1100,700
	num=stat
	comevent ie_event, ie, DIID_DWebBrowserEvents2,*event
	ie->"Navigate" url

*main
	stop
		
*event
	;	COMイベント処理
	dispid = comevdisp(ie_event)
	if dispid = DISPID_BEFORENAVIGATE2 : gosub *OnBeforeNavigate
	if dispid = DISPID_NAVIGATECOMPLETE2 : gosub *OnNavigateComplete2
	return

*OnBeforeNavigate
	comevarg name,ie_event,1
	objprm inputid,name
	return

*OnNavigateComplete2
	pDoc = ie("Document")
	name = pDoc("Title")
	title name
	delcom pDoc
	return

*Button1
	ie->"GoBack"
	goto *main
*Button2
	ie->"GoForward"
	goto *main
*Button3
	ie->"Navigate" homeurl
	goto *main
*Button4
	goto *main
*Button5
	goto *main
*Button6
	ie->"Navigate" url
	goto *main

まあKAさんのおっしゃる事ももっともだと思いますが。
「どこがわからないのかもわからない」のが初心者の初心者たる所以ですので。

ありがとうございます！更新ボタンと中止ボタンは何とか自分で解決できましたが、
移動ボタンを押すと

	sdim url,512
		url="http://www.onionsoft.net"

のアドレス戻ってしまうのですがどうしてでしょうか？

ああ本当だ！失礼しました。
最後の部分を次のように書き変えてください。これで移動できると思います。

*Button6

	ie->"Navigate" input1
	goto *main

いちおう説明を付け加えておくと、

ie->"Navigate" input1

は、変数 input1 に代入されているアドレスに移動するよう、ieに指示を送っています。 先ほどは

ie->"Navigate" url

となっていたので、変数 url に代入されていたアドレス"http://www.onionsoft.net"に移動してしまったのです。
初歩的なミスですね。お恥ずかしい限りです。

今回は親切に教えていただき本当にありがとうございました！
おかげですべて解決いたしました。今度からはもっと自分で調べたりして、
なるべく自分で解決できるようにしたいと思っています。