HSPTV!掲示板

前回と同じく、なんとなく作ってみました。
「壁紙かってに変更君」このネーミングは結構苦労しました。

#define CLSID_ActiveDesktop "{75048700-EF1F-11D0-9888-006097DEACF9}"
#define IID_IActiveDesktop "{F490EB00-1240-11D1-9888-006097DEACF9}"
#usecom IActiveDesktop IID_IActiveDesktop CLSID_ActiveDesktop
#comfunc IActiveDesktop_ApplyChanges 3 int
#comfunc IActiveDesktop_SetWallpaper 5 wstr, int
#comfunc IActiveDesktop_SetWallpaperOptions 7 int, int
#enum WPSTYLE_CENTER = 0
#enum WPSTYLE_TILE
#enum WPSTYLE_STRETCH
	onexit *exit
	newcom adesktop, CLSID_ActiveDesktop
	chdir ""//ここに、壁紙のあるフォルダーを指定してね。
	dirlist list,"*.jpg":s=stat
	randomize
	notesel list
	repeat 
		noteget get,rnd(s)
		filepath=get
		gosub *setwallpaper
	wait 1000
	loop
*setwallpaper
	IActiveDesktop_SetWallpaper adesktop, filepath
	WALLPAPEROPT = 8, WPSTYLE_CENTER
	IActiveDesktop_SetWallpaperOptions adesktop, varptr(WALLPAPEROPT)
	IActiveDesktop_ApplyChanges adesktop, 7
	return
*exit
	delcom adesktop
	end

あるサンプルを少し改造しただけですけど。

大富豪Aさんはこのスクリプトで動いたのでしょうか？

chdir ""//ここに、壁紙のあるフォルダーを指定してね。
	dirlist list,"*.jpg":s=stat

でlistにはファイル名しか入りません(ディレクトリパスがない)

IActiveDesktop_SetWallpaper adesktop, filepath

でファイル名だけでは読み込めるはずがないと思います

以下アスペクト比保持リサイズ改良版

#define CLSID_ActiveDesktop "{75048700-EF1F-11D0-9888-006097DEACF9}"
#define IID_IActiveDesktop "{F490EB00-1240-11D1-9888-006097DEACF9}"
#usecom IActiveDesktop IID_IActiveDesktop CLSID_ActiveDesktop
#comfunc IActiveDesktop_ApplyChanges 3 int
#comfunc IActiveDesktop_SetWallpaper 5 wstr, int
#comfunc IActiveDesktop_SetWallpaperOptions 7 int, int
#enum WPSTYLE_CENTER = 0
#enum WPSTYLE_TILE
#enum WPSTYLE_STRETCH

	newcom adesktop, CLSID_ActiveDesktop
	onexit *exit
	dirname = "D:\\Users\\kanahiron\\pictures"//ここに、壁紙のあるフォルダーを指定してね。
	chdir dirname
	dirlist list,"*.jpg":s=stat
	randomize
	notesel list
	repeat 
		noteget get,rnd(s)
		get = ""+dirname+ "\\"+ get

		buffer 1
		picload get
		fx = ginfo(12)
		fy = ginfo(13)
		
		sx = ginfo(20)
		sy = ginfo(21)
	
		a1 = double(sx)/fx
		a2 = double(sy)/fy
		if a1-a2<=0{
			buffer 2,sx,(a1*fy)
			pos 0,0
			gzoom sx,(a1*fy),1,0,0,fx,fy,1
		} else { 
			buffer 2,(a2*fx),sy
			pos 0,0
			gzoom (a2*fx),sy,1,0,0,fx,fy,1
		}
		filename = ""+dirname+ "\\"+ "temp"
		bmpsave filename
		gosub *setwallpaper
		delete filename
		wait 1000
	loop
	stop
*setwallpaper
	IActiveDesktop_SetWallpaper adesktop,filename
	WALLPAPEROPT = 8, WPSTYLE_CENTER
	IActiveDesktop_SetWallpaperOptions adesktop, varptr(WALLPAPEROPT)
	IActiveDesktop_ApplyChanges adesktop, 7
return
*exit
	delcom adesktop
end

あ dirnameに入力したの消し忘れた
まぁいいや　個人情報じゃないしｗ

>kanahironさん
コメントありがとうございます。
僕の環境では、正しく実行されました。
chdirでとりあえずディレクトリの変更をしているのでたぶん大丈夫だと思いますが・・・。
バッファに画像を読み込ませなくても、

WALLPAPEROPT = 8, WPSTYLE_CENTER

の値を書き換えれば、キチンとリサイズされますよ。(たしか)

うーん
自分の環境ではディレクトリ移動してもサブルーチン先では読み込めません
あと、WPSTYLE_STRETCHも自分の環境ではアスペクト比無視されてしまって使えません
Windows 7 64bit

>kanahironさん
僕の環境はできるんですけど.....
Windows Vista しかも、セレロン　M

なんとなく

WALLPAPEROPT = 8, 3

ってやったらアスペクト比保持で全画面になりました 相変わらずフルパスじゃないと読み込めませんが

フルパスじゃないと読み込みませんでした。
Windows 7 32bit（OS入れ直して一般的な環境が整ったばかりの綺麗な状態です）

＞僕の環境はできるんですけど.....
自分専用ならそれでいい。