HSPTV!掲示板

文字を半透明にするにはどうしたらよいのですか？
後、文字を縦に書きたいのですが、、、
↓みたいな方法しかないのでしょうか？

font msmincho,50,1
pos 35,120
mes "YOU"
wait 15
font msgothic,25,1
pos 10,120
mes"あ"
mes"な"
mes"た"
stop

一度書いてしまった文字は画像と一緒です。
なので、文字を半透明にするにはbuffer命令で用意した見えないウインドウに一度書いて、それを半透明コピーしてください。

>縦書き
今度公開する自作のモジュールで考えておきます。

縦書きにするなら公平に2Byte単位で数えられるようcnvstowでUnicodeに変換してから
再び表示するときにSJISに戻すのが一番よさそう

ただstrlenが簡単に使えないんだこれが、、、

mes{"
あ
な
た
"}
でもOKですよ。

#module
#deffunc mesy str p1
	sdim u:cnvstow u,p1
	cy=ginfo_cy
	repeat
		p=wpeek(u,cnt*2)
		if p==0:break
		pos ginfo_cx,cy+ginfo_mesy*cnt
		mes cnvwtos(p)
	loop
return
#global

pos 50,50
mesy "なんたらかんたら"

考え方次第で色々な方法があるので
命令を勉強して色々試してみて下さい。

#const R_90 M_PI/2
    FontSize = 80
    Message = "縦書きで書く"
;    背景作成
    gradf 0, 0, 640, 480, 1, $0000ff, $ffffff
    color 64, 64, 64
   	repeat 240
   		line 0, cnt*2, 640, cnt*2
   	loop

;----------  grotateで90度回転コピーする&半透明  ----------
    buffer 1, 640, 400
    font "@ＭＳ 明朝", FontSize
    pos 8, 8        ;grotateは右端と下端のラインが潰れるので端には書かない
    mes Message
;    90度回転&半透明でコピー
    gsel 0, 1
    gmode 4, 640, 400, 64
    color 255, 255, 255
    pos 440, 312
    grotate  1, 0, 0, R_90, 640, 400

;----------  フォントサイズを計算して縦に一文字ずつ表示&色変化（全角文字のみ対応）  ----------
    font "ＭＳ 明朝", FontSize
    repeat 6
        wait 30
        color cnt*48, cnt*48, cnt*48
        pos 632-FontSize*2, FontSize*cnt
        mes strmid(Message, cnt*2, 2)
    loop