まず、文字列の中に「\」を含めたいのなら、「\\」と2個連続で書く必要があります。
それから、フォントのインストール場所ですが、
「C:\Users\ユーザー名\AppData\Local\Microsoft\Windows\Fonts」と
「C:\Windows\Fonts」の2箇所がありますので、ユーザーフォルダだけを
チェックしてもそれだけでは足りません。
（実際私の環境でも「C:\Users\ユーザー名\AppData\Local\Microsoft\Windows」に
Fontsというフォルダはありませんでした）
また、ユーザー名にUnicodeが含まれている場合ですと、
hsp3utfを利用しないと、普通のやり方ではフォルダにアクセスすることはできません。
（アクセスできないこともないが、WinAPIを駆使するなど、だいぶ話が面倒になる）
「フォントを同梱し、そのフォントを使いたい」ということなら、
私が過去に「インストールなしでフォントを使用するモジュール」を
作りましたので、それを利用するのはどうでしょうか？
//フォントをインストールせずに使用するモジュール
#include "gdi32.as"
#module
#const use_fonts 10 //登録できるフォントの最大数(変更可能)
#const global FR_PRIVATE 0x10 //「登録したフォントをこのプログラムだけで使用する」オプション
#const global FR_NOT_ENUM 0x20 //「登録したフォントがフォント選択ダイアログ等で表示されないようにする」オプション
#deffunc font_file_init
l_flag=0
dim l_opt,use_fonts
sdim l_name,64,use_fonts
return
//font_file p1,p2,p3
//指定したファイル名のフォントを一時的に使えるように登録する。
//p1はフォントのファイル名。
//p2を1にした場合はこれまでの登録を解除。(省略時は0)
//p3はFR_PRIVATEかFR_NOT_ENUMか、もしくは0かを指定。(省略時はFR_PRIVATEとFR_NOT_ENUMの両方とも有効)
#define global font_file(%1,%2=0,%3=0x30) _font_file %1,%2,%3
#deffunc _font_file str file,int cl_flag,int opt
if cl_flag : font_clean
if l_flag>=use_fonts : return 0
l_opt(l_flag)=opt
l_name(l_flag)=file
l_flag++
AddFontResourceEx file,opt,0
if stat=0 : l_flag--
return stat
#deffunc font_clean onexit
repeat
if l_flag<=0 : break
l_flag--
RemoveFontResourceEx l_name(l_flag),l_opt(l_flag),0
loop
return
#global
font_file_init //←最初に実行する
//以下、使用例
//サブフォルダ「font」に「k8x12S.ttf」があるものとする。
font_file "font\\k8x12S.ttf" //フォントのファイル名を指定
font "k8x12S",20
mes "東京特許許可局"
ドライブ:\Users\ユーザー名\AppData\Local\Microsoft\Windows\Fontsの中身を取得したい
