HSPTV!掲示板

質問させていただきます。
たとえばフロッピーディスクや、SD,M,CF,などのドライブにハードが刺さってるか
チェックすることはできるのでしょうか？
ＰＣに読み込まれてるドライブ（使用状況）をチェックするソースは６時間ぐぐって
見つけたのですが、ハードが刺さっているか刺さっていないかチェックするソースは
ＶＢ６で一つ見つけただけです。
しかし、ＶＢ使った時ないので理解できません。
ただ、そのやり方を見る限り正規なやり方ではなくエラー処理を逆手にとったやり方
みたいです。
http://homepage1.nifty.com/rucio/main/tyukyu/tyukyu3.htm
どなたかご教授お願いします。
なるべくエラーのdialogが出ないやり方でお願いします。

たぶんこんな感じ

newcom oFS,"Scripting.FileSystemObject"
chrdrv=""
repeat 26
poke chrdrv, 0, 65+cnt
if oFS("DriveExists",chrdrv+":") {
oDrive=oFS("GetDrive", chrdrv+":")
if oDrive("IsReady") {
if oDrive("DriveType") == 0 : mes chrdrv+": 不明です。"
if oDrive("DriveType") == 1 : mes chrdrv+": リムーバルディスクです。"
if oDrive("DriveType") == 2 : mes chrdrv+": ハードディスクです。"
if oDrive("DriveType") == 3 : mes chrdrv+": ネットワークドライブです。"
if oDrive("DriveType") == 4 : mes chrdrv+": CD-ROMです。"
if oDrive("DriveType") == 5 : mes chrdrv+": RAMディスクです。"
}
}
loop
delcom oFS
stop

　FD, MO, MS（というかPSP）はメディアがないとどうしてもダイアログが
出てしまうようですし（onerrorもHSP2のskiperrも効かない）、
CD・DVDはダイアログは出ないものの、メディアなしとファイル・フォルダなしが
区別できません。
未フォーマットはメディアがなく試せませんでした。

#include "hspext.as"

	drive="E"	;調べたいドライブ（半角大文字）

	type="不明", "なし", "リムーバブル", "ハードディスク", "ネットワークドライブ"
	type.5="CD,DVD", "RAMディスク"

	fxinfo info, peek(drive,0)-'@', 8
	mes type.info

	dir=drive+":\\"
	fxaget attr, dir: c=stat
	mes "attr="+attr+" stat="+stat

	mask=dir+"*.*"
	sdim buf,32000
	dirlist buf, mask: c=stat
	mes "stat="+c+" ["+buf+"]"
stop

お〜〜〜〜すごい！！！
woodfieldsさんの十分使えます！！！
ハードが刺さっていないとそのドライブが表示されないから、
チェックすることができるようになりました！！

ANTARESさんのはなぜか実行することができません。
hspext.asファイルが壊れてるのかＥＲＲがでます。
すみません・・＜(。_。)＞ モウシワケナイ
しかし、ありがとうございました。
大変助かります！！
これでファイル移植も完璧にできます。
本当にありがとうございました！！

ついでに、たちの悪いカードリーダーなんかも無敵のWindowsVistaでも絶対に大丈夫な究極のどろなわです（極遅です）。

#include "hspext.as"

chrdrv="" : buf_mes=""
repeat 26
	poke chrdrv, 0, 65+cnt
	sdim ln,4096
	sdim buf,32000
	pipeexec buf,"cmd /C dir "+chrdrv+": /w",1
	;if stat : dialog "実行できませんでした" : end
	;mes "実行中..."
	repeat
		pipeget ln          ; パイプの取得/更新
		if stat=0 : break   ; 実行終了ならループを抜ける
		wait 10
		;mes "実行完了..."
	loop
	notesel buf
	;mes ""+notemax+"\n\n"+buf
	if notemax <= 1 {				; 標準エラー出力が１行わたされてる
		noteget buf_mes,0			; 空行をカットしてる
		mes chrdrv+": "+buf_mes
	}else{
		mes chrdrv+":【ドライブは使用可能です。】"
	}
loop
stop

ヘルプのpipegetのサンプルスクリプトを利用してますが、おかげで「指定されたパスが見つかりません。」
「デバイスの準備ができていません。」の標準エラー出力までパイプに渡されてるという新たな発見に遭遇しました。

woodfieldsさんありがとうございます！！！
しかしＡドライブだけチェックできません。（πーπ）グスグス
新しい方も試してみたんですがＡドライブだけ認識してくれません！！

newcom oFS,"Scripting.FileSystemObject"
chrdrv=""
if oFS("DriveExists","A:") {
oDrive=oFS("GetDrive", "A:")
if oDrive("IsReady")=true : mes"err": else : mes"ok"

}

と、Ａドライブだけ指定してもハードが刺さってない状態で認識されます。
タイムラグが出てるのでしょうか？
他のドライブはちゃんと認識するのですが・・？？？？
意味が分かりません・・・。

は〜〜ＦＤだけあきらめるしかないのでしょうか・・。
ヾ(＠† ▽ †＠）ノうわーん

すみません・・。わかりました・・。
使えなくなったＦＤ刺してました・・。
大変申し訳ありませんでした！！！！
ｍ（．＿．）ｍ　ゴメン