HSPTV!掲示板

　repeat〜loop構文を使っていると、時々以下のような事が起きる気がします。

１．二重にrepeat命令を使うので、repeat命令の次行にcnt相当の変数定義(以下は一例)

	repeat 8
		x = cnt
		repeat 6
			y = cnt
			color x*30+15, y*40+15, 192
			boxf x*40, y*20, x*40+39, y*20+19
			pos x*40, y*20
			color
			mes "("+x+","+y+")"
		loop
	loop

２．break命令で脱出した場合と、通常の場合を区別する為にフラグ変数定義(以下は一例)

	is_breaked = 0
	repeat rnd(5)+5
		if cnt>8 : is_breaked = 1 : break
	loop
	if is_breaked = 1 : dialog "break命令で抜け出しました" : end
	dialog "普通に抜け出しました"
	end

３．上２つのせいでrepeat〜loop構文が絡むユーザー定義命令はローカル変数が多い(以下は一例)

	#module
	#defcfunc area_checker array dimen, local breaked, local x, local y, local z, local t
	breaked = 0
	repeat length(dimen)
		x = cnt
		repeat length2(dimen)
			y = cnt
			repeat length3(dimen)
				z = cnt
				repeat length4(dimen)
					t = cnt
					if dimen(x,y,z,t) = "ひゃっはー" : breaked = 1 : break
				loop
				if breaked = 1 : break
			loop
			if breaked = 1 : break
		loop
		if breaked = 1 : break
	loop
	if breaked = 1 : return "ひゃっはーは("+x+","+y+","+z+","+t+")座標に存在します"
	return "ひゃっはーは存在しません"
	#global
	sdim dimension, 12, 10, 10, 10, 10
	dimension(rnd(10),rnd(10),rnd(10),rnd(10)) = "ひゃっはー"
	mes area_checker(dimension)

　慣れてしまえば問題無いような気もしますが、この手の変数は命令の処理方法次第で消去する事ができます。ここに書くと非常に長くなるので開発Wikiのページに一例を。
http://hspdev-wiki.net/?%BE%AE%A5%EF%A5%B6%2F%C6%C3%BC%EC%2Frepeat%A1%C1loop%B9%BD%CA%B8%A4%CE%B3%C8%C4%A5
　上記の通り、命令をマクロで修正して新たな引数とマクロを加えてやるだけでも、変数の定義を省略したり変数自体を消去する事ができます。
　しかしながら、マクロレベルで修正してしまうとマクロ展開後のプログラムが恐ろしく読み辛くなってしまいます。どうにかＨＳＰ本体の部分で修正できないものでしょうか。

これじゃダメですか？

#module
	#defcfunc area_checker array dimen, local breaked, local x, local y, local z, local t
	breaked = 0
	repeat length(dimen)
		x = cnt
		repeat length2(dimen)
			y = cnt
			repeat length3(dimen)
				z = cnt
				repeat length4(dimen)
					t = cnt
					if dimen(x,y,z,t) = "ひゃっはー" : breaked = 1 : break
				loop
				if breaked = 1 : break
			loop
			if breaked = 1 : break
		loop
		if breaked = 1 : break
	loop
	if breaked = 1 : return "ひゃっはーは("+x+","+y+","+z+","+t+")座標に存在します"
	return "ひゃっはーは存在しません"
	#global

#module DC
#defcfunc DimChecker array dimen
	Rep_All=length(dimen)*length2(dimen)*length3(dimen)*length4(dimen)

	repeat Rep_All
		x = (cnt/(length2(dimen)*length3(dimen)*length4(dimen)))\length(dimen)
		y = (cnt/(length3(dimen)*length4(dimen)))\length2(dimen)
		z = (cnt/(length4(dimen)))\length3(dimen)
		t = cnt\length4(dimen)
;title ""+x+","+y+","+z+","+t	//カウンタチェック用
		if dimen(x,y,z,t) = "ひゃっはー" : breaked = 1 : break
;wait 1	//repeat保険
	loop
	if breaked = 1 : return "ひゃっはーは("+x+","+y+","+z+","+t+")座標に存在します"
	return "ひゃっはーは存在しません"
#global

	randomize
	sdim dimension, 12, 10, 10, 10, 10
	dimension(rnd(10),rnd(10),rnd(10),rnd(10)) = "ひゃっはー"
	mes area_checker(dimension)
	mes DimChecker(dimension)

マクロで十分ならわざわざ新命令にするほどかは疑問。
マクロ展開後のコードの見づらさなどは気にする必要があるとも思えない。
あとカウンタ用変数を指定するなら既存のforで十分な気がする。
その他の機能も使用頻度が多いとは思えない。