HSPTV!掲示板

どなたかご教授願います。

ステータスバーを設置したのですが
親ウィンドウのサイズを変えると、ステータスバーが先の場所に取り残されてしまいます。

親ウィンドウサイズを変更した場合に
子ウィンドウであるステータスバーを、自動的に親ウィンドウにフィットさせたいのですが、
どのような記述をすると可能でしょうか。

下が現在のスクリプトです。
（それとも、設置の仕方が間違っているのでしょうか……

#include "user32.as"

#define WS_CHILD			$40000000
#define WS_VISIBLE			$10000000
#define WS_OVERLAPPEDWINDOW		$00CF0000
 
;最大化ウィンドウで作成
;	最大化するために、ディスプレイサイズでウィンドウ作成
	screen scrID, ginfo(20), ginfo(21)
;	自ウィンドウのスタイルを変更
	GetWindowLong hwnd, -16
	SetWindowLong hwnd, -16, stat |  WS_OVERLAPPEDWINDOW
;標準のウィンドウサイズに設定
	width 640, 480

;ステータスバー作成
	winobj "msctls_statusbar32",  "ステータスバー作成", , WS_CHILD | WS_VISIBLE
	hStatus = objinfo(stat, 2)
	
stop

ウィンドウサイズが変更されたときに、ステータスバーへWM_SIZEを送信すればできます。

#include "user32.as"

#define WM_SIZE				$00000005
#define WS_CHILD			$40000000
#define WS_VISIBLE			$10000000
#define WS_OVERLAPPEDWINDOW		$00CF0000

;最大化ウィンドウで作成
;	最大化するために、ディスプレイサイズでウィンドウ作成
	screen scrID, ginfo(20), ginfo(21)
;	自ウィンドウのスタイルを変更
	GetWindowLong hwnd, -16
	SetWindowLong hwnd, -16, stat |  WS_OVERLAPPEDWINDOW
;標準のウィンドウサイズに設定
	width 640, 480

;ステータスバー作成
	winobj "msctls_statusbar32",  "ステータスバー作成", , WS_CHILD | WS_VISIBLE
	hStatus = objinfo(stat, 2)
	
	oncmd gosub *OnSize, WM_SIZE
	
stop

*OnSize
	sendmsg hStatus, WM_SIZE, 0, 0
	
	return

ありがとうございます！
感動です！

そのように記述することで
ウィンドウサイズが変更されたとき
ステータスバーに通知できるんですね！

これで制作が進められます！
ありがとうございます！