|
|
|
2012/8/19(Sun) 15:30:57|NO.48687
グーグルカレンダーからその日一日の予定を取得して表示するプログラムを作っています。
元となるxmlデータの取得・解析はすぐできたのですが表示で悩んでいます。
カレンダーは縦軸に時間軸をとった、一日単位のものを作りたいと考えています。
（グーグルカレンダーの一日表示と全く同じものです。）
使ったことがある方は分かると思いますが
グーグルカレンダーでは、同じ時間帯に重なった予定がある場合、
予定のサイズと位置を自動調節して、表示が重ならないようにしてくれます。
この挙動のアルゴリズムがわからず悩んでいます。
自分なりに整理して
・各予定の表示位置Ｘ,Ｙと表示サイズW, Hを求めたい
・Y,Hについては予定の時間から計算できる。
・Ｗは
（カレンダー全体の横幅）÷（同時進行する予定の最大数）
でもとめられる。
というところまで行きました。
しかしどうにも予定の表示位置Xが求められません。
どなたか、ご教授ください。
|
|
|
2012/8/19(Sun) 22:14:26|NO.48691
グーグルカレンダーは使ったことありませんが、
単純に横に並べるのであれば、
一つ目：X＝０（カレンダーの左端）
二つ目：X＝W
三つ目：X＝W×２
以下同様
で良いのではないでしょうか。
|
|
|
2012/8/19(Sun) 22:47:03|NO.48692
すいません、説明不足でした。
さらに自分が考えたWの求め方も誤りでした。
問題を整理すると
・ev_start:予定の開始時刻
・ev_duration:予定の継続時間
・Wbase,Hbase:カレンダー全体の横幅、高さ
が与えられています。これらを利用して
・ev_X,ev_Y:予定の配置位置
・ev_H,ev_W:予定のサイズ
を求めようとしています。その際に機能が満たすべき要件は
【要件】
�〕縦蠅魯�レンダーの横幅一杯まで埋まってないといけない
（埋まっていないとしたら、ev_Wが小さすぎるか、予定の並び順が不適）
�⇒縦蠅呂�さなって表示されてはならない。
の２点です。
例として、以下の様な4個の予定を考えます。
ev1 10:00〜11:00
ev2 10:00〜12:00
ev3 10:00〜11:00
ev4 11:00〜12:00
この場合ev1は最大3つの予定（自分含む）と同時進行します。（10:00〜11:00）
よってev1_W = Wbase/3 となります。ev2_W, ev3_W も同様です。
仮にWbase = 3としたら、ev1_W = ev2_W = ev3_W = 1 となります。
ここで、要件�，鯔�たすためには
ev4_W = 2、ev2_X = 0 としなければなりません。
（そうしないと11:00〜12:00の枠に隙間が生じてしまう）
この最適解を求めるためのアルゴリズムが分かりません。
自分の方法ですと、ev4はev1とのみ同時進行しますので
ev4_W = Wbase/2 = 1.5 となってしまいます。
Makotoさんの方法ですと、今回の場合、ev2_X = 1となってしまい、
11:00〜12:00の枠に隙間が生じてしまいます。
結局、どちらの場合も要件�，鯔�たせません。
|
|
|
2012/8/19(Sun) 22:56:37|NO.48693
図を用意しました
http://temperman.6.ql.bz/calendar.jpg
右が成功例、左が失敗例です。
ev2が中央(ev2_X=1)に来てしまうとev_4をどう配置しても
11:00〜12:00の枠に隙間ができてしまいます。
よって ev2_X = 0 (または2）、ev4_W = 2 が確定します。
|
|
|
2012/8/20(Mon) 05:47:09|NO.48695
縦列でまず描画を行って、隣の列と重複する範囲の、境界線を塗りつぶしたらどうでしょうか？
#const border 1
#const lwidth 60
#const vertical 4
dim y,2,3
y(0,0) = 150,320
y(0,1) = 20,200
y(0,2) = 40,300
y(0,3) = 290,450
// グラフの描画
repeat vertical
// 境界線のある、四角形の描画
l = cnt*lwidth
color
boxf l , y(0,cnt) , l+lwidth-1 , y(1,cnt)-1
color 200,200,255
boxf l+border , y(0,cnt)+border , l+lwidth-border-1 , y(1,cnt)-border-1
loop
wait 100
repeat vertical-1
i = cnt+1
if(y(0,cnt) > y(0,i)):ry=y(0,cnt) :else:ry=y(0,i) // 大きい方を返します
if(y(1,cnt) < y(1,i)):ry2=y(1,cnt) :else:ry2=y(1,i) // 小さい方を返します
l=i*lwidth
boxf l-border,ry+border,l+border-1,ry2-border-1
loop
|
|
|
2012/8/20(Mon) 09:58:43|NO.48698
これどこのICPCなの……
ヒューリスティクスとしては、
・ev_W＝項目数(nと置く)で初期化
・予定「終了」時刻が最も早い予定から順に「左から」配置していく。
この際、その予定開始時刻が、既存の配置済み予定の最も早い終了時刻より遅かったら、
その予定の上に配置するようにする。
・配置後、ev_W＝消費した横幅として、描画をスタートさせる。ただし、
描画は「左右を反転」させて行う。
てなとこか？ 適当に書いたコードを晒してみる。
;火憐……カレンダー問題
#module
#defcfunc evposx double x
return Wbase@-x/ev_W@*Wbase@+time_W@
#defcfunc evposy double y
return (y-ev_H_start@)/ev_H@*Hbase@
#global
;初期化
n=4 ;予定数
dim ev_start,n ;予定開始時刻
dim ev_duration,n ;予定継続時間
dim ev_end,n ;予定終了時刻
dim ev_X,n :dim ev_Y,n ;予定の表示位置(それぞれ単位・経過時間(分)の指定)
dim ev_last,n ;予定の各列での最速終了時刻
Wbase=400 :Hbase=400 ;カレンダーの表示サイズ
time_W=50 ;時刻表示用幅
ev_H=60*24 :ev_W=n ;予定のサイズ
fontsize=16 ;表示文字サイズ
;データ入力
ev_start.0=10*60,10*60,10*60,11*60 ;0:00からの経過時間をminuteで指定
ev_duration.0=60,120,60,60 ;継続時間をminuteで指定
;処理開始
;1. 終了時刻を計算
for k,0,n
ev_end(k)=ev_start(k)+ev_duration(k)
next
;2. 配置していく(一旦ソートした後配置)
for i,0,n-1
for j,i+1,n
if ev_end(i)>ev_end(j) {
w=ev_start(i) :ev_start(i)=ev_start(j) :ev_start(j)=w
w=ev_duration(i) :ev_duration(i)=ev_duration(j) :ev_duration(j)=w
w=ev_end(i) :ev_end(i)=ev_end(j) :ev_end(j)=w
}
next
next
ev_H_start=ev_start(0) :ev_H_end=ev_end(n-1);予定の最速開始時刻/最遅終了時刻
ev_last(0)=ev_end(0)
ev_X_early=0 :ev_end_early=ev_last(0) ;予定の最速終了時刻とその予定位置
ev_X(0)=0 :ev_Y(0)=ev_start(0) ;予定の表示位置
ev_W_now=1 ;現在の横幅
for k,1,n
if ev_end_early<=ev_start(k) {
ev_X(k)=ev_X_early
ev_last(ev_X_early)=ev_end(k)
ev_X_early=0 :ev_end_early=ev_last(0)
for w,0,ev_W_now
if ev_end_early>ev_last(w) {
ev_X_early=w :ev_end_early=ev_last(w)
}
next
}
else {
ev_X(k)=ev_W_now
ev_W_now+
}
ev_Y(k)=ev_start(k)
if ev_Y(k)<ev_H_start :ev_H_start=ev_Y(k)
next
ev_H=ev_H_end-ev_H_start :ev_W=ev_W_now
;描画
screen 0,Wbase+time_W,Hbase :title "カレンダー"
font msgothic,fontsize
for k,0,n ;予定表示
color 255,204,0
boxf evposx(ev_X(k)),evposy(ev_Y(k)),evposx(ev_X(k)+1),evposy(ev_Y(k)+ev_duration(k))
color
line evposx(ev_X(k)),evposy(ev_Y(k)),evposx(ev_X(k)+1),evposy(ev_Y(k))
line evposx(ev_X(k)+1),evposy(ev_Y(k)),evposx(ev_X(k)+1),evposy(ev_Y(k)+ev_duration(k))
line evposx(ev_X(k)+1),evposy(ev_Y(k)+ev_duration(k)),evposx(ev_X(k)),evposy(ev_Y(k)+ev_duration(k))
line evposx(ev_X(k)),evposy(ev_Y(k)+ev_duration(k)),evposx(ev_X(k)),evposy(ev_Y(k))
pos evposx(0.5+ev_X(k)),evposy(0.5*ev_duration(k)+ev_Y(k)) :mes "ev_"+k
next
for time,0,24 ;時刻表示
posy=evposy(time*60)-fontsize/2
if posy<0 :if posy+fontsize>=0 :posy=0 :else :_continue
if posy+fontsize>Hbase-1 :if posy<=Hbase-1 :posy=Hbase-1-fontsize :else :_continue
pos 0,posy :mes strf("%02d",time)+":00"
next
stop
ただし、このコードでは、 http://temperman.6.ql.bz/calendar.jpg右図のように、
「自動的に予定の横幅を広げる機能」には対応していない……！
それでも良ければどーぞ。Googleカレンダー使ったこと無いから感覚が分からん。
| |
|
|
2012/8/20(Mon) 10:29:25|NO.48701
サラッと間違えてしまった、すまん。
>if ev_end(i)>ev_end(j) {
を
>if (ev_end(i)>ev_end(j))|((ev_end(i)=ev_end(j))&(ev_start(i)<ev_start(j))) {
に、
>ev_X(k)=ev_W_now
>ev_W_now+
を
>ev_X(k)=ev_W_now
>ev_last(ev_W_now)=ev_end(k)
>ev_W_now+
にしてくれ……。
|
|
|
2012/8/20(Mon) 17:12:43|NO.48702
ヂオン様
すいませんがもう少し詳しくアルゴリズムを説明していただいてもよろしいでしょうか。
YSR様
この方法だと以下の様な場合には前述の問題と同様の問題が起きてしまいます。
ev1 11:00〜12:00
ev2 10:00〜12:00
ev3 11:00〜12:00
ev4 10:00〜11:00
なんか、想像していた以上に難しい問題だったみたいです。
自分でももう少し考えますので、何かわかることがあればぜひ書き込みをお願いします。
|
|
|
2012/8/20(Mon) 17:55:07|NO.48703
雛形を作成しました。
もし、今後この問題を考えてくださる場合、必要であれば以下をご利用ください。
なお、イベントに関する変数（ev_系列)に表記を統一して、
Hbase, Wbase をbase_H, base_W と改めました。
;初期化
#const n 4 ;イベントの個数
;イベントに関する変数
dim ev_start, n ;開始時刻
dim ev_end, n ;終了時刻
dim ev_duration, n ;継続時間
dim ev_X, n ;表示位置の左上X座標
dim ev_Y, n ;表示位置の左上Y座標
dim ev_W, n ;表示される幅
dim ev_H, n ;表示される高さ
;------------------初期設定ここから---------------
base_H = 400
base_W = 400
ev_start = 600, 600, 600, 660
ev_duration = 60, 120, 60, 60
;------------------初期設定ここまで---------------
;ev_end, base_start, base_end, base_duration を求める処理
base_start = ev_start(0)
for i, 0, n
ev_end(i) = ev_start(i) + ev_duration(i)
if base_start > ev_start(i) : base_start = ev_start(i)
if base_end < ev_end(i) : base_end = ev_end(i)
next
base_duration = base_end - base_start
;ev_Y, ev_Hを求める処理
for i, 0, n
ev_Y(i) = base_H * (ev_start(i)-base_start) / base_duration
ev_H(i) = base_H * ev_duration(i) / base_duration
next
;------------------最適化処理ここから---------------
;------------------最適化処理ここまで---------------
;描画
screen 0, base_W, base_H
for i, 0, n
color 255, 210, 0
boxf ev_X(i), ev_Y(i), ev_X(i)+ev_W(i), ev_Y(i)+ev_H(i)
color 0,0,0
line ev_X(i), ev_Y(i), ev_X(i), ev_Y(i)+ev_H(i)
line ev_X(i), ev_Y(i)+ev_H(i), ev_X(i)+ev_W(i), ev_Y(i)+ev_H(i)
line ev_X(i)+ev_W(i), ev_Y(i)+ev_H(i), ev_X(i)+ev_W(i), ev_Y(i)
line ev_X(i)+ev_W(i), ev_Y(i), ev_X(i), ev_Y(i)
pos ev_X(i)+5, ev_Y(i)+5
mes "Event" + i
next
stop
| |
|
|
2012/8/20(Mon) 17:57:24|NO.48704
雛形の使い方を書き忘れていました。
初期設定の欄ではイベントの開始時刻および継続時間を分単位で指定してください。
なお、イベントの個数を変更する場合はnの値を変更するのを忘れないでください。
最適化処理の欄にはev_X, ev_W を求めるアルゴリズムを記入してください。
|
|
|
2012/8/20(Mon) 21:37:16|NO.48706
「面白そうですね」と思ってやったら…普通に…難しい…
;初期化
randomize
setup_idx = 0
goto *begin
*begin
switch( setup_idx )
case 0
n = 4
swbreak
case 1
n = 4 + rnd(10)
swbreak
swend
;イベントに関する変数
dim ev_start, n ;開始時刻
dim ev_end, n ;終了時刻
dim ev_duration, n ;継続時間
dim ev_X, n ;表示位置の左上X座標
dim ev_Y, n ;表示位置の左上Y座標
dim ev_W, n ;表示される幅
dim ev_H, n ;表示される高さ
;------------------初期設定ここから---------------
base_H = 400
base_W = 400
switch( setup_idx )
case 0
ev_start = 600, 600, 600, 660
ev_duration = 60, 120, 60, 60
swbreak
case 1// random case
repeat n
ev_start(cnt) = 600 + 10*rnd(12)
ev_duration(cnt) = 10 + 10*rnd(11)
loop
swbreak
swend
;------------------初期設定ここまで---------------
;ev_end, base_start, base_end, base_duration を求める処理
base_start = ev_start(0)
for i, 0, n
ev_end(i) = ev_start(i) + ev_duration(i)
if base_start > ev_start(i) : base_start = ev_start(i)
if base_end < ev_end(i) : base_end = ev_end(i)
next
base_duration = base_end - base_start
;ev_Y, ev_Hを求める処理
for i, 0, n
ev_Y(i) = base_H * (ev_start(i)-base_start) / base_duration
ev_H(i) = base_H * ev_duration(i) / base_duration
next
;------------------最適化処理ここから---------------
// 難しいのでナイーブに
TL_EV_START = 0
TL_EV_END = 1
dim tlEventTime, n*2 + 1
dim tlEventCont, n*2 + 1
dim tlEventCooc, n*2 + 1// after
goto *@forward
#defcfunc isTlEvLower int l, int r
// compare < time, cont >
if ( tlEventTime(l) == tlEventTime(r) ) {
return ( tlEventCont(l) > tlEventCont(r) )// end is prior to
}
return ( tlEventTime(l) < tlEventTime(r) )
*@
tlEventCount = 0
repeat n
tlEventTime(tlEventCount) = ev_start(cnt)
tlEventCont(tlEventCount) = TL_EV_START
tlEventCount++
tlEventTime(tlEventCount) = ev_end(cnt)
tlEventCont(tlEventCount) = TL_EV_END
tlEventCount++
loop
// sort idx by <time,cont> c asc
dim tlEventSortedIdx, tlEventCount + 1
repeat tlEventCount
tlEventSortedIdx(cnt) = cnt
loop
if ( tlEventCount > 1 ) {
repeat tlEventCount-1
tidx = cnt+1
if ( isTlEvLower( tlEventSortedIdx(tidx), tlEventSortedIdx(tidx-1) ) ) {
tmidx = tlEventSortedIdx(tidx)
repeat tlEventCount
tlEventSortedIdx(tidx) = tlEventSortedIdx(tidx-1)
tidx--
if ( tidx <= 0 ) : break
if ( isTlEvLower( tmidx, tlEventSortedIdx(tidx-1) ) ^ 1 ) : break
loop
tlEventSortedIdx(tidx) = tmidx
}
loop
}
// set cooc
coocNum = 0
repeat tlEventCount
tidx = tlEventSortedIdx(cnt)
switch( tlEventCont(tidx) )
case TL_EV_START
coocNum++
swbreak
case TL_EV_END
coocNum--
// check
if ( coocNum < 0 ) {
// おかしい…
}
swbreak
swend
tlEventCooc(tidx) = coocNum
loop
// sort idx by cooc desc
dim tlEventSortedIdxByCooc, tlEventCount + 1
repeat tlEventCount
tlEventSortedIdxByCooc(cnt) = cnt
loop
if ( tlEventCount > 1 ) {
repeat tlEventCount-1
tidx = cnt+1
if ( tlEventCooc(tlEventSortedIdxByCooc(tidx)) > tlEventCooc(tlEventSortedIdxByCooc(tidx-1)) ) {// greater is 'lower'
tmidx = tlEventSortedIdxByCooc(tidx)
repeat tlEventCount
tlEventSortedIdxByCooc(tidx) = tlEventSortedIdxByCooc(tidx-1)
tidx--
if ( tidx <= 0 ) : break
if ( tlEventCooc(tmidx) <= tlEventCooc(tlEventSortedIdxByCooc(tidx-1)) ) : break
loop
tlEventSortedIdxByCooc(tidx) = tmidx
}
loop
}
// calculate w
repeat tlEventCount
tidx = tlEventSortedIdxByCooc(cnt)
if ( tlEventCont(tidx) != TL_EV_START ) : continue// check start only
evIdxPoolNum = 0
dim evIdxPool, n+1
repeat n
if ( ( ev_start(cnt) <= tlEventTime(tidx) ) && ( ev_end(cnt) > tlEventTime(tidx) ) ) {// endはノーカン
evIdxPool(evIdxPoolNum) = cnt
evIdxPoolNum++
}
loop
// check
if ( evIdxPoolNum != tlEventCooc(tidx) ) {
// 最大ケースじゃないっぽいので帰る
// 本来なら同じ時間は縮退するべきだったことに気付いたのがこの辺
continue
}
evEmptyNum = 0
evLeftW = base_W
repeat evIdxPoolNum
tmidx = evIdxPool(cnt)
if ( ev_W(tmidx) == 0 ) {
evEmptyNum++
} else {
evLeftW -= ev_W(tmidx)
}
loop
if ( evEmptyNum > 0 ) {
repeat evIdxPoolNum
tmidx = evIdxPool(cnt)
if ( ev_W(tmidx) == 0 ) {
ev_W(tmidx) = evLeftW / evEmptyNum
}
loop
}
loop
// calculate x
// ここ適当：ev_endが早い順にgreedy、それっぽくなるが間違ってる
// 多分本当の解法はgreedyじゃないっぽい、しかし面倒なのでここまでで…
dim evSortedIdxByEnd, n+1
repeat n
evSortedIdxByEnd(cnt) = cnt
loop
if ( n > 1 ) {
repeat n-1
tidx = cnt+1
if ( ev_end(evSortedIdxByEnd(tidx)) < ev_end(evSortedIdxByEnd(tidx-1)) ) {
tmidx = evSortedIdxByEnd(tidx)
repeat n
evSortedIdxByEnd(tidx) = evSortedIdxByEnd(tidx-1)
tidx--
if ( tidx <= 0 ) : break
if ( ev_end(tmidx) >= ev_end(evSortedIdxByEnd(tidx-1)) ) : break
loop
evSortedIdxByEnd(tidx) = tmidx
}
loop
}
// det
// 右端を使うと左が空くことがあるので、左に入れるならそのままにする
allowedPenetration = 3// 整数で演算のせいで残念なことになる前に、ちょっとのめり込みは許容
repeat n
tidx = evSortedIdxByEnd(cnt)
rightMost = 0
befNum = cnt
if ( befNum > 0 ) {
repeat befNum// 面倒なので更新が必要なくても最大ケース回す
repeat befNum
tmidx = evSortedIdxByEnd(cnt)
if ( ( ev_start(tidx) < ev_end(tmidx) ) && ( ev_end(tidx) > ev_start(tmidx) ) ) {// aabb y
if ( ( rightMost < (ev_X(tmidx)+ev_W(tmidx)-allowedPenetration) ) && ( (rightMost+ev_W(tidx)-allowedPenetration) > ev_X(tmidx) ) ) {// x
tRight = ev_X(tmidx) + ev_W(tmidx)
if ( rightMost < tRight ) : rightMost = tRight
}
}
loop
loop
}
ev_X(tidx) = rightMost
// check
if ( ev_X(tidx)+ev_W(tidx) > (base_W+allowedPenetration) ) {
// はみ出してる
}
loop
;------------------最適化処理ここまで---------------
;描画
screen 0, base_W+200, base_H+200// 全体が見えるようちょっと大きめ
for i, 0, n
color 255, 210, 0
boxf ev_X(i), ev_Y(i), ev_X(i)+ev_W(i), ev_Y(i)+ev_H(i)
color 0,0,0
line ev_X(i), ev_Y(i), ev_X(i), ev_Y(i)+ev_H(i)
line ev_X(i), ev_Y(i)+ev_H(i), ev_X(i)+ev_W(i), ev_Y(i)+ev_H(i)
line ev_X(i)+ev_W(i), ev_Y(i)+ev_H(i), ev_X(i)+ev_W(i), ev_Y(i)
line ev_X(i)+ev_W(i), ev_Y(i), ev_X(i), ev_Y(i)
pos ev_X(i)+5, ev_Y(i)+5
mes "Event" + i
next
pos base_W, 0
button goto "randomize", *random_setup
stop
*random_setup
setup_idx = 1
goto *begin
end
てんさんのひな形を少々弄っております、「randomize」ボタンを押すとランダムにデータが生成されます。
幅を求める方はかなりナイーブに書いたので、大体のケースで（処理が遅いながら）大丈夫だと思います。
むしろ位置Xを求める方が若干悩みました、これが難しい…というか面倒。
イベント数が多くなった場合、位置Xが間違ってしまう可能性が高いです。（イベントを左右で入れ替えていくときっちり収まるようにはなるみたいです、目測ですが）
真面目にやるならgreedyにやらずに、間違ったら別の組み合わせでチェック、というような再帰的な操作が必要になりそうです。
そういうのを書くのはなかなか骨が折れるんですよねHSP…なのでここまで。
ナイーブと言いつつかなり分かりづらい書き方になってますね、うーん、副作用とか全然考えずに適当に書いてしまった…。
まあ、こんな感じでやってみてもいいのか、程度で眺めて頂けると有難いです。
| |
|
|
2012/8/20(Mon) 22:42:26|NO.48711
はじめまして。
継続時間の長い予定から、できるだけ左の列に配置するというのはどうでしょうか？
全て配置後、右側の空き領域で判断して伸ばしたり右に移したり…と。
#const cMaxE 8 ;最長予定時間(でっち上げ用
#define draw redraw 1 : redraw 0
title "Hit Any Key [Esc:EXIT]"
randomize : font msGothic,,16
redraw 0 : color
repeat 5
line 22,cnt*96+32,31,cnt*96+32
pos 8,cnt*96+26 : mes strf("%2d",cnt*6)
loop
goto *Main
#deffunc kwait ;入力待ち
*@ : await 5 : stick j : if j=128{end} : if j{return j} : goto *@b
*Main ;メイン処理
dim iaEvt,rnd(29)+12,5 : dim i,9 : dim iaTim,24
foreach iaEvt ;てきとうに予定でっち上げ
iaEvt(cnt,0)=-1 ;X (未配置フラグとして-1)
iaEvt(cnt,1)=rnd(24) ;Y (開始時刻)
iaEvt(cnt,2)=1 ;W (初期幅1固定)
iaEvt(cnt,3)=limit(rnd(cMaxE)+1,1,24);H (継続時間)
iaEvt(cnt,4)=rnd(8) ;C (色)
if iaEvt(cnt,1)+iaEvt(cnt,3)>24{iaEvt(cnt,3)=24-iaEvt(cnt,1)}
if i.7<iaEvt(cnt,3){i.7=iaEvt(cnt,3)} ;最長継続時間
i=iaEvt(cnt,1),iaEvt(cnt,3)
repeat i(1) : iaTim(i(0)+cnt)++ : loop
loop : gosub *DrawEvt : gsel 0,1 : kwait
foreach iaTim : if i.8<iaTim(cnt){i.8=iaTim(cnt)} : loop
i.0=i.8*3/2 ;場合によってははみ出す為
dim iaCel,i.0,24 ;タイムテーブル用2次配列
memset iaCel,$FF,i.0*24*4 ;-1で初期化
;長い予定から，できるだけ左の列へ配置
repeat i.7
i.6=i.7-cnt
repeat length(iaEvt)
if iaEvt(cnt,3)!i.6{continue}
i.1=0,iaEvt(cnt,1),iaEvt(cnt,3),cnt
repeat : i.0=0
repeat i.3,i.2 : if iaCel(i.1,cnt)>=0{i.0++ : break} : loop
if i.0=0{
iaEvt(i.4,0)=i.1 : repeat i.3,i.2 : iaCel(i.1,cnt)=i.4 : loop
gosub *DrawEvt : kwait ;確認用描画
if i.5<i.1{i.5=i.1} : break
} else {i.1++}
loop
loop
loop
; i.5=最大予定右列
; i.8=最大予定重複数
; iaCel:予定表テーブル(各id or -1[空き])
; iaTim:各時間予定数
hsvcolor ,,255 : boxf 48,440
color 255 : pos 48,440 : mes "END"
draw : kwait : goto *Main
*DrawEvt ;描画
hsvcolor ,,255 : boxf 32 : j=0,0,0,0,0,0,0
foreach iaEvt
s=strf("%2d:%2d,%2d,%2d,%2d,%2d",cnt,iaEvt(cnt,0),iaEvt(cnt,1),iaEvt(cnt,2),iaEvt(cnt,3),iaEvt(cnt,4))
hsvcolor ,,64 : pos cnt/20*160+321,cnt\20*20+5 :mes s
if iaEvt(cnt,0)<0{continue}
hsvcolor iaEvt(cnt,4)*25,160,255 : j.2++
pos cnt/20*160+320,cnt\20*20+4 :mes s
j.3=iaEvt(cnt,0)*16+32,iaEvt(cnt,1)*16+32
j.5=iaEvt(cnt,2)*16,iaEvt(cnt,3)*16
color : boxf j.3,j.4,j.3+j.5,j.4+j.6
hsvcolor iaEvt(cnt,4)*25,128,255
j.0=(gInfo(16)<<16)|(gInfo(17)<<8)|(gInfo(18))
hsvcolor iaEvt(cnt,4)*25,255,192
j.1=(gInfo(16)<<16)|(gInfo(17)<<8)|(gInfo(18))
gradf j.3+1,j.4+1,j.5-1,j.6-1,1,j.0,j.1
loop
pos 48,440 : color
mes strf("%2d / %2d",j.2,length(iaEvt)) : draw
return
テンプレも何も無視しちゃってる上に、配置しかしてないスクリプトですけど…
| |
|
|
2012/8/20(Mon) 23:41:57|NO.48713
テンプレ乙！
自分の書いたアルゴリズムだと、最適化処理のところは、
/* 火憐ダゼー……カレンダー問題の最適化用コード */
dim flg_opt,n ;位置を決定できたら1
dim ev_last,n ;予定の各列での最速終了時刻
nowWidth=0 ;予定の「横幅」
//表示横座標(仮)を求める
for i,0,n
//終了時間最速の予定Aを求める
//(終了時間が同じ場合開始時間が遅い方優先)
end_early_num_A=-1 :end_early_time_A=9999 ;初期化
for k,0,n
if flg_opt(k)=0 {
if end_early_time_A>ev_end(k) {
end_early_num_A=k
end_early_time_A=ev_end(k)
}
else {
if end_early_time_A=ev_end(k) {
if ev_start(k)>ev_start(end_early_num_A) {
end_early_num_A=k
end_early_time_A=ev_end(k)
}
}
}
}
next
flg_opt(end_early_num_A)=1
//もし、予定A開始時間>終了時間となる最早終了の予定Bが存在したら、
//その上に予定Aを設置。でなければ新規に予定Aの場所を設ける。
//(これは「右から」走査するのがポイント)
flg=0 :end_early_num_B=-1
for k,nowWidth-1,-1,-1
if ev_start(end_early_num_A)>=ev_last(k) {
flg=1
ev_X(end_early_num_A)=k
_break
}
next
if flg=1 {
ev_last(ev_X(end_early_num_A))=ev_end(end_early_num_A)
}
else {
ev_X(end_early_num_A)=nowWidth
ev_last(nowWidth)=ev_end(end_early_num_A)
nowWidth+
}
next
//表示横座標・幅を計算
ev_W_default=base_W/nowWidth
for i,0,n
ev_X(i)=(nowWidth-ev_X(i)-1)*ev_W_default
ev_W(i)=ev_W_default
next
ですな。
>NO.48702
いや……要するに、「画面に隙間ができないように描画せよ」ってことになるのか？
これだと「隙間を埋めるように描画する処理」が要るから最適化の問題じゃないんじゃ……？
単に左詰めにしろ、って意味なら可能っちゃ可能なんだろうけど。
| |
|
|
2012/8/21(Tue) 00:35:58|NO.48714
３k様
プログラムを解読していたのですが
�，泙此∩瓦討離ぅ戰鵐箸粒�始・終了時刻をいれた配列を用意
tlEventTime…イベントの開始・終了時刻を入れた配列
tlEventCont…tlEventTimeの各時刻が開始なのか終了なのか判定するフラグ配列
��tlEventTimeを昇順にソート
tlEventSortedIdx…ソート後の時刻（時刻そのものではなく、tlEventTimeのindexを保管している）
�３道�刻における、同時進行中のイベント数をチェック
tlEventCooc…各時刻における、進行中のイベント数
��tlEventCoocが多い順に時刻をソート。tlEventCoocが多いものからWを計算していく。
�し彁斬仂櫂ぅ戰鵐箸粒�始時刻における、同時進行中のイベントを探して貯める
evIdxPool…同時進行中のイベントのindexをプールしておく配列
�シ彁斬仂櫂ぅ戰鵐箸粒�始時刻における、残された横幅を
同時進行中のイベントの中でまだWが決まっていないイベントたちと等分する。
ev_LeftW…まだイベントが入っていない(空白の)横幅
同時進行中のイベントが多い（＝他イベントのWへの影響力が強い）イベントから
優先的に配置していくということでしょうか？
何パターンもチェックしてみましたがどれも最適な幅になっていました。
ですので、Wの求め方はこれで完成であると思われます。ありがとうございます。
ただ、Xの求め方に不備があったようで、時々base_Wをはみ出してしまう時がありました。
（幅は変えずに位置を並べ替えれば最適解となる。）
一方、774様のスクリプトは予定のX座標についてものすごい良い精度で求まりました！
ですので両者を掛けあわせれば完成形が求まるのではないかと考えました。
しかし、いかんせん774様のX座標を求めるアルゴリズムが全く解読できませんでした。orz・・・
簡単にでも構いませんので、どなたか解説をお願いできませんか？
|
|
|
2012/8/21(Tue) 00:50:58|NO.48715
YSR様
確かに。。
これは最適化問題ではなく「要件を満たす配置方法がいくつか有り、その内の１つを求めよ」
という問題になっていました。すいません。
もともとこの問題を考え始めたきっかけをお話しますと、
描画した予定枠の中に、予定に関する情報を表示しようとしていました。
その際、予定枠が小さすぎて情報が表示しきれないことがありました。
そこで、なるべくカレンダー一杯まで予定枠を広げたい、と考えた結果この問題に至りました。
ですので質問を最適化問題らしく修正するとすれば、
各イベントの横幅(ev1_W,ev2_W...)の総和を Sum_ev_W として、
要件
�．ぅ戰鵐箸聾澆い暴鼎覆辰読充┐気譴討呂覆蕕覆ぁ�
�▲ぅ戰鵐箸魯�レンダーからはみ出してはならない。
という要件を満たすようにカレンダーを作った際に、Sum_ev_Wが最大となるように配置方法を求めるアルゴリズム」
を考えていただけたらと思います。
YSR様のアルゴリズムですと、初期設定が
ev_start = 660, 600, 660, 600
ev_duration = 60, 120, 60, 60
の場合、無駄な隙間ができてしまいますので、このアルゴリズムでは不完全であるということになります。
|
|
|
2012/8/21(Tue) 01:02:33|NO.48716
すいません、条件に不備がありますね。orz
詳しくは↓の画像を見ていただければわかるかと。
http://temperman.6.ql.bz/calendar3.jpg
カレンダーの評価方法がまず決まらないことにはアルゴリズムの方針も立ちませんよね。すいません。
なんとなくニュアンスは伝わりつつあると思うのですが。
|
|
|
2012/8/21(Tue) 02:35:26|NO.48717
>NO.48715
ぶっちゃけ３ｋさんのようにランダムデータで実験とかしてないからナー……。
私のより良い、というのを確認してないからいまいちピンと来ませぬ。
向こうは貪欲法で評価しているようですが、
こんなもんマジメにやりだしたら再帰でウボァーなことになる
(HSPは再帰が苦手)のは見え見えですのであれで正解な気もします。
プロコンの蟻本( http://www.amazon.co.jp/dp/4839941068)に似たよーな問題として、
「どの順で仕事を片付けるか」的なのがありまして、
それの解答が「最も早く終わる仕事から片付ける」といったものだったので
それを真似ただけだったり。
つまり３ｋさんより不真面目。
「表のどの位置が埋まっているか」を管理(分単位とか)すれば
横に拡張することなど楽勝に見えますが、冷静に考えれば
「その管理する配列がデカすぎるものに」
「左に拡張するか右に拡張するかがワカラン」
等の問題があるのであえて手抜きしたわけです。そう考えると774さんってすげー。
ちなみに、時間を時(hour)単位でしか管理しなくていいならば、
数行前での「管理する配列」がグッと小さくなって実装も簡単に。
逆に管理するイベントが1000とかになってくるとマジで頭捻らないと
秒単位での応答が期待できないことに……。
問題のサイズを教えてくれたら嬉しいなって。
|
|
|
2012/8/21(Tue) 02:41:10|NO.48718
そんなに難しい事はしてないのですが、配列使い回し過ぎ詰め過ぎですね…
二次配列 iaCel を横(最大同時予定*1.5)マス、縦24マスの方眼紙のように見立てて判定してます。
左端の列からその予定の時間帯が完全に空いているか、空いてないなら右隣の列へと移行です。
私も例の画像から時間単位だと思っていたので分単位だとコレだと問題ありそうですね…
横サイズが1.5倍なのは配置順によっては最大予定数以上になる為の応急措置です。
以下、配列変数を多少解り易そうな変数名に変えてみたつもりです。
;長い予定から，できるだけ左の列へ配置
repeat iMaxLen
iNowLen = iMaxLen-cnt ;最長の継続時間のから徐々に短い時間のを配置
repeat length(iaEvt)
if iaEvt(cnt,3)!iNowLen{continue} ;配置中の継続時間以外は無視
iX = 0 ;左端の列から検査
iY = iaEvt(cnt,1) ;＼
iLen = iaEvt(cnt,3) ; > cntが使えなくなるのでキープ
iID = cnt ;／
repeat ;以降、できるだけ左の置ける列探し
ii = 0 ;チェック用一時変数
repeat iLen,iY ;その列で置ける空間(時間帯)が空いてるか見てます
if iaCel(iX,cnt)>=0{ii++ : break}
loop
if ii=0{ ;ii=0 なら置けるという事
iaEvt(iID,0)=iX
repeat iLen,iY
iaCel(iX,cnt)=iID ;置いた場所にフラグとして予定ID代入
loop
gosub *DrawEvt : kwait ;確認用描画
if i.5<iX{i.5=iX} ;最右列保持(何かに使えるかと…
break
} else {iX++} ;ii>0 既存の予定と重なるので右の列へ…
loop
loop
loop
表示域に関してですが色やアイコンを設定可能にし、文字以外である程度内容を把握可能にするというのはどうでしょうか？
予定を選択すると詳細な情報に切り替ったり、ポップアップ表示など。
或いは表示範囲の拡大縮小機能なども在れば、使う側にとっては有益ではないかと思います。
作る側にとっては確実に手間も面倒も増えますけど…
|
|
|
2012/8/21(Tue) 02:54:15|NO.48719
>方眼紙のように見立てて
ぐぬぬ、やっぱり方眼紙(？)作戦が鉄板なのか……？
たかが60分の予定×20個の既存予定×10だけで12000個もの配列を判定しないといけないケドネ！
まあ一日の予定だし、1000個も詰め込む変態はいないと考えて組むのが正解か……。
とりあえず件のひな形に嵌る形に整形していただけると、それはとっても嬉しいなって。
私？ 眠いのでもう寝まふ……。
|
|
|
2012/8/21(Tue) 02:58:46|NO.48720
あ、やっぱり774さんの方法が最善な気がする。冷静に考えれば、
4(int型サイズ)*30(予定数)*(60*24)(分)＝168.75KBとメモリ量も大したこと無いし。
NO.48717で言ってた「右か左か」についても、
嵌る位置で一番左に置けば右以外に拡張しようがないし、アルゴリズムはこれで確定かな。
試してないが重そうだけど。
|
|
|
2012/8/21(Tue) 11:56:50|NO.48726
※連投気味でごめんなさい。
やっと……やっと、774さんの方法をひな形に嵌る形で実装できたよー！
;最適化アルゴリズム by 774
;※ev_Xの基準を、列単位→ピクセルへと途中変換しています。詳しくはコメント参照。
dim ev_table,n,base_duration ;予定数幅,時間幅
dim ev_preflg,n ;イベントが既に嵌められているかのフラグ(あったら1)
ev_W_now=0 ;予定数幅
;各予定について、嵌るべき位置を探す
;(ev_tableが0なら何もない、1以降は-1したイベント番号が入っている)
for i,0,n
;最大長でかつまだ嵌っていないイベントを探す
ev_longest=-1 :ev_longest_time=-1
for k,0,n
if (ev_preflg(k)=0)&(ev_longest_time<ev_duration(k)) {
ev_longest=k
ev_longest_time=ev_duration(k)
}
next
;当て嵌め
ev_setflg1=0 ;丁度いい当て嵌め位置が存在したら1
offset=ev_start(ev_longest)-base_start
for column,0,ev_W_now
ev_setflg2=1 ;既に既存の予定が嵌っていたら0
for l,0,ev_duration(ev_longest)
if ev_table(column,offset+l)!0 :ev_setflg2=0 :_break
next
if ev_setflg2=1 :ev_setflg1=1 :_break
next
if ev_setflg1=1 {
;差し込み
for l,0,ev_duration(ev_longest)
ev_table(column,offset+l)=ev_longest+1
next
ev_X(ev_longest)=column
}
else {
;新規
for l,0,ev_duration(ev_longest)
ev_table(ev_W_now,offset+l)=ev_longest+1
next
ev_X(ev_longest)=ev_W_now
ev_W_now+
}
;後処理
ev_preflg(ev_longest)=1
next
;横幅が拡張できるかを調べる
dim ev_preflg,n ;変数を再利用(こっちはチェックしたら1)
default_W=base_W/ev_W_now
for i,0,n
;最大長でかつまだチェックしていないイベントを探す
ev_longest=-1 :ev_longest_time=-1
for k,0,n
if (ev_preflg(k)=0)&(ev_longest_time<ev_duration(k)) {
ev_longest=k
ev_longest_time=ev_duration(k)
}
next
;(右に)拡張できるかをチェック
ev_W(ev_longest)=1
offset=ev_start(ev_longest)-base_start
for column,ev_X(ev_longest)+1,ev_W_now
ev_wdflg=1 ;拡張出来なかったら0
for l,0,ev_duration(ev_longest)
if ev_table(column,offset+l)!0 :ev_wdflg=0 :_break
next
if ev_wdflg=1 :ev_W(ev_longest)+ :else :_break
next
;後処理
ev_X(ev_longest)*=default_W
ev_W(ev_longest)*=default_W
ev_preflg(ev_longest)=1
next
どうでしょう？
| |
|
|
2012/8/22(Wed) 02:32:02|NO.48742
皆様のアルゴリズムも参考にさせていただきながら、自分でも１つ、
なかなか精度が良いとおもわれるアルゴリズムを閃きました。
例によって図での説明になります。
http://temperman.6.ql.bz/calendar4.jpg
補足として、
３のステップの際に、各グラフの幅は、そのグラフの同じレベルの要素数の最大値
（オレンジのグラフの場合、Event2とEvent6を同じレベルとみなすので2。青のグラフは1）
の比でbase_Wを分割すると綺麗に予定が配置できます。
今回の場合、オレンジ:青=2:1で横幅を分割しました。
|
|
|
2012/8/22(Wed) 10:41:07|NO.48743
>NO.48742
ほほう……
実装頑張ってくださいね。
|
|
|
2012/8/22(Wed) 21:19:46|NO.48753
お役に立ったようで何よりです。
そちらの方法ですと、
左端の列から未配置の次の予定(同時開始があれば最長のもの)を探索。
見付かった予定を配置して、その予定の終了時刻からその次を探索。
次の予定が見付からないようなら右隣の列へ移って同様に。
と配置してくと整理の時に少し楽になるような気がします(列の入れ替えが無い筈ですので)。
ふと思ったのですが、予定の表示域は長方形でないとダメなのでしょうか。
|
|
|
2012/8/22(Wed) 23:04:09|NO.48754
>長方形でないとダメ
変形アリなら毎回画面埋め尽くしていますよ774さん……
まあ774さんの実装なら、例えば
「空白箇所は真左の予定の領域とする。ただしそれでも余ったら右ね」
てなように書き換えるだけ(NO.48726の場合ev_tableを二回走査するだけ)で実現可能かと
|
|
|
2012/8/23(Thu) 22:07:01|NO.48770
>変形アリなら毎回画面埋め尽くしていますよ
そういう意味になるかも知れません。
「互いに重なって表示されてはならない」という要件が矩形である為のものなら
以下は論外な話になりますので無視して下さい。
仮に表示域確保の為の要件であったのなら、
配置での表示域確保後は矩形である必要は無いのではないかと思ったのです。
いっそ全て右端まで伸ばして、右のもの程上に重ねるように描画すれば
矩形の時より表示域が減る事はないですし、みっちり端まで埋まりますから
より要望を満たせる形になりはしないかと。
横棒グラフのような表示形式になりますね。
;初期化
randomize : dim n
base_H = 400 : base_W = 400
base_start = 360 : base_zoom = 3
ev_zoom = 1,2,3,4,6,12 : tmp_Z=2
screen 0, base_W, base_H
buffer 9, base_W, 180*24+440,8
*start
n=rnd(20)+8 ;イベントの個数
;イベントに関する変数
dim ev_start, n ;開始時刻
dim ev_end, n ;終了時刻
dim ev_duration, n ;継続時間
dim ev_X, n ;表示位置の左上X座標
dim ev_Y, n ;表示位置の左上Y座標
dim ev_W, n ;表示される幅
dim ev_H, n ;表示される高さ
dim ev_Col, n ;表示される色
sdim ev_Info,$100, n ;表示される内容
goto *main
#uselib "user32.dll"
#func DrawText "DrawTextA" int,sptr,int,sptr,int
#deffunc draw_ev_info int px, int py
h=px-40,py,0,0,-1 : if (h.0<0)|(h.0>359){return 0}
h.0/=tmp_X@ : h.1=(h.1+base_start@-20)*1440/(360*base_zoom@)
repeat
repeat n
if ev_X@.cnt!h.0{continue}
if ev_start@.cnt>h.1{continue}
if ev_end@.cnt>=h.1{h.4=cnt : break}
loop : if h.4>=0{break}else{h.0-- : if h.0<0{break}}
loop : if h.4<0{return 0}
gsel 0 : redraw 0 : gmode 4,360,360,192 : color
; title strf("[%d,%d]:%d,%d=%d",px,py,h.0,h.1,h.4);;;;;;;;
pos 20,20 : gcopy 9,20,20 : gmode 0
hsvcolor ev_Col@(h.4)*12,255,160
h.2=(ginfo(16)<<16)|(ginfo(17)<<8)|(ginfo(18))
hsvcolor ev_Col@(h.4)*12,160,255
h.3=(ginfo(16)<<16)|(ginfo(17)<<8)|(ginfo(18))
gradf 26,30,348,20,1,h.3,h.2 : s=strf("Event%d",h.4)
pos 31,32 : color : mes s :hsvcolor ,,255 : pos 30,31 : mes s
pos 30,54 : s=strf("%2d:%02d 〜",ev_start@(h.4)/60,ev_start@(h.4)\60)
s=strf("%s %2d:%02d",s,ev_end@(h.4)/60,ev_end@(h.4)\60)
mes strf("%s (%2d:%02d)",s,ev_duration@(h.4)/60,ev_duration@(h.4)\60)
s=ev_Info@(h.4) : h=30,80,370,370
DrawText hdc,s,-1,varptr(h),$2010 : pos 0,0
redraw 1
return 1
#deffunc draw_ev_rect int pi
j.0=ev_X@.pi*tmp_X@+40,(((ev_start@.pi*base_zoom@>>1)+1)>>1)+420
j.2=base_W-j.0-1,limit(((ev_duration@.pi*base_zoom@>>1)+1)>>1,20,4320)
j.4=0,0,ev_Col@.pi : hsvcolor j.6*12,192,96
circle j.0,j.1,j.0+18,j.1+18,1 : circle j.0,j.1+j.3-18,j.0+18,j.1+j.3,1
boxf j.0,j.1+9,j.0+1,j.1+j.3-10 : boxf j.0+9,j.1,j.0+j.2,j.1+j.3-1
color : boxf 0,0,base_W,18 : hsvcolor ,,255
circle 360,0,378,18,1 : hsvcolor j.6*12,64,255
j.4=(ginfo(16)<<16)|(ginfo(17)<<8)|(ginfo(18))
hsvcolor j.6*12,160,255
j.5=(ginfo(16)<<16)|(ginfo(17)<<8)|(ginfo(18))
gradf 0,0,360,6,1,j.4,j.5 : boxf 0,6,359,11
hsvcolor j.6*12,255,160
j.4=(ginfo(16)<<16)|(ginfo(17)<<8)|(ginfo(18))
gradf 0,12,360,6,1,j.5,j.4 : gmode 7,9,9
pos j.0+1,j.1+1 : gcopy 9,351,0
pos j.0+1,j.1+j.3-10 : gcopy 9,351,9 :gmode 1
pos j.0+10,j.1+1 : gcopy 9,0,0,j.2-9,9
pos j.0+10,j.1+j.3-10 : gcopy 9,0,9,j.2-9,9
if j.3>20{gradf j.0+1,j.1+9,j.2,j.3-17,1,j.4,j.5}
s=strf("Event%d %2d:%02d",pi,ev_start@.pi/60,ev_start@.pi\60)
j.0+=10 : j.1=j.1+2
j.2+=j.0-1 : j.3+=j.1-3 : hsvcolor j.6*12,255,64
DrawText hdc,s,-1,varptr(j),$2010
j=j.0-1,j.1-1,j.2-1,j.3-1 : hsvcolor ,,255
DrawText hdc,s,-1,varptr(j),$2010
return
#deffunc kwait ;入力
j.1=0 : *@ : await 5 : stick j : if j=128{end}
if (j=256)&(j.1=0){draw_ev_info MouseX,MouseY : j.1=stat : goto *@b}
if j{if j.1{return 0}else{return j&1279}}
goto *@b
;------------------初期設定ここから---------------
*main
repeat n
ev_start.cnt=rnd(1430)
ev_duration.cnt=(rnd(356)+5)
if ev_duration.cnt+ev_start.cnt>=1440{
ev_duration.cnt=1440-ev_start.cnt}
loop
;------------------最適化処理ここから---------------
repeat n
ev_end.cnt=ev_start.cnt+ev_duration.cnt
ev_X.cnt=-1 : ev_W.cnt=1
ev_Info.cnt=strf("Event%d の詳細は開発中です。",cnt)
ev_Col.cnt=rnd(16)
loop
tmp_X=0 : tmp_W=0 : i=0,0,0
repeat n
tmp_X=0 : tmp_Y=-1 : tmp_H=0 : i=-1
repeat n
if ev_X.cnt>=0{continue}
If ev_duration.cnt<tmp_H{continue}
If (ev_duration.cnt=tmp_H)&(ev_start.cnt>tmp_Y){continue}
i=cnt : tmp_Y=ev_start.cnt : tmp_H=ev_duration.cnt
loop
repeat : i.1=0,tmp_Y+tmp_H
repeat n
if(i=cnt)|(tmp_X!ev_X.cnt){continue}
if(tmp_Y>=ev_start.cnt)&(tmp_Y<ev_end.cnt){i.1++ : break}
if(i.2>ev_start.cnt)&(i.2<=ev_end.cnt){i.1++ : break}
loop
if i.1=0{
ev_X.i=tmp_X
if tmp_W<=tmp_X{tmp_W=tmp_X+1}
break
}else{tmp_X++}
loop
loop
i=tmp_W-2,0 ;十二分に幅が在りそうなら少し右へ移動
repeat : i.2=1,9999,-1
repeat n
if i.0!ev_X.cnt{continue}
if i.1>ev_start.cnt{continue}
if i.3<ev_start.cnt{continue}
i.3=ev_start.cnt : i.4=cnt
loop : if i.4<0{i=i.0-1,0 : if i.0<1{break} :continue}
i.1=ev_end(i.4)
repeat : i.5=0
repeat n
if (i.0+i.2)!ev_X.cnt{continue}
if (i.1>ev_start.cnt)&(i.1<=ev_end.cnt){i.5++ : break}
if (i.3>=ev_start.cnt)&(i.3<ev_end.cnt){i.5++ : break}
if (ev_start.cnt<i.1)&(ev_start.cnt>=i.3){i.5++ : break}
if (ev_end.cnt<=i.1)&(ev_end.cnt>i.3){i.5++ : break}
loop : if i.5{break} : i.2++ : if (i.0+i.2)>=tmp_W{break}
loop : if i.2>2{ev_X(i.4)+=(i.2>>1)}
loop
;------------------最適化処理ここまで---------------
;描画
*draw
gsel 9 : redraw 0 : hsvcolor ,,255: boxf : base_zoom=ev_zoom(tmp_Z)
tmp_H=base_zoom*4 : i.0=48/tmp_H
gmode 3,base_W-24,1,64 : hsvcolor ,,128
boxf 0,60,base_W,65
repeat tmp_H+1 : pos 24+((cnt\2)*8),cnt*90+420 : gcopy 9,0,60 : loop
font msGothic,20,17
gradf 0,20,20,20,1,$888899,$222233 : gmode 7,20,20
repeat tmp_H+1
if (cnt\2)=1{continue}
color : boxf 20,20,40,40
hsvcolor ,,255 : pos 20,20 :mes strf("%2d",cnt*i.0/2)
pos 0,cnt*90+410 : gcopy 9,0,20
loop
font msGothic,16,16
tmp_X=360/(tmp_W+1) : i.1=0,-1,0,0
repeat : i.0=-1 : i.3=1440
repeat n
if ev_X.cnt!i.1{continue}
if ev_start.cnt<=i.2{continue}
if ev_start.cnt>i.3{continue}
i.0=cnt : i.3=ev_start.cnt
loop
if i.0>=0{
i.2=i.3 : draw_ev_rect i.0
i.4++ : if i.4>=n{break}
}else{i.1=i.1+1,-1}
loop
color : boxf 0,0,400,400 : hsvcolor ,,255
circle 20,20,40,40,1 : circle 360,20,380,40,1
circle 20,360,40,380,1 : circle 360,360,380,380,1
boxf 30,20,369,379
gmode 6,360,10,255 : hsvcolor ,,48 : boxf 20,30,379,369
gradf 20,0,360,10,1,$AAAAAA,$CCCCCC
pos 20,20 : gcopy 9,20,0
gradf 20,0,360,10,1,$CCCCCC,$EEEEEE
pos 20,370 : gcopy 9,20,0
gmode 3,base_W-24,1,64 : tmp_H=base_zoom*4
repeat tmp_H+1 : pos 24+((cnt\2)*8),cnt*90+420 : gcopy 9,0,60 : loop
redraw 1 : gsel 0 : gmode 1,base_W,base_H
*@ : base_start=limit(base_start,0,base_zoom*360-360)
gmode 1,base_W,base_H : pos 0,0 : gcopy 9,0,base_start+400
kwait : i.1=base_start,tmp_Z : if stat&$FF0{goto *start}
if stat&2{base_start-=180} : if stat&8{base_start+=180}
if stat&1{i.2=tmp_Z-1} : if stat&4{i.2=tmp_Z+1}
i.2=limit(i.2,0,5) : if i.2!tmp_Z{tmp_Z=i.2 : goto *draw}
goto *@b
カーソルキーで動きます。
| |
|
|
2012/8/23(Thu) 23:27:28|NO.48781
>>NO.48770
んんんん！？！？
本気出し過ぎでしょ……クオリティ高すぎｗ
|
|
カレンダーの配置の最適化アルゴリズム
