HSPTV!掲示板

chkbox2.asについてどうしても分からないことがあったので再度質問させて頂きます。

前スレhttp://hsp.tv/play/pforum.php?mode=all&num=49689

#include "chkbox2.as"

pos 10,5
color 225,225,225
color2 0,0,0//背景色
font "ＭＳ ゴシック",12//フォントも指定できる
objsize 200,20
chkbox2 "チェック0",c0
oncmd gosub *wm_command,$111	;変更
hChk=cstat//cstatにオブジェクトハンドル
hStatic=sstat//sstatにスタティックテキストのオブジェクトハンドル(文字部分)


pos 10,30
color 225,225,225
color2 0,0,0//背景色
font "ＭＳ ゴシック",12//フォントも指定できる
objsize 200,20
chkbox2 "チェック1",c1
oncmd gosub *wm_command,$111	;変更
hChk=cstat//cstatにオブジェクトハンドル
hStatic=sstat//sstatにスタティックテキストのオブジェクトハンドル(文字部分)


pos 10,55
color 225,225,225
color2 0,0,0//背景色
font "ＭＳ ゴシック",12//フォントも指定できる
objsize 200,20
chkbox2 "チェック2",c2
oncmd gosub *wm_command,$111	;変更
hChk=cstat//cstatにオブジェクトハンドル
hStatic=sstat//sstatにスタティックテキストのオブジェクトハンドル(文字部分)


stop



*wm_command
	sendmsg objinfo_hwnd(hChk),0xF0,0,0
	if c0 = 1 : gosub *c0_ : else : gosub *c0_k
return



*c0_

	mes "0"

return


*c0_k

	mes "1"
	
return

今度は上のスクリプトのようにチェックボックスを３つに増やし見てみました。

そして、HSPウィンドウをアクティブ→他のウィンドウをアクティブ→HSPウィンドウをアクティブ・・・と繰り返していくと急にHSPが閉じてしまいます。

しかも、チェックボックスを8個にすると「HSPエラー９, サブルーチンやループのネストが深すぎます」と出てしまいます。

どうすれば良いのでしょうか？

よろしくお願いします。

chkbox2.asの以下の部分を修正してください。

#if 0	;【誤】
	repeat CHK2cnt
		if lparam=hStatic_CHK2.cnt{
			;SetBkColorChk2 wparam,0x01//	↓これを消してコメントアウトを二箇所外せば文字以外が透過される
			return CreateSolidBrushChk2(RGB_CHK2(mod_col2_r,mod_col2_g,mod_col2_b))
			;return GetStockObjectChk2(5);
		}
		if lparam=hStatic2_CHK2.cnt{
			SetBkColorChk2 wparam,RGB_CHK2(mod_col2_r,mod_col2_g,mod_col2_b)//こっちを透過しようとすると黒くなる(重ねてる為？)
			SetTextColorChk2 wparam,RGB_CHK2(ginfo(16),ginfo(17),ginfo(18))
			return GetStockObjectChk2(5)
		}
	loop
#else	;【正】
	flg=0
	repeat CHK2cnt
		if lparam=hStatic_CHK2.cnt{
			flg=1
			break
		}
		if lparam=hStatic2_CHK2.cnt{
			flg=2
			break
		}
	loop
	if flg==1 {
		;SetBkColorChk2 wparam,0x01//	↓これを消してコメントアウトを二箇所外せば文字以外が透過される
		return CreateSolidBrushChk2(RGB_CHK2(mod_col2_r,mod_col2_g,mod_col2_b))
		;return GetStockObjectChk2(5);
	} else : if flg==2 {
		SetBkColorChk2 wparam,RGB_CHK2(mod_col2_r,mod_col2_g,mod_col2_b)//こっちを透過しようとすると黒くなる(重ねてる為？)
		SetTextColorChk2 wparam,RGB_CHK2(ginfo(16),ginfo(17),ginfo(18))
		return GetStockObjectChk2(5)
	}
#endif

ANTARESさん
ありがとうございます。
解決いたしました。