HSPTV!掲示板

矩形をドラッグで移動するプログラムを組みました。

	di_tex_xf=100
	di_tex_yf=100
repeat 
	color 0,0,0 :boxf di_tex_x,di_tex_y,di_tex_xf,di_tex_yf
	getkey mousel,1
	if mousel=1& mousex>=di_tex_x&mousey>=di_tex_y&mousex<=di_tex_xf&mousey<=di_tex_yf :gosub *di_tex_go
	await 1
loop

*di_tex_go
repeat
	redraw 0
	color 255,255,255
	boxf
	color 0,0,0
	boxf di_tex_x,di_tex_y,di_tex_xf,di_tex_yf
	di_tex_x=mousex
	di_tex_y=mousey
        di_tex_xf=mousex+100
	di_tex_yf=mousey+100
	redraw 1
	getkey mousel,1
	if mousel=0 :break
	await 0
loop

return

このプログラムだと、矩形をクリックしたら矩形の左上がマウスの位置に移動すると思います。
こうではなく、矩形をクリックしたらその位置から矩形を移動できるようにするにはどのようにすればいいのでしょうか？

クリックした時の位置を取得すれば良いのではないでしょうか？

	di_tex_xf=100
	di_tex_yf=100
repeat 
	color 0,0,0 :boxf di_tex_x,di_tex_y,di_tex_xf,di_tex_yf
	getkey mousel,1
	if mousel=1& mousex>=di_tex_x&mousey>=di_tex_y&mousex<=di_tex_xf&mousey<=di_tex_yf :gosub *di_tex_go
	await 1
loop

*di_tex_go
	chk_x = di_tex_x - mousex
	chk_y = di_tex_y - mousey
repeat
	redraw 0
	color 255,255,255
	boxf
	color 0,0,0
	boxf di_tex_x,di_tex_y,di_tex_xf,di_tex_yf
	di_tex_x=mousex+chk_x
	di_tex_y=mousey+chk_y
	di_tex_xf=mousex+100+chk_x
	di_tex_yf=mousey+100+chk_y
	redraw 1
	getkey mousel,1
	if mousel=0 :break
	await 0
loop

return

なるほど
このようにすればよかったのですね。
ありがとうございました。