HSPTV!掲示板

日時書式指定文字列の変換の方法を教えてしてください。
例えば、現在の日時が"2016/6/10 21:22:02"だとしたら、
"YYYY-MM-DD(dddd) tt h:mm:ss"で変換すると、"2016-06-10(金曜日) 午後 9:22:02"
と、返ってくるやつです。

DateTimeオブジェクトを使えば良いとかあるのですが、よくわかりません。

strfを使う方法では問題あるでしょうか？

sdim youbi,8,7
youbi="日曜日","月曜日","火曜日","水曜日","木曜日","金曜日","土曜日"
sdim zengo,6,2
zengo="午前","午後"

ye=gettime(0)	//年
mo=gettime(1)	//月
wd=youbi(gettime(2))	//曜日
da=gettime(3)	//日
ap=zengo(gettime(4)/12)	//午前午後
ho=gettime(4)\12	//時
mi=gettime(5)	//分
se=gettime(6)	//秒

mes strf("%04d-%02d-%02d("+wd+") "+ap+" %02d:%02d:%02d",ye,mo,da,ho,mi,se)

hsp3util.asに答えがある

GetDateFormat()
GetTimeFormat()
あたりを使ってみるとか？

https://msdn.microsoft.com/ja-jp/library/cc422084.aspx
https://msdn.microsoft.com/ja-jp/library/cc447950.aspx

#include "kernel32.as"
#define LOCALE_SYSTEM_DEFAULT 0x0400

	
	// https://msdn.microsoft.com/ja-jp/library/cc422084.aspx
	// https://msdn.microsoft.com/ja-jp/library/cc447950.aspx


	// 現在日付時刻版
	sdim DateStr, 256 + 1
	sdim TimeStr, 256 + 1
	
	GetDateFormatA LOCALE_SYSTEM_DEFAULT, 0, 0, "yyyy-MM-dd(dddd)", varptr(DateStr), 256
	GetTimeFormatA LOCALE_SYSTEM_DEFAULT, 0, 0, "tt h:mm:ss", varptr(TimeStr), 256

	mes "現在日付時刻：" + DateStr + " " + TimeStr

	// 任意の日付・時刻
	dim SYSTEMTIME, 4
	wpoke SYSTEMTIME, 0, 2016	// 年
	wpoke SYSTEMTIME, 2, 6		// 月
	;wpoke SYSTEMTIME, 4, 5		// 曜日
	wpoke SYSTEMTIME, 6, 10		// 日
	wpoke SYSTEMTIME, 8, 21		// 時
	wpoke SYSTEMTIME, 10, 22	// 分
	wpoke SYSTEMTIME, 12, 02	// 秒
	wpoke SYSTEMTIME, 14, 000	// ミリ秒

	GetDateFormatA LOCALE_SYSTEM_DEFAULT, 0, varptr(SYSTEMTIME), "yyyy-MM-dd(dddd)", varptr(DateStr), 256
	GetTimeFormatA LOCALE_SYSTEM_DEFAULT, 0, varptr(SYSTEMTIME), "tt h:mm:ss", varptr(TimeStr), 256

	mes "任意日付時刻：" + DateStr + " " + TimeStr

みなさんありがとうございます。
解決しました。