HSPTV!掲示板

題名の通り、ieコンポーネントを非表示にすることはできないでしょうか。
ShowWindow関数を使っても、うまくいきません。
これはhttp://www.geocities.co.jp/Playtown-Yoyo/6130/hsp/hsp-object-hide.htmlのサンプル
をieコンポーネントに置き換えたものです。

#include "user32.as"

	pos 100, 100
	chkbox "ちぇっく", a
	hChkbox = objinfo(stat, 2)	; ウィンドウハンドル取得

	button "切り替え", *change1

	pos 200, 100
	axobj web,"Shell.Explorer.2",100,50
	web->"Navigate""www.google.co.jp"
	hCombox = objinfo(stat, 2)	; ウィンドウハンドル取得

	button "切り替え", *change2

	stop

*change1
	if check1 {
		ShowWindow hChkbox, 5
	} else {
		ShowWindow hChkbox, 0
	}

;	0 or 1 のスイッチ処理
	check1 ^ 1

	stop

*change2
	if check2 {
		ShowWindow hCombox, 5
	} else {
		ShowWindow hCombox, 0
	}

	check2 ^ 1

	stop

お願いします！

obj.asのresizeobjでサイズをゼロにするのはどうでしょうか？
http://hsp.tv/play//pforum.php?mode=pastwch&num=67093
が参考になれば。

#include "user32.as"

	pos 100, 100
	chkbox "ちぇっく", a
	hChkbox = objinfo(stat, 2)	; ウィンドウハンドル取得

	button "切り替え", *change1

	pos 200, 100
	axobj web,"Shell.Explorer.2",100,50
	hCombox = objinfo(stat, 2)	; stat=2 [オブジェクトID]
	web->"Navigate""www.google.co.jp"
	//hCombox = objinfo(stat, 2)	; stat=0 [web->"Navigate"の戻り値]

	button "切り替え", *change2

	stop
/*〜〜 以下略 〜〜*/

上記のようにしてもうまくいかないでしょうか？

statの値はヘルプ内で明示してない命令等でも頻繁に書き換わるので、
必要ならその命令の直後に使用(或いは変数に格納)した方が良いですよ。

774さん、ありがとうございます！
こんな簡単なことだったのですね！
いやあ、こんなことで質問してしまい申し訳ないです。

#include "user32.as"

	pos 100, 100
	chkbox "ちぇっく", a
	hChkbox = objinfo(stat, 2)	; ウィンドウハンドル取得

	button "切り替え", *change1

	pos 200, 100
	axobj web,"Shell.Explorer.2",100,50
	hCombox = objinfo(stat, 2)	; ウィンドウハンドル取得
	web->"Navigate""www.google.co.jp"

	button "切り替え", *change2

	stop

*change1
	if check1 {
		ShowWindow hChkbox, 5
	} else {
		ShowWindow hChkbox, 0
	}

;	0 or 1 のスイッチ処理
	check1 ^ 1

	stop

*change2
	if check2 {
		ShowWindow hCombox, 5
	} else {
		ShowWindow hCombox, 0
	}

	check2 ^ 1

	stop