HSPTV!掲示板

こんにちは。
HSP 3.6を使って円を等分する点の上に縦50×横10の四角形を配置します。
以下のコードで６等分の場合が完成することを確認しました。

#const vert 50 // 縦の長さ
#const hori 10 // 横の長さ
#const r1 100  // 円の半径

val1 = sqrt(3)

screen 1, ginfo_dispx, ginfo_dispy 

color 0, 0, 0

// ６等分
boxf ginfo_dispx/2-hori/2, ginfo_dispy/2-r1-vert/2, ginfo_dispx/2+hori/2, ginfo_dispy/2-r1+vert/2

boxf ginfo_dispx/2+r1/2*val1-hori/2, ginfo_dispy/2-r1/2-vert/2, ginfo_dispx/2+r1/2*val1+hori/2, ginfo_dispy/2-r1/2+vert/2

boxf ginfo_dispx/2+r1/2*val1-hori/2, ginfo_dispy/2+r1/2-vert/2, ginfo_dispx/2+r1/2*val1+hori/2, ginfo_dispy/2+r1/2+vert/2

boxf ginfo_dispx/2-hori/2, ginfo_dispy/2+r1-vert/2, ginfo_dispx/2+hori/2, ginfo_dispy/2+r1+vert/2

boxf ginfo_dispx/2-r1/2*val1-hori/2, ginfo_dispy/2+r1/2-vert/2, ginfo_dispx/2-r1/2*val1+hori/2, ginfo_dispy/2+r1/2+vert/2

boxf ginfo_dispx/2-r1/2*val1-hori/2, ginfo_dispy/2-r1/2-vert/2, ginfo_dispx/2-r1/2*val1+hori/2, ginfo_dispy/2-r1/2+vert/2

同じように１２等分で１〜３つ目まで進めたところ、
１番目と３番目は表示されるのに、２番目の四角形は画面に表示されないことに気がつきました。

#const r2 200 // 円の半径
// １２等分
boxf ginfo_dispx/2-hori/2, ginfo_dispy/2-r2-vert/2, ginfo_dispx/2+hori/2, ginfo_dispy/2-r2+vert/2 // １番目

boxf ginfo_dispx/2+r2/2-hori/2, ginfo_dispy/2-r2/2*val1-vert/2, ginfo_dispx/2+r2/2+hori/2, ginfo_dispy/2-r2/2*val1+vert/2 // ２番目

boxf ginfo_dispx/2+r2/2*val1-hori/2, ginfo_dispy/2-r2/2-vert/2, ginfo_dispx/2+r2/2*val1+hori/2, ginfo_dispy/2-r2/2+vert/2 // ３番目

また、sin, cos関数を使って試みると、
２番目が表示されないことに加え、３番目の位置が変わってしまいました。

val2 = sin(Π/6)
val3 = cos(Π/6)

boxf ginfo_dispx/2-hori/2, ginfo_dispy/2-r2-vert/2, ginfo_dispx/2+hori/2, ginfo_dispy/2-r2+vert/2 // １番目

boxf ginfo_dispx/2+r2*val2-hori/2, ginfo_dispy/2-r2*val3-vert/2, ginfo_dispx/2+r2*val2+hori/2, ginfo_dispy/2-r2*val3+vert/2 // ２番目

boxf ginfo_dispx/2+r2*val3-hori/2, ginfo_dispy/2-r2*val2-vert/2, ginfo_dispx/2+r2*val3+hori/2, ginfo_dispy/2-r2*val2+vert/2 // ３番目

なぜ２番目の四角形は表示されないのでしょうか。
分かる方いらっしゃいましたら助言お願いいたします。

１０等分などの場合も予定しているので、
sin, cos関数を利用したコードについても助けていただけると幸いです。
よろしくお願いいたします。

描く四角形それぞれについて一つ一つ位置を手計算していたのでは大変ですので、
「sin, cos関数を利用したコード」を最初から作った方が楽だと思います。
「div=12」の部分を10にすれば10等分もできます。

#const vert 50 // 縦の長さ
#const hori 10 // 横の長さ
#const r1 200  // 円の半径

#const vert2 vert/2
#const hori2 hori/2
#define boxf_c(%1,%2) boxf (%1)-hori2,(%2)-vert2,(%1)+hori2-1,(%2)+vert2-1
//↑「boxf_c p1,p2」で、(p1,p2)を中心にhori×vertの四角形を描く

screen 1, ginfo_dispx, ginfo_dispy 
x0=ginfo_dispx/2 : y0=ginfo_dispy/2	//円の中心

color 0,0,0

div=12	//円を何等分するか

repeat div
	t=M_PI*2*cnt/div	//角度
	x=int(cos(t)*r1)+x0 : y=int(sin(t)*r1)+y0
	boxf_c x,y
loop

沢渡様
回答ありがとうございます。

#defineを利用して効率的に表示するということに考えが至りませんでした、、
大いに勉強になります、ありがとうございます。

回答を参考にさせていただき、円を６等分する点上に四角形を表示して、
そのうち任意のものを傾けるプログラムを作成しました。

#const vert 50 // 縦の長さ
#const hori 10 // 横の長さ
#const r 100   // 円の半径

#const vert2 vert/2
#const hori2 hori/2
#define boxf_c(%1,%2) boxf (%1)-hori2,(%2)-vert2,(%1)+hori2-1,(%2)+vert2-1
//↑「boxf_c p1,p2」で、(p1,p2)を中心にhori×vertの四角形を描く
#define grect_c(%1,%2) grect (%1),(%2),π/2,hori,vert

screen 1, ginfo_dispx, ginfo_dispy

x0=ginfo_dispx/2 : y0=ginfo_dispy/2	//円の中心

color 0,0,0

div=6	//円を何等分するか

repeat div
	t=M_PI*2*cnt/div	//角度
	x=int(cos(t)*r)+x0 : y=int(sin(t)*r)+y0
	if cnt=0 : {
		grect_c x,y
} else {
		boxf_c x,y
}
loop
stop

最初に表示する四角形だけを90°回転させたいのですが回転しないまま表示されてしまいます。
90など数字を直接入れると回転はしますが、想定した状態ではありませんでした。

角度の入力に問題があると思うのですが、grect命令について調べても有益な情報を見つけることができず。
重ね重ねで恐縮ではあるのですが、お助けいただけないでしょうか。

「Π」というギリシャ文字にはHSPでは特別な意味はありませんよ。
「Π」をM_PI(円周率を表す定数)に置き換えれば上手くいくと思いますが。

単純なところを見落としていました。
ありがとうございました。