HSPTV!掲示板

いま、テキストエディタを作っているのですが、
メモ帳のように、今の時刻をメッセージボックスに書き出すボタンを作りたいのですが
一部だけ、スクリプトを教えてください！

参考にしてください。

今の時刻を取得するスクリプト

	youbi="日","月","火","水","木","金","土"

	time =""+gettime(0)+"年"
	time+=""+gettime(1)+"月"
	time+=""+gettime(3)+"日"
	time+=""+youbi(gettime(2))+"曜日"
	time+="\n"
	time+=""+gettime(4)+"時"
	time+=""+gettime(5)+"分"
	time+=""+gettime(6)+"."+gettime(7)+"秒"

	mes time

メッセージボックスを書き換えるスクリプト

	a=""
	mesbox a,640,450,0
	button "button",*label
	stop
*label
	a+="Hot Soup Processor\n"
	objprm 0,a
	stop

・F5のキーコードは0x116
・oncmdで処理するのが望ましい
・日付はGettimeで取得できる
・文字列つなぎ合わせるには "月"+x+"日"でOK
・ちなみにメモ帳で、.LOGと最後にかいて保存すると、自動的に日付が付加されて保存されます。

1) gettime と strf をがんばって使って時刻の文字列を作る

Hour = strf("%02d", gettime(4))

2) 現在選択されているテキストエディタの先頭を取得する

sendmsg objinfo(mesbox_id,2), $B0, varptr(pStart), 0

んな感じ

ちょっと強引ですが、HSPEXTを使ってみたスクリプト。
あまり賢くない方法です。Win32APIが分からないぜ〜という方にはちょうどいいかも。
この方法はTESTというウィンドウが２つあったら確実にバグりますのでご注意を。
F5でメモ帳みたいに好きなカーソル位置に挿入可能です。

#include "hspext.as"

title "TEST"	//←同じ文字の方がいい
t=""
mesbox t,640,480,1,256*256
//button "時刻挿入",*times
onkey goto *times	//キー割り込み
stop

*times
if wparam=116{	//F5のキーコードです。
aplsel "TEST",0	//←同じ文字の方がいい
aplobj "EDIT",0

	youbi="日","月","火","水","木","金","土"

	time =""+gettime(0)+"年"
	time+=""+gettime(1)+"月"
	time+=""+gettime(3)+"日"
	time+=""+youbi(gettime(2))+"曜日"
	time+=""+gettime(4)+"時"
	time+=""+gettime(5)+"分"


aplstr ""+time
wait 20
}

メモ帳と同じ挙動なら、EM_REPLACESELメッセージを使ってください。

「EM_REPLACESEL HSP」とかでググれば情報でてきます。ここの掲示板の
過去ログにも多数。

sndmes命令を使ってみた例。

#define EM_REPLACESEL $C2

t=""
mesbox t,640,480,1,256*256
hE = objinfo(stat,2)	//statにはオブジェクトのIDが入っている。


//button "時刻挿入",*times
onkey goto *times	//キー割り込み
stop

*times
if wparam=116{	//F5のキーコードです。

	youbi="日","月","火","水","木","金","土"

	time =""+gettime(0)+"年"
	time+=""+gettime(1)+"月"
	time+=""+gettime(3)+"日"
	time+=""+youbi(gettime(2))+"曜日"
	time+=""+gettime(4)+"時"
	time+=""+gettime(5)+"分"

sendmsg hE,EM_REPLACESEL,0,""+time
wait 20
}

sndmes命令ではなくsendmsg命令でした〜(^_^;)

ありがとうございました！