おにたまさんの[#defcfunc alien]に物理法則を融合

複数の追随者(ここでは３人)のスクリプトを載せます。
ただ、各ターゲットをそれぞれのキャラの真後ろにすると、リーダーのちょっとした動きでも、振れ幅が大きくなりすぎます。
動きは面白いけど......。プログラムに組み込むと、不都合なことが起こりやすいでしょう。
リーダー真後ろに等間隔で置いた方が扱いやすそうです。
書き換えのコメントのある行を◆◆～◆◆で置き換えると、各ターゲットを等間隔にしたものになります。
「sample/hgimg4/」に入れて実行してみて下さい。


#include "hgimg4.as"
title "ゾロゾロ関数(+物理法則)"

	gpreset

	setcls CLSMODE_SOLID, $404040

	gptexmat id_tex, "hsp3dish.png"	; テクスチャマテリアル作成
	gpfloor id_floor, 50, 50, , id_tex	; 床ノードを追加
	gppbind id_floor, 0

	setpos GPOBJ_CAMERA, 0,5,15	; カメラ位置を設定

	box_w=0.6 : box_x=0.0 : box_y=box_w/2 : box_z=0.0

;〓〓[id_model(0)]〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
	gpbox mo_box(0), box_w, 0x3333ff	; [id_model(0)]用箱ノードを追加 (青色)
	setpos mo_box(0), box_x, box_y, box_z
	setcoli mo_box(0), 1, 1	; コリジョングループ設定
	gppbind mo_box(0), 1.0, 1.0	; 物理設定
	setalpha mo_box(0), 64
;━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
	gpload id_model(0), "res/tamane"	; [tamane]モデル読み込み
	setscale id_model(0), 0.006,0.006,0.006
	setpos id_model(0), box_x, box_y-box_y/2, box_z

;〓〓[id_model(1)]〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
	gpbox mo_box(1), 0.6, 0x3333ff	; [id_model(1)]用箱ノードを追加 (青色)
	setpos mo_box(1), -6, 0.3, 5	; 仮の初期位置(基本的にどこでもいい)
	setcoli mo_box(1), 1, 1	; コリジョングループ設定
	gppbind mo_box(1), 1.0, 1.0	; 物理設定
	setalpha mo_box(1), 64
;━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
	gpload id_model(1), "res/tamane2"	; [tamane2]モデル読み込み
	setscale id_model(1), 0.007,0.007,0.007
	setpos id_model(1), 0, 0.0, 0	; 仮の初期位置(基本的にどこでもいい)
	; メインループ内で、[id_model(1)]用箱の位置をコピー

;〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
	getpos mo_box(1), x, y, z

;〓〓[id_model(2)]〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
	gpbox mo_box(2), 0.6, 0x3333ff	; [id_model(2)]用箱ノードを追加 (青色)
	setpos mo_box(2), x-1, y, z-1	; 仮の初期位置(基本的にどこでもいい)
	setcoli mo_box(2), 1, 1	; コリジョングループ設定
	gppbind mo_box(2), 1.0, 1.0	; 物理設定
	setalpha mo_box(2), 64
;━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
	gpload id_model(2), "res/tamane2"	; [tamane2]モデル読み込み
	setscale id_model(2), 0.004,0.006,0.004
	setpos id_model(2), 2, 0.0, 2	; 仮の初期位置(基本的にどこでもいい)
	; メインループ内で、[id_model(2)]用箱の位置をコピー

;〓〓[id_model(3)]〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
	gpbox mo_box(3), 0.6, 0x3333ff	; [id_model(3)]用箱ノードを追加 (青色)
	setpos mo_box(3), x-3, y, z-3	; 仮の初期位置(基本的にどこでもいい)
	setcoli mo_box(3), 1, 1	; コリジョングループ設定
	gppbind mo_box(3), 1.0, 1.0	; 物理設定
	setalpha mo_box(3), 64
;━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
	gpload id_model(3), "res/tamane2"	; [tamane2]モデル読み込み
	setscale id_model(3), 0.005,0.007,0.005
	setpos id_model(3), 2, 0.0, 2	; 仮の初期位置(基本的にどこでもいい)
	; メインループ内で、[id_model(3)]用箱の位置をコピー

;〓〓障害物〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
	gpbox block_A, 1.2, 0xffff00	; 障害物用箱ノードを追加 (黄色)
	setpos block_A, -2, 0.6, 2
	setcoli block_A, 1, 1
	gppbind block_A, 0	; 物理設定 = 動かない
	setalpha block_A, 192
;━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
	gpbox block_B, 1.2, 0xffff00	; 障害物用箱ノードを追加 (黄色)
	setpos block_B, 3, 0.6, -8
	setcoli block_B, 1, 1
	gppbind block_B, 0	; 物理設定 = 動かない
	setalpha block_B, 192
;━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
	gpbox block_C, 1.2, 0xffff00	; 障害物用箱ノードを追加 (黄色)
	setpos block_C, 6, 0.6, 4
	setcoli block_C, 1, 1
	gppbind block_C, 0	; 物理設定 = 動かない
	setalpha block_C, 192
;━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━

;〓〓ターゲット〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
	gpbox target(0), 0.2, 0xff0000	; ターゲット用箱ノードを追加 (赤色)
	gpbox target(1), 0.2, 0xff0000	; ターゲット用箱ノードを追加 (赤色)
	gpbox target(2), 0.2, 0xff0000	; ターゲット用箱ノードを追加 (赤色)

;〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
	gpact id_model(0)
	gpact id_model(1)
	gpact id_model(2)
	gpact id_model(3)

	number=3	; 従者の人数

;〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
*MainLoop

	stick key,15
	if key&128 : end

	if key&2 {	; ■■ [↑]キーで、前進
		; [モデルの向きの変化量] が [カメラの向きの変化量] と違うならば
		if model_cnt!=ca_cnt : gosub *model_cnt_set	; [モデル=id_model(0)] の向きを操作

		; [モデルの向きの変化量] が [カメラの向きの変化量] に同じならば
		if model_cnt=ca_cnt {
			; deg2rad(ca_deg) = カメラ角度(ca_deg)をラジアンに変換して
			Mx=sin (deg2rad(ca_deg))*(0.1)
			Mz=cos (deg2rad(ca_deg))*(0.1)

			gppapply mo_box(0), GPPAPPLY_IMPULSE, Mx, 0.0, Mz	; 珠音用箱に[GPPAPPLY_IMPULSE](=瞬間的な衝撃)を与える
			}

		setangr id_model(0), 0.0, model_cnt, 0.0
		}

	if key&8 {	;■■ [↓]キーで、後退
		; [モデルの向きの変化量] が [カメラの向きの変化量] と違うならば
		if model_cnt!=ca_cnt : gosub *model_cnt_set	; [モデル=id_model(0)] の向きを操作

		; [モデルの向きの変化量] が [カメラの向きの変化量] に同じならば
		if model_cnt=ca_cnt {
			; deg2rad(ca_deg) = カメラ角度(ca_deg)をラジアンに変換して
			Mx=sin (deg2rad(ca_deg))*(-0.03)
			Mz=cos (deg2rad(ca_deg))*(-0.03)

			gppapply mo_box(0), GPPAPPLY_IMPULSE, Mx, 0.0, Mz
			}

		setangr id_model(0), 0.0, model_cnt, 0.0
		}

;■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
;	次の ①→②→③→④ を繰り返すことで、順次、後を追っていくモデルの動きとなる
;	ただ、主人となる[モデル]は、操作による回転/移動(位置決め)なので、自らの[ターゲット]はない
;	当然、① はなく、次の ② から始まり、操作している [ボックス] に 主人の [モデル] をセット
;	③ の回転の代わりに、それと連動するカメラの動きを入れる
;	④ の回転値は、操作による回転なので、これまた当然、求める必要はなく
;	次の ① で、自らの[モデル] の回転値に、操作による回転値(model_cnt)を使って、最初の従者用の[ターゲット]の位置決めをする
;	ここからは、②→③→④→①→②→③ とループしていくが、最後の従者は、③ でループ終了

;	■■ ① ■■ [モデル] の回転に応じて、その[モデル]の後ろに 次の [ターゲット] の位置を決める

;	■■ ② ■■ [ターゲット] に近づいて行く [ボックス] に [モデル] をセット

;	■■ ③ ■■ その [モデル] の向きを 前の [モデル] の方向に向き直す
;
;	■■ ④ ■■ 操作している [モデル] の回転値を求める
;■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■


;■■ ② ■■ 操作している [ボックス=mo_box(0)] に 主人の [モデル=id_model(0)] をセット
;■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
	getpos mo_box(0), x, y, z
	setpos id_model(0), x, y-box_w/2, z

;■■ ③ ■■ (カメラをセット)その [モデル=id_model(0)] の向きを操作
;■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
	base_x=x : base_y=y : base_z=z
	gosub *camera_set	; カメラをセット


repeat number + 1	; number=3

	if cnt!=0 {	; 主人 でなければ

;■■ ③ ■■ その [モデル=id_model(cnt)] の向きを 前の [モデル=id_model(cnt-1)] の方向に向き直す
;■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
		getpos id_model(cnt-1), mo_x, mo_y, mo_z
		gplookat id_model(cnt), mo_x, mo_y, mo_z
		addangr id_model(cnt), 0, 128, 0

;■■ ④ ■■ その [モデル=id_model(cnt)] の回転値を求める
;■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
;〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆
		getangr id_model(cnt), angr_x, angr_y, angr_z

;〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆
		if angr_x = 0 {
			angr255_y = ( angr_y+256) \ 256
			} else {
			angr255_y = (-angr_y+384) \ 256
			}
;〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆〇●□■◇◆
		}

;■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
;■■ ① ■■ [モデル] の回転に応じて、その[モデル=id_model(cnt)]の後ろに 次の [ターゲット=target(cnt)] の位置を決める
;■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
	if cnt=0 : angr_cnt=model_cnt	; 主人 ならば
	if cnt!=0 : angr_cnt=angr255_y	; 主人 でなければ

	if cnt!=number {	; 最後の従者 でなければ
		mo_deg=360* angr_cnt /256	;この行を ◆◆[ mo_deg=360* model_cnt /256 ]◆◆ で、ターゲット等間隔
		marker_x=sin (deg2rad(mo_deg))*1.2	;この行を ◆◆[ marker_x=sin (deg2rad(mo_deg))*1.2 *(cnt+1) ]◆◆ で、ターゲット等間隔
		marker_z=cos (deg2rad(mo_deg))*1.2	;この行を ◆◆[ marker_z=cos (deg2rad(mo_deg))*1.2 *(cnt+1) ]◆◆ で、ターゲット等間隔

		getpos mo_box(cnt), x, y, z
		setpos target(cnt), x-marker_x, 0.1, z-marker_z
		getpos target(cnt), target_x, target_y, target_z

; その [ターゲット=target(cnt)] に、次の [ボックス=mo_box(cnt+1)] を 近づけていく
;■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
		getpos mo_box(cnt+1), now_x, now_y, now_z	; [mo_box(cnt+1)]の 現在の位置

		etx=alien( now_x, target_x)	; [mo_box(cnt+1)]の 進むべき X座標
		etz=alien( now_z, target_z)	; [mo_box(cnt+1)]の 進むべき Z座標

	;■■ 新規関数[#defcfunc alien] へ行く ＝ [gosub *#defcfunc alien ～ return 戻り値] のようなかたち
//	setpos mo_box(cnt+1), etx, 0.0, etz
	; メインループ毎時の [mo_box(cnt+1)]の進むべき[etx, 0.0, etz]の位置 と 現在の[mo_box(cnt+1)]の位置 との差

		impulse_x = etx - now_x	; X方向の差
		impulse_z = etz - now_z	; Z方向の差

	; この差をX,Z方向の[impulse]として、[GPPAPPLY_IMPULSE]で、[ボックス=mo_box(cnt+1)]を動かす
		gppapply mo_box(cnt+1), GPPAPPLY_IMPULSE, impulse_x, 0, impulse_z

;■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
;■■ ② ■■ [ターゲット] に近づいて行く [ボックス=mo_box(cnt+1)] に [モデル=id_model(cnt+1)] をセット
;■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
		getpos mo_box(cnt+1), x, y, z
		setpos id_model(cnt+1), x, y-box_w/2, z

;■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
;■■ ③ ■■ その [モデル=id_model(cnt+1)] の向きを 前の [モデル=id_model(cnt)] の方向に向き直す
;■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
		getpos id_model(cnt), mo_x, mo_y, mo_z
		gplookat id_model(cnt+1), mo_x, mo_y, mo_z
		addangr id_model(cnt+1), 0, 128, 0

		}

loop


;━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
	redraw 0	; 描画開始
	gpdraw	; シーンの描画
	redraw 1	; 描画終了
	await 1000/60	; 待ち時間

goto *MainLoop


;〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
#defcfunc alien double value, double value2	; [double] = 実数値に変換

	esp(0)=0.09*2.0 : esp(1)=0.08*2.0	; [tamane2]用箱 の移動スピード

;	res=limitf( value2-value, -esp(0), esp(1) )	; [limit] ではなく、[limitf]実数値 とする
;	return value+res

;	上記の２式を合わせて ↓↓
	return value+limitf( value2-value, -esp(0), esp(1) )

;〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
*camera_set
	if key&1 {	; [←]キー
		ca_cnt++
		if ca_cnt=256 : ca_cnt=0
		}
	if key&4 {	; [→]キー
		ca_cnt--
		if ca_cnt=-256 : ca_cnt=0
		}

	setangr GPOBJ_CAMERA, 0, ca_cnt, 0

//	[モデルの向き]≠[カメラの向き]の場合も組み入れているので、この命令は削除
//	setangr id_model, 0, ca_cnt, 0	; 珠音も、カメラと同じだけの回転量


//	[ca_cnt](=256で一回転)を増減することで、カメラの移動方向の角度[ca_deg]を変える
//	単位係数を(-20)として、珠音用箱からの カメラ位置のＸ/Ｚ方向の距離を求め、カメラをセットする
	ca_deg=360*ca_cnt/256
	; deg2rad( ) = 度をラジアンに変換
	Cx=sin (deg2rad(ca_deg))*(-20)
	Cz=cos (deg2rad(ca_deg))*(-20)

	setpos GPOBJ_CAMERA, base_x+Cx, base_y+10, base_z+Cz	; カメラをセット

	gplookat GPOBJ_CAMERA, base_x, base_y-7, base_z	; カメラから指定した座標(珠音用箱方向)を見る

return

;〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
*model_cnt_set
		; [モデルの向きの変化量] が [カメラの向きの変化量] より大きいならば
		if model_cnt>ca_cnt {
			sa=model_cnt-ca_cnt
			if sa<=128 : model_cnt-- : if model_cnt<ca_cnt : model_cnt=ca_cnt
			if sa>128 : model_cnt++ : if model_cnt>(ca_cnt+256) : model_cnt=ca_cnt
			}

		; [モデルの向きの変化量] が [カメラの向きの変化量] より小さいならば
		if model_cnt<ca_cnt {
			sa=model_cnt-ca_cnt
			if sa>=-128 : model_cnt++ : if model_cnt>=ca_cnt : model_cnt=ca_cnt
			if sa<-128 : model_cnt-- : if model_cnt<=(ca_cnt-256) : model_cnt=ca_cnt
			}

return

;〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
HSPTV!掲示板
