HSPTV!掲示板

onkey gosub *keydown

*main
	if ginfo_cy>ginfo_winy : cls
	mes "0.5秒"	;0.5秒感覚でメッセージ
	await 500
	goto *main
*keydown
	mes iparam	;WM_KEYDOWNでキーコード表示
	return

このソースコードを実行すると0.5秒間隔でメッセージが表示されます
でもなにかウィンドウメッセージに反応すると直後のawaitやwaitが消えるんですが、これはバグでしょうか？

ヘルプには特に記述は見つからなくて、ゲームなんかでウィンドウメッセージを使うときawaitが消えるとなるとかなり困ります・・・

>これはバグでしょうか？
仕様（こうじゃないとメッセージに即座に反応して欲しい時困る）
wait待機中にメッセージを受け取ったら
待機を中断してるだけで消えてる訳じゃない

on系を使いながら一定の時間待機したいなら
waitだけじゃなく時間で管理するかWin32Apiのsleepを併用する

#uselib "KERNEL32.DLL"
#func Sleep "Sleep" sptr

onkey gosub *keydown

*main
	if ginfo_cy>ginfo_winy : cls
	mes "0.5秒"	;0.5秒感覚でメッセージ
	Sleep 500
	await 0
	goto *main
*keydown
	mes iparam	;WM_KEYDOWNでキーコード表示
	return

通常Sleepは環境により精度が違う(10ms前後)ので注意
精度を設定する事は出来る

おおなるほど・・・
ということはHSPのoncmd系はコールバック関数のWindowProcとは違うってことでしょうか？

時間管理だとこんな感じ

onkey gosub *keydown

*main
	if ginfo_cy>ginfo_winy : cls
	mes "0.5秒"	;0.5秒感覚でメッセージ

	c=0
	a=gettime(7)
	repeat 
		await 1
		b=gettime(7)
		c+=(b-a+1000)\1000
		if c>=500 {break}
		a=b
	loop

	goto *main
*keydown
	mes iparam	;WM_KEYDOWNでキーコード表示
	return

gettime(7)の精度も10ms程度なので注意(awaitの精度は上がってるのに・・・)

Sleepのとはキーリピートに対する動作の違いがある
場合によってはSleepの方も時間で管理が必要になる
Sleep中はメッセージを受け取らないので
設定を大きくするとウィンドウ操作の反応が鈍くなる

>仕様（こうじゃないとメッセージに即座に反応して欲しい時困る）
メッセージ処理の後に続けて即座に処理をしたい場合だった・・・

>ということはHSPのoncmd系はコールバック関数のWindowProcとは
on系はawait,wait,stopの待機中にのみ溜まったメッセージの受信処理がされる
何時メッセージが送られても待機中以外は受信されない