HSPTV!掲示板

前回の質問(http://hsp.tv/play/pforum.php?mode=all&num=38991)で
解決したかと思われたのですが問題がありまして、
（更新・ページ進む・ページ戻る）にてページ移動するとURLが取得できるのですが
リンクで移動すると取得できないのです（´・ω・｀）
リンクイベントが起きると取得するにはどうすればいいですか？
取得したものはinput(変数=url)に入れます
イメージ(リンク・更新等クリック)→（ページ取得・URL取得）→（ページ表示・URL表示）
とゆう流れです、分かりにくかったらすみません

DocumentCompleteイベントを捕まえればいいのでは

#define DIID_DWebBrowserEvents2     "{34A715A0-6587-11D0-924A-0020AFC7AC4D}"
#define DISPID_DocumentComplete		259

	sdim url,1000
	input url,640,25
	axobj ie, "Shell.Explorer.2",640,455
	comevent ie_event, ie, DIID_DWebBrowserEvents2, *lb_event

	ie->"Navigate" "http://www.yahoo.co.jp"

	stop

*lb_event
	switch comevdisp(ie_event)
		case DISPID_DocumentComplete
			gosub *OnDocumentComplete
			swbreak
		default
			swbreak
	swend
	return
*OnDocumentComplete
	comevarg url2, ie_event, 1
	objprm 0,url2
	return

	#define DIID_DWebBrowserEvents2 "{34A715A0-6587-11D0-924A-0020AFC7AC4D}"
	
	#define DISPID_NAVIGATECOMPLETE2 252
	
	
	pos 0, 0
	axobj IE, "Shell.Explorer.2", 640, 300
	IE -> "Navigate" "http://hsp.tv/play/pforum.php"
	
	comevent ieevt, IE, DIID_DWebBrowserEvents2, *evt// ブラウザイベントの登録
	stop

*evt
	DispID = comevdisp(ieevt)
	
	// DISPID_NAVIGATECOMPLETE2
	if DispID = DISPID_NAVIGATECOMPLETE2 {
		doc = IE("Document")
		mes doc("URL")
		return
	}
	return
もうすでにeduさんが書き込んでいますが
NAVIGATECOMPLETE2を使う方法もあるよということで

解決できそうです、皆さんありがとうございました。