HSPTV!掲示板

HSP初心者です。
オブジェクトIDからオブジェクトの種類を習得する方法はありますか？

できるかできないかで言えばできます。
ただし、windows限定ですが。
オブジェクトidからobjinfoを使ってウィンドウハンドルを取得
GetClassNameを使ってウィンドウクラス名を取得
で、大変なのがここからで、
クラス名がButonだったとします。
その時、buttonとchkboxがあります。
この場合、今度はウィンドウスタイルをGetWindowLongで取得する必要があります
クラス名がEditだったとします
その時、inputとmesboxがあります。
この場合、やはりウィンドウスタイルを取得する必要があります。
残りのオブジェクトはクラス名からの判断で出来ます。
ウィンドウスタイルが絡むとどうも苦手なので、
実際にプログラムを作るのは他の人に任せます。

きたないサンプルですが、良ければどうぞ。
一応、HSP標準命令で設置できるオブジェクトには対応しているはずです。

// オブジェクトIDからオブジェクトの種類を取得するサンプル
#module
	#uselib "user32.dll"
		#func GetClassName "GetClassNameA" sptr,sptr,sptr
		#func GetWindowLong "GetWindowLongA" sptr,sptr

	; p1 = オブジェクトのID
	; p2 = オブジェクトの種類を代入する変数
	; p3 = 取得するクラス名の長さ
	#deffunc GetObjType int objId, var ClassName, int nMaxCount
	
		objHwnd = objinfo_hwnd(objId)	// IDをハンドルに変換
		
		// クラス名取得
		sdim ClassName,nMaxCount
		GetClassName objHwnd,varptr(ClassName),nMaxCount
		
		// chkbox判定
		if ClassName=="Button"{
			; スタイルに BS_AUTOCHECKBOX が含まれているなら chkbox
			GetWindowLong objHwnd,-16
			if (stat & 0x00000003){
				ClassName = "Chkbox"
			}
		}
	
		// mesbox input判定
		if ClassName=="Edit"{
			; スタイルに ES_MULTILINE が含まれているなら mesbox
			GetWindowLong objHwnd,-16
			if (stat & 0x0004){
				ClassName = "mesbox"
			}else{
				ClassName = "input"
			}
		}
	return
#global


	title "オブジェクトIDからオブジェクトの種類を取得"
	color 0,0,255: boxf
	
	
	// オブジェクト設置
		objsize ginfo_winx,25
	
	; button
		pos ,ginfo_cy+10
		button "button",*hoge
		id_button = stat
	
	; chkbox
		pos ,ginfo_cy+10
		dim x
		chkbox "chkbox",x
		id_chkbox = stat
	
	; input
		pos ,ginfo_cy+10
		x = "input"
		input x
		id_input = stat
	
	; mesbox
		pos ,ginfo_cy+10
		x = "mesbox"
		mesbox x
		id_mesbox = stat
	
	; combox
		pos ,ginfo_cy+10
		dim x
		combox x,,"combox \ncombox"
		id_combox = stat
	
	; listbox
		pos ,ginfo_cy+10
		listbox x,0,"listbox"
		id_listbox = stat
	
	
	// 結果
		sdim sClassN,256
		color 255,255,255
		
		repeat 6
			GetObjType cnt, sClassN, 256
			mes str(cnt)+"："+sClassN
		loop
		
stop
*hoge

だいぶ被りましたが、こいるさんと似たようなモジュールです。

オブジェクトの種類を表す数値が飛び飛びになっているのは
winobjを使って『ラジオボタン』や『トグル式ではないチェックボックス』等を
使った時のための拡張用です。

数値自体に深い意味は無いので適当に変更しても問題ありません。

// オブジェクト判別モジュール
#module

#define	GWL_STYLE			-16

#uselib "user32.dll"
#cfunc	GetWindowLong "GetWindowLongA" int, int
#func	GetClassName "GetClassNameA" int, var, int

	// オブジェクトIDからオブジェクトの種類を判別
	#defcfunc GetObjKind int _id
		sdim clsname, 260;		// クラス名用変数の初期化
		style = 0;				// ウィンドウスタイル用変数の初期化

		GetClassName objinfo(_id, 2), clsname, 260;			// クラス名取得
		style = GetWindowLong(objinfo(_id, 2), GWL_STYLE);	// スタイル取得
		style -= 0x50000000;	// 全オブジェクトに共通するスタイルは除外（WS_CHILDWINDOW | WS_VISIBLE）

		if( clsname == "Button" ) {
		// Buttonコントロール
			style &= 0xF;	// 下位4ビットだけ取得
			if( style == 0 ) {			// プッシュボタン（BS_PUSHBUTTON）
				rc = 1;			// button
			}
			else:if( style == 3 ) {		// トグル式チェックボックス（BS_AUTOCHECKBOX）
				rc = 3;			// chkbox
			}
		}
		else:if( clsname == "ComboBox" ) {
		// ComboBoxコントロール
			style &= 0x3;	// 下位2ビットだけ取得
			if( style == 3 ) {				// ドロップダウンリストボックス（CBS_DROPDOWNLIST）
				rc = 13;		// combox
			}
		}
		else:if( clsname == "Edit" ) {
		// Editコントロール
			if( style & 4 ) {				// 複数行エディットコントロール（ES_MULTILINE）
				rc = 22;		// mesbox
			}
			else {
				rc = 21;		// input
			}
		}
		else:if( clsname == "ListBox" ) {
		// ListBoxコントロール
			rc = 31;			// listbox
		}

		return rc;

	// オブジェクトの種類を示す数値からオブジェクト名を返す
	#defcfunc GetObjName int _kind
		sdim name, 260;		// オブジェクト名用変数の初期化
		if( _kind == 0 ) {
			name = "unknown";	// 不明なオブジェクト
		}
		else:if( _kind == 1 ) {
			name = "button";
		}
		else:if( _kind == 3 ) {
			name = "chkbox";
		}
		else:if( _kind == 13 ) {
			name = "combox";
		}
		else:if( _kind == 21 ) {
			name = "input";
		}
		else:if( _kind == 22 ) {
			name = "mesbox";
		}
		else:if( _kind == 31 ) {
			name = "listbox";
		}

		return name;

#global

	// 以下サンプル
	objsize 100, 20;
	pos 0, 0;
	input inp, , , 50;
	obj_id = stat;

	obj_kind = GetObjKind(obj_id);
	obj_name = GetObjName(obj_kind);

	mes "オブジェクトの種類は "+obj_kind+" です。";
	mes "オブジェクト名は "+obj_name+" です。";

	stop;

あらやさん、サンプルありがとうございます！
参考にさせていただきます！

こいるさん、
サンプルありがとうございます😊
参考にさせていただきます

こいるさんのサンプルで解決出来ました
ありがとうございます