HSPTV!掲示板

↓で作ったんですが実行すると文字が点滅してします...
screen 0,176,20
*C1
cls
nen=gettime (0):gatu=gettime (1):nichi=gettime (3):ji=gettime (4):fun=gettime (5):byou=gettime (6):miri=gettime (7)
if ji<10:ji="0"+ji+""
if fun<10:fun="0"+fun+""
if byou<10:byou="0"+byou+""
if miri<10:miri="0"+miri+""
if nichi<10:nichi="0"+nichi+""
if gatu<10:gatu="0"+gatu+""
mes ""+nen+"/"+gatu+"/"+nichi+" "+ji+":"+fun+":"+byou+"."+miri+"
goto *c1

脱字発見！！
誤：点滅してします...
正：点滅してしまいます...

文字のちらつき(点滅)を抑えるにはredraw命令が使えます。
詳しくはヘルプを参照してください。

下に改良したソースを載せておきました。
何か違ったらすいません・・・

//screen 0,176,20
screen 0,186,20 ; 一桁入っていなかったので少し大きくしました。
*C1
redraw 0 ; この命令から先は描画しても反映されなくなる
color 255,255,255 : boxf ; clsだとredraw命令も消えてしまうのでこちらを使うのが適しています。
//ここから先は貴殿のプログラムと同じです。
nen=gettime (0):gatu=gettime (1):nichi=gettime (3):ji=gettime (4):fun=gettime (5):byou=gettime (6):miri=gettime (7)
if ji<10:ji="0"+ji+""
if fun<10:fun="0"+fun+""
if byou<10:byou="0"+byou+""
if miri<10:miri="0"+miri+""
if nichi<10:nichi="0"+nichi+""
if gatu<10:gatu="0"+gatu+""
pos 0,0//座標を左上に指定する
color 0,0,0 ; mes命令で描画する文字の色を黒にする
mes ""+nen+"/"+gatu+"/"+nichi+" "+ji+":"+fun+":"+byou+"."+miri+"
//ここまでが貴殿のプログラムと同じです。
redraw 1 ; redraw 0 からこの命令までに描画したものをすべて反映
await ; repeat〜loopの間にはwaitからawaitを入れないと動作を停止してしまいます。
goto *c1

ヘルプの説明が分かりにくいですが
clsは画面の消去ではなく『初期化』を行う命令です。

HSPでの画面の消去は通常boxf等で『画面を上書きする』事で代用して下さい。
その際、redraw 0とredraw 1の間に描画命令を記述する事で
チラつきを防ぐ事が可能です。

Hathinoさん、有難う御座います。
本当にワガママで申し訳ありませんが、ボタンをつけて終了できるようにしたいんです
本当にすみません！！教えてください

Hathinoさん、有難う御座います。
本当にワガママで申し訳ありませんが、ボタンをつけて終了できるようにしたいんです
本当にすみません！！教えてください
これ取り消します

ありさん、こんな初心者に分かりやすく説明していただき有難う御座いました
clsは初期化をおこなうんですね
有難うございました

解決しました。ありさん、Hathinoさん有難う御座いました！

桁合わせなら”strf:書式付き文字列を変換”を使うとif命令が少なくなりますね。

screen 0,186,20
*c1
	redraw 0
	color 255,255,255	:boxf
	pos 0,0	:color 0,0,0
	mes strf("%d/%02d/%02d %02d:%02d:%02d.%03d",gettime(0),gettime(1),gettime(3),gettime(4),gettime(5),gettime(6),gettime(7))
	redraw 1
	await 1
goto *c1

たんすさん
かなりコンパクトになりましたね
有難う御座います

NO.62180のスクリプトコピペした実行してみたら
確かに点滅している上、操作しようとするとフリーズした。

GOMEKIT!さん
フッ！フリーズしましたぁ！？

ではHathinoさんのプログラムを起動してみてください！！

少し、落ち着きましょう・・・