HSPTV!掲示板

初めまして。
この掲示板の過去ログのinoviaさんのスクリプトを流用させてもらって
作成中の自作ゲームのオープニングでムービーを流してます。

inoviaさんのスクリプト

gsel 0,1			//ID0ウィンドウをアクティブ
	mref mr,67			//ウィンドウハンドル取得
	onexit *e			//終了時に移動
	dialog "mpg;*.avi;*.wmv;*.asf;*.3gp;*.mp4;*.flv",16,"動画など"
	//↑環境依存
	if stat=0:none=1			//未選択時に終了
	fname=refstr			//ファイル名を代入
	mci "open \""+fname+"\" alias f"
	if stat=-1 : dialog "Open err":end	//オープンエラー
	mci "window f handle "+mr.13		//ウィンドウハンドルをMCIに送信
	mci "put f destination at 0 0 "+ginfo_sizex+" "+ginfo_sizey//ウィンドウに貼り付け
	mci "play f repeat"
	stop
*e	//なるべくこれを呼び出す
	mci "stop all"//MCIはALLで全部クリアできます。
	mci "close all"
	end

このスクリプトのダイアログ部分を消して指定してあるムービーが最初に流れるようにしてます。
そしてムービーが終わった　or ムービー中にクリックされたら
タイトル画面に行くようにしてるんですが、
ムービー　→　タイトル画像　の時に画面がちらつくというか
ムービーの終わりの処理？が見えて画面が乱れます。
他の場所ではredrawやboxfを使ってちらつきはないんですけど
このムービーの終わりのちらつきはどう対処すれば良いですか？

本人登場です。(^_^;)
こんな感じにすれば、終了時にちらつかせないようにできます。

	gsel 0,1			//ID0ウィンドウをアクティブ
	mref mr,67			//ウィンドウハンドル取得
	onexit *e			//終了時に移動
	dialog "mpg;*.avi;*.wmv;*.asf;*.3gp;*.mp4;*.flv",16,"動画など"
	//↑環境依存
	if stat=0:none=1			//未選択時に終了
	fname=refstr			//ファイル名を代入
	mci "open \""+fname+"\" alias f"
	if stat=-1 : dialog "Open err":end	//オープンエラー
	mci "window f handle "+mr.13		//ウィンドウハンドルをMCIに送信
	mci "put f destination at 0 0 "+ginfo_sizex+" "+ginfo_sizey//ウィンドウに貼り付け
	mci "play f"

	//↓オブジェクト等を使っていなければ、メニューは動画再生中に描写したほうがいい。
	boxf
	color 255,255,255
	mes "メインメニュー"
	//↓こういうオブジェクトは後で描写する。
	//button "end",*e

*start
	mci "status f mode"
	if refstr="stopped"{//止まった時の処理
		mci "put f destination at -640 -480 640 480"//←無理やり画面の外へ追い出す。
		wait 10//処理が早すぎるのでウェイトをいれる。
		mci "stop f"
		mci "close f"
		goto *starttitle
	}
	stick key,1,1
	if key=256{//左クリックされた時の処理
		mci "put f destination at -640 -480 640 480"//←無理やり画面の外へ追い出す。
		wait 10//処理が早すぎるのでウェイトをいれる。
		mci "stop f"
		mci "close f"
		goto *starttitle
	}
	title ""+refstr
	wait 5
	goto *start
	
*starttitle
	//先ほど描写しなかったオブジェクトを貼り付け。
	button "end",*e

	stop

*e
	end

うわぁ！
どうもすいません＞＜
ありがとうございますうう！！
今まだ見たばかりなので組み込めてはいないんですけど
とりあえずお礼をば！
また後ほど結果をご連絡しまーっす！！

でっきましたっ！
もうまじ感謝ですわぁ！！
しかしmciってのは自分にはハードルが高い：；

せっかくだからここからメニュー画面のフェードインにも挑戦してみまっす！