とりあえず
<甲>:*shoriラベルが無限ループを構築してしまっている
<乙>:ドットの総当たりが上手く起動していない
<丙>:いくらawait命令でも10万回も繰り返されては恐ろしく時間がかかる
<丁>:*shoriラベルが各ドット単位の処理を意味するのか、全体の処理を意味するのか不明
このような理由から件のソースは上手く起動しないのではないかと思われます。
で、解決方法ですが
<甲>:*shoriをサブルーチンにする
<乙>:repeat〜loop構文で総当たりを構築する
<丙>:規定回数毎にawait命令を入れる、乃至そもそも有限なのでウェイトを入れない
<丁>:*shoriラベルが何を意味すべきかをあらかじめ自分の中で固めておく
と言った方法が考えられます。
参考までに、赤月さんのソースからこちらなりに意図を汲んで作ったソースを以下に
貼らせていただきます。(もし、赤月さんの意図が『モノクロ画像を作りたい』と言う意味だと
したら申し訳ありません)
#const DECHROMA_WINDOW 1
#const VIEW_WINDOW 0
#const DIALOG_FAILTURE 0
dialog "jpg|png|bmp|gif", 16, ""
if stat = DIALOG_FAILTURE : end
dechroma_set_window DECHROMA_WINDOW
gsel VIEW_WINDOW : redraw 0
dechroma_convert_graphic refstr
redraw 1
#module dechroma
#const RED 0
#const GREEN 1
#const BLUE 2
#const COLOR_BORDER 150
#define ctype BRIGHTNESS(%1) brightness_date(check_x, check_y, %1)
#define POINT_X now_x + check_x
#define POINT_Y now_y + check_y
#deffunc dechroma_set_window int window
内部ウィンドウ = window
return
#deffunc dechroma_convert_graphic str fileadress, local now_window, local now_x, \
local now_y, local check_x, local check_y, local size_x, local size_y, \
local brightness_date
now_window = ginfo_sel
now_x = ginfo_cx
now_y = ginfo_cy
buffer 内部ウィンドウ
picload fileadress
size_x = ginfo_sx
size_y = ginfo_sy
dim brightness_date, size_x, size_y, 3
repeat size_x * size_y
check_x = cnt \ size_x
check_y = cnt / size_x
pget check_x, check_y
if ginfo_r > COLOR_BORDER : BRIGHTNESS(RED) = 255
if ginfo_g > COLOR_BORDER : BRIGHTNESS(GREEN) = 255
if ginfo_b > COLOR_BORDER : BRIGHTNESS(BLUE) = 255
loop
gsel now_window
repeat size_x * size_y
check_x = cnt \ size_x
check_y = cnt / size_x
color BRIGHTNESS(RED), BRIGHTNESS(GREEN), BRIGHTNESS(BLUE)
pset POINT_X, POINT_Y
loop
pos now_x, now_y
return
#global