HSPTV!掲示板

たとえば、
buffer 1
picload "a.jpg"
という仮想画面があったとします。
bufferは、直接メモリにデーターを展開する（はず？）ので
メモリのアドレスを参照して内容を取り出してintやnoteselで変数を作成して
picloadで変数を指定して読み出し画像を表示させるのは可能ですか

書き込み字の題名は他のスレッドと区別が付くようにするため質問の内容に関連するものをつけてくださいね。
次回からはお願いします。

> bufferは、直接メモリにデーターを展開する（はず？）ので

buffer命令はイメージとしては見えないウィンドウが開いています。
画面上に表示されないscreen命令と思って使ってください。


> picloadで変数を指定して読み出し画像を表示させるのは可能ですか

picload感覚で使いたいようなので、VRAMデータを取得したいという話ではなさそうですね。
普通はpicloadで読み込んだ画像はgcopyでコピーして使います。
bufferでもscreenでも同じことです。

ヘルプでgcopy命令調べると「サンプル逆引き」にたくさんサンプルあるのでそこから参考になりそうなものを探すといいと思います。

memfile で 指定した 変数名は
picload や mmload 等で ロードすることが出来るみたいです。

	#define fpath dir_exe+"\\doclib\\onibtn.gif"
	exist fpath:flen=strsize
	sdim buf,flen
	bload fpath,buf,flen,0
	memfile buf			 			; ロードする直前で指定すること。
	picload "MEM:"+getpath(fpath,2) ; "MEM:" に 拡張子指定用のダミーファイル名 を加算します。
									; 以下のように[ "."+拡張子 ] のみでも動作します。

多分、他の言語の用法と混同しているのでは。

>memfile で 指定した 変数名は
すでにファイルは読み込まれているのが前提と考えると
ファイルストリームの話じゃなくて、メモリを参照する話なのでは?

>picloadで変数を指定して読み出し画像を表示させるのは可能ですか
可能だが変数指定はできない。picload使うなら、いったん何らかのファイルに保存しないと無理

bufferに展開されているのは画像ファイルそのものではないので
一旦bmpsaveとかでファイルに出力することなく、
メモリ上だけで全部やってしまいたい！というのでしたら
自分で画像ファイルデータへと加工してあげる必要があると思います

まぁ普通なら「こんなのgcopyで済むじゃん！」って言われるのがオチですけども
アイデアがあれば、何か面白い利用方法があるかもしれませんね（^△^;

#define BMPINFOHEAD_SIZE 14

// bufferに画像読み込み
// (この画像をpicloadで他のウィンドウにロードするのが最終目的)
buffer 1
picload "a.jpg"


// BMPデータ生成に必要な情報収集
mref bmscr, 67
bmpInfPtr = lpeek( bmscr, 6 * 4 )
bmpInfSize = lpeek( bmscr, 15 * 4 )
vramPtr = lpeek( bmscr, 5 * 4 )
vramSize = lpeek( bmscr, 16 * 4 )
bmpFileSize = BMPINFOHEAD_SIZE + bmpInfSize + vramSize

// BMPデータ格納のためのメモリ確保
sdim buf, bmpFileSize

// BMPファイルヘッダ作成
wpoke buf, 0, 'M' << 8 | 'B'
lpoke buf, 2, bmpFileSize
wpoke buf, 6, 0
wpoke buf, 8, 0
lpoke buf, 10, BMPINFOHEAD_SIZE + bmpInfSize

// BMP情報ヘッダのコピー
dupptr bmpInfData, bmpInfPtr, bmpInfSize
memcpy buf, bmpInfData, bmpInfSize, BMPINFOHEAD_SIZE, 0

// BMPピクセルデータのコピー
dupptr vramData, vramPtr, vramSize
memcpy buf, vramData, vramSize, BMPINFOHEAD_SIZE + bmpInfSize, 0


// PICLOADしてみる(bufという変数に画像データが入っている)

gsel 0
memfile buf, 0, bmpFileSize
picload "MEM:.bmp"