|
|
|
2011/1/14(Fri) 17:28:56|NO.36603
現在シューティングゲームを制作しています。
現在メインループの演算の頻度を
await 1
としているのですが、実際にパソコンは一秒間に６０回の画面更新を行っているので
無駄な演算をさせてしまい、負荷をかけているきがします。
そこで画面の更新に合わせて演算をさせたいと思うのですが、
16.xxx
と割り切れないので適した数値がわかりません
画面の更新にあったawait のパラメータはどのように設定したらよいのでしょうか
もし知っている方がいらっしゃれば教えてください
よろしくお願いします
|
|
|
2011/1/14(Fri) 18:15:30|NO.36604
これは１秒間に６０回ループしたいということかな？
(16.xxxより)
となると実数値は設定できないので
１６で我慢するか
E3Dで作成するか
(fps を 60 で指定)
|
|
|
2011/1/15(Sat) 01:19:38|NO.36607
うーん、多分リフレッシュレートのことを言っているのだと思います。
モニタのリフレッシュレート以上のfps値で画面を更新しても意味が無いんじゃないか？
ということを言いたいのだと思います。
確かにそうですね。ゲームの場合、描画サイクル(fps値)は60fpsか30fpsかで作られるのがだいたい普通みたいです。
しかし、fps値を60や30にするのは他にも理由があります。
・cpu負荷も軽減できます。
・fps値が安定します。
await 0や1でCPUまかせに高速に画面を更新しちゃうとfps値が安定せず、同じ動作でもCPUの状態でキャラクターが極端にゆっくり動いたりすばやく動いたりしてしまいます。これはゲームでは致命的な欠陥になってしまいます。
ということで、たいていの人はゲームを作るとき、awaitで適度な待機をしてfps値を安定させます。時間はawait 16前後か30前後で作っていると思います。
> 画面の更新にあったawait のパラメータはどのように設定したらよいのでしょうか
実を言うとawait命令はさほど精度が高いわけではありません。（詳しくはawaitとかで過去ログ探すと何か出てくると思います。）
ということで、このスクリプトを試してみてください。
#include "d3m.hsp"
t = 10
*main
redraw 1 : await t : redraw 0 : color 255, 255, 255 : boxf : color : pos 0,0
stick key
if key&2 : t++ ;↑
if key&8 : t-- ;↓
t=limit(t,0,100)
mes "await " + t
mes ""+d3getfps() + " fps"
goto *main
↑↓キーを押すとawaitのパラメータが変わります。
awaitのパラメータを１ずつ変えてもfps値がステップ状に変化していくことが確認できると思います。
ん？あれ…16だと40fpsになった…だと。
いままで確認せずに17とか16で作ってた…。orz
|
|
|
2011/1/15(Sat) 02:30:59|NO.36608
気になったのでawaitとfps値の関係を調査してみました。
http://homepage3.nifty.com/ghpk/tmp/await_fps.png
結果はこの図のように、690,64,32,21,16,13,11,9...とステップ状に推移しました。
ギリギリの15とか30使うより真ん中の8とか25ぐらいのほうがfps値が安定しそうな気がしますね。
しかしこのグラフ、環境に依存するんでしょうか。
テスト環境
OS:Vista 32bit
CPU:Core2Duo 3.0GHz
|
|
|
2011/1/15(Sat) 05:24:04|NO.36609
16,17,32,33は不安定なようです
CPU:Core2 Duo E7500 2.93GHz
OS:XP 32bit
#include "d3m.hsp"
#uselib "user32.dll"
#func SetTimer "SetTimer" int,int,int,nullptr
#func KillTimer "KillTimer" int,int
#define WM_TIMER 0x0113
start=8 ;await
vend=40 ;await
interval=1 ;1ステップの計測時間（秒）
musi=2 ;先頭２行は信用できない
if start>=musi: start-=musi
ndim=vend-start+1
dim anum,ndim
dim aval,ndim
ddim aver,ndim
dim amin,ndim
dim amax,ndim
t=start
i=0
screen 0,640,640,,0,0
font msgothic,16
objmode 2
title ""+interval+"秒お待ちください"
onexit goto *l_exit
oncmd gosub *l_ontimer,WM_TIMER
timerID = 1
timeoutValue=interval*1000
gosub *l_setTimer
*main
redraw 1 : await t : redraw 0 : color 255, 255, 255 : boxf : color : pos 0,0
fps=d3getfps()
if fps>0 {
sum+=fps
num++
if fps<min: min=fps
if fps>max: max=fps
}
goto *main
*l_ontimer
KillTimer hwnd,timerID
anum.i=num
aval.i=t
aver.i=double(sum)/num
amin.i=min
amax.i=max
title "i="+i+" t="+t+" sum="+sum+" num="+num+" ave="+aver.i+" min="+min+" max="+max
i++
t++
if t<=vend {
gosub *l_setTimer
goto *main
}
s="await 回数 平均 最小 最大\n"
repeat ndim-musi,musi
s+=strf(" %3d %3d %4.1f %3d %3d\n",aval.cnt,anum.cnt,aver.cnt,amin.cnt,amax.cnt)
loop
mesbox s,640,640
stop
*l_setTimer
num=0
sum=0
min=1000
max=0
SetTimer hwnd,timerID,timeoutValue
timerID = stat
return
*l_exit
KillTimer hwnd,timerID
end
await 回数 平均 最小 最大
8 65 63.7 63 64
9 63 64.0 64 64
10 65 64.3 64 65
11 63 64.1 63 65
12 65 63.9 63 65
13 64 63.8 63 65
14 63 63.7 63 65
15 63 63.3 63 64
16 40 54.0 42 63
17 32 36.9 32 42
18 32 32.0 32 32
19 32 32.0 32 32
20 32 32.0 32 32
21 32 31.8 31 32
22 32 32.2 32 33
23 32 32.0 32 32
24 32 32.0 32 32
25 32 32.0 32 32
26 32 31.8 31 32
27 32 32.0 32 32
28 32 32.0 32 32
29 32 32.0 32 32
30 32 32.2 32 33
31 32 32.0 32 32
32 24 28.4 24 32
33 21 23.0 22 24
34 22 21.3 21 22
35 21 21.2 21 22
36 21 21.5 21 22
37 22 21.2 21 22
38 21 21.2 21 22
39 21 21.4 21 22
40 22 21.3 21 22
| |
|
|
2011/1/15(Sat) 05:47:47|NO.36610
３回やってみましたが、３回とも16のときの回数は40だったので、
不安定なのはawaitではなくd3getfpsのようです。
|
|
|
2011/1/15(Sat) 12:33:10|NO.36611
>不安定なのはawaitではなくd3getfpsのようです。
こちらの環境でも同じくd3getfpsのほうが不安定
|
|
|
2011/1/15(Sat) 13:49:41|NO.36613
d3getfpsのかわりのFPS計測モジュールと精度がよくなっているかもしれないawait命令
#module
#uselib "winmm.dll"
#cfunc timeGetTime "timeGetTime"
#defcfunc getFPS
time = timeGetTime() - ntime
if time >= keisoku {
fps = strf("%.2f", drawcnt)
ntime = timeGetTime()
drawcnt = 0.0
}else : drawcnt += ( 1000.0 / keisoku )
return fps; + " - " + ( keisoku - time )
#deffunc setFPSTime int _keisoku
keisoku = _keisoku
ntime = timeGetTime()
fps = "**.**"
return
#deffunc awaitt int atime
if busy = 0 {
busy = 1
repeat
wait 0
if timeGetTime() - mtime >= atime : break
loop
mtime = timeGetTime()
busy = 0
}
return
#deffunc setAwait
mtime = timeGetTime()
return
#global
setAwait
t = 10
FPSTime = 1000
setFPSTime FPSTime
ax = 1
objsize 100, 20
FPSS = 50, 100, 500, 1000, 2500, 5000
foreach FPSS
pos cnt * 100, 140
button gosub "頻度を" + FPSS(cnt) + "に変更", *set_FPS
wait 0
loop
awts = 5, 10, 12, 16, 20, 24
foreach awts
pos cnt * 100, 160
button gosub "awaitを" + awts(cnt) + "に変更", *set_awt
wait 0
loop
msg = "標準命令", "新規命令"
*main
stick k, 1 + 4
if k & 1 : FPSTime-- : setFPSTime FPSTime
if k & 2 : t++
if k & 4 : FPSTime++ : setFPSTime FPSTime
if k & 8 : t--
if k & 32 : awtm ^= 1
if t < 0 : t = 0
if FPSTime < 50 : FPSTime = 50 : setFPSTime FPSTime
redraw 0
color 255, 255, 255
boxf
color 0, 0, 0
pos 0, 0
mes "現在のawaitの時間：" + t
mes "現在のFPS：" + getFPS()
mes "[" + FPSTime + "]ミリ秒ごとにFPSを更新"
mes "左右の矢印キーでFPSの更新頻度変更"
mes "上下の矢印キーでawaitの時間を変更"
mes "Enterキーでawait命令の切り替え"
mes "awaitは" + msg(awtm) + "の方です。"
circle x, 200, x + 20, 220// 比較用に
x += ax
if x > ginfo(12) - 20 : ax = -abs(ax)
if x < 0 : ax = abs(ax)
redraw 1
if awtm = 0 : await t : else : awaitt t
goto *main
*set_FPS
FPSTime = FPSS(stat)
setFPSTime FPSTime
return
*set_awt
t = awts(stat - length(FPSS))
return
| |
|
|
2011/1/15(Sat) 20:20:21|NO.36620
どなたもこなたもそういうありきたりなことばかり。
質問をよーく読み返しましょう。FPSのことではありません。
>実際にパソコンは一秒間に６０回の画面更新を行っている
このように質問者は断言している。これはこの問題の「条件」である。
>無駄な演算をさせてしまい、負荷をかけているきがします。
画面が更新されていない間に何度も演算するのは無駄で負担をかけている気がする。
>そこで画面の更新に合わせて演算をさせたいと思う
画面の更新に合わせて演算をさせたい。
要するにモニターが６０回/秒更新されるのに合わせて６０回/秒演算したいわけじゃない。
どのようにしてパソコンが６０回/秒更新しているのか調べたのか気になるところだが、質問者は
６０回/秒のモニター更新に合わせて更新の直前にプログラムが諸演算を終えれば一切の無駄がなく効率が上がり負担も減るだろう
という考えなのだ。
結論から言うと、プログラム内の全演算が1/60秒で終えるプログラムであれば可能かもしれないが
モニターの描画と同期させてプログラミングするというのはひどくナンセンスだと思われる。
そしてawaitはそのようなモニターの描画と同期させるためにプログラムの実行を「待つ」目的のために使う命令ではない。
|
|
|
2011/1/15(Sat) 22:55:40|NO.36623
みなさん動作報告ありがとうございます。
まとめるとこんな感じかな。
・fpsはステップ状に変化する。
・16、32ms前後付近でfps値が大きく変化する。環境による違いはあまりない。
・fpsが大きく変化する待ち時間付近はfps値が安定しない。
awaitでは16や32付近は使わないほうがよさそうですね。
>>NO.36609
検証プログラムどうもです。でも待ち時間変更してからすぐに計測開始してるような気が…。
d3getfpsは過去1sec分のフレーム数をカウントして表示してるので、待ち時間変えてからfps値の表示が安定するまで1秒かかる仕様です。
最大値が大きいのは安定する前の値だからのようです。
不安定といえば、await 16以下でE3DGetFPSを使うと数フレームおきに500fpsとか取得してきます。ｗ
>> 先輩さん
投稿時に削除用パスワードを設定しておけば、自分のレスは削除ができますよ。
SU-�靴気鵑瓦瓩鵑覆気ぁ�スレの趣旨がそれてしまいましたね。
話を戻して…きちんと質問に回答してなかったことに気が付いたので回答。
> 画面の更新にあったawait のパラメータはどのように設定したらよいのでしょうか
うん、それ無理。
await命令では。
後で調べてみたところリフレッシュレートとタイミングを合わせるにはVSYNC同期をとるという方法があるようですが、DirectX等が必要みたいです。
この手法は主にCPU負荷低減よりも、画面のちらつき（ティアリング）を抑える目的で用いられているようです。
このちらつきは気にしなければ気にならないレベルのものです。（人にもよると思いますが）
簡単な実装はが難しそうなので、awaitで60fps近辺で動作するように作ったほうが手軽でよいと思います。
|
|
|
2011/1/16(Sun) 02:50:48|NO.36625
>d3getfpsは過去1sec分のフレーム数をカウントして
>表示してるので、待ち時間変えてからfps値の表示が
>安定するまで1秒かかる仕様です。
サンプリング時間をとってみたところ、確かに安定しました。
サンプリング時間１秒だとまだ不安定だったので1.2秒にしてみました。
でも、そうすると、「await 16等が不安定」の根拠がなくなるのではと
思い、NO.36607のスクリプトを実行してみましたが、
16だけ、安定した後でマウスを動かすと値が乱れますね。
#include "d3m.hsp"
#uselib "user32.dll"
#func SetTimer "SetTimer" int,int,int,nullptr
#func KillTimer "KillTimer" int,int
#define WM_TIMER 0x0113
start=8 ;await
vend=40 ;await
interval=1 ;1ステップの計測時間（秒）
samptime=1200 ;f3getfpsサンプリング時間（ミリ秒）
musi=1 ;先頭１行は信用できない
if start>=musi: start-=musi
ndim=vend-start+1
dim anum,ndim
dim aval,ndim
ddim aver,ndim
dim amin,ndim
dim amax,ndim
t=start
i=0
screen 0,640,640,,0,0
font msgothic,16
objmode 2
c=samptime/1000+interval
title ""+c+"秒お待ちください"
onexit goto *l_exit
oncmd gosub *l_ontimer,WM_TIMER
timerID = 1
f=0 ;本番フラグ。0のときはf3getfpsのサンプリング
timeoutValue=sampt
gosub *l_setTimer
*main
redraw 1 : await t : redraw 0 : color 255, 255, 255 : boxf : color : pos 0,0
fps=d3getfps()
if fps>0 {
sum+=fps
num++
if fps<min: min=fps
if fps>max: max=fps
}
goto *main
*l_ontimer
KillTimer hwnd,timerID
if f==0 {
;f3getfpsのサンプリングが終わったので本番開始
f=1
timeoutValue=interval*1000
gosub *l_setTimer
goto *main
}
;本番終了
anum.i=num
aval.i=t
aver.i=double(sum)/num
amin.i=min
amax.i=max
title "i="+i+" t="+t+" sum="+sum+" num="+num+" ave="+aver.i+" min="+min+" max="+max
i++
t++
if t<=vend {
;f3getfpsのサンプリング開始
f=0
timeoutValue=samptime
gosub *l_setTimer
goto *main
}
s="await 回数 平均 最小 最大\n"
repeat ndim-musi,musi
s+=strf(" %3d %3d %4.1f %3d %3d\n",aval.cnt,anum.cnt,aver.cnt,amin.cnt,amax.cnt)
loop
mesbox s,640,640
stop
*l_setTimer
num=0
sum=0
min=1000
max=0
SetTimer hwnd,timerID,timeoutValue
timerID = stat
return
*l_exit
KillTimer hwnd,timerID
end
| |
|
|
2011/1/16(Sun) 15:07:19|NO.36631
質問者は何処に・・・
|
|
|
2011/1/16(Sun) 16:05:38|NO.36632
すみません。返信がおそくなりました
たくさんのアドバイスありがとうございます。
様々な意見が聞けて助かりました。
勘違いやまだ知らない部分もあったので調べてみたいと思います
|
|
|
2011/1/16(Sun) 19:26:32|NO.36645
GENKIさんすいませんね。
忘れたというのは否定できませんが
クッキー一覧ツールを使って忘れたパスワードを得ることも
削除用パスワードのpassword属性を後から無効にしてパスワードを表示させることも
クリックした要素の詳細な情報（伏せられているパスワードでさえ）を表示することも
こちらで可能だったのですが、
ここの管理人や協力者は厳しい発言を削除するのが趣味らしので
消されるだろうと思っておりました。
|
|
画面更新に適したawait命令のパラメーターについて教えてください
