HSPTV!掲示板

API関数[MessageBox]で作ったダイアログについて質問です。

#include "user32.as"
text1="テストです"
text2="タイトルのテスト"
MessageBox hwnd , varptr(text1) , varptr(text2) , 0x00004000
mes stat

http://msdn.microsoft.com/ja-jp/library/cc410914.aspx
こちらのサイトで見たのですが、ヘルプボタンが押されたとき、
「メッセージボックスに［ヘルプ］ボタンを追加します。ユーザーが［ヘルプ］ボタンをクリックするか F1 キーを押すと、システムはオーナーへ メッセージを送信します。」
と書いてありました。
しかし、取得の方法が良く分かりませんでした。
どうすれば、取得できるでしょうか？

#include "user32.as"
oncmd gosub *onhelp,$00000053
//WM_HELP
text1="テストです"
text2="タイトルのテスト"
MessageBox hwnd , varptr(text1) , varptr(text2) , 0x00004000
mes stat
stop
*onhelp
dialog "ヘルプがクリックされました"
return

oncmdとWM_HELPについて調べてみてください。

閉じる処理付き

#include "user32.as"

#define WM_CLOSE 0x0010
#define WM_HELP 0x0053
#define MB_HELP 0x00004000

oncmd gosub *OnWMHelp, WM_HELP

	text1 = "テストです"
	text2 = "タイトルのテスト"
	MessageBox hwnd, varptr(text1), varptr(text2), MB_HELP
	mes stat
	
stop

*OnWMHelp
	
	mes "HELPが押された"

	// 
	// HELPを押した後ダイアログを閉じる必要がある場合の処理です 
	//

	dim HELPINFO, 7
	dupptr HELPINFO, lparam, 4*7, 4

	// ウィンドウハンドル
	tHwnd = HELPINFO(3)
	sendmsg tHwnd, WM_CLOSE
	
	//
	//
	//
	
return

ありがとうございました！